git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.WebFinger do
   6   alias Pleroma.HTTP
   7   alias Pleroma.User
   8   alias Pleroma.Web
   9   alias Pleroma.Web.Federator.Publisher
  10   alias Pleroma.Web.XML
  11   alias Pleroma.XmlBuilder
  12   require Jason
  13   require Logger
  14
  15   def host_meta do
  16     base_url = Web.base_url()
  17
  18     {
  19       :XRD,
  20       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  21       {
  22         :Link,
  23         %{
  24           rel: "lrdd",
  25           type: "application/xrd+xml",
  26           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  27         }
  28       }
  29     }
  30     |> XmlBuilder.to_doc()
  31   end
  32
  33   def webfinger(resource, fmt) when fmt in ["XML", "JSON"] do
  34     host = Pleroma.Web.Endpoint.host()
  35     regex = ~r/(acct:)?(?<username>[a-z0-9A-Z_\.-]+)@#{host}/
  36
  37     with %{"username" => username} <- Regex.named_captures(regex, resource),
  38          %User{} = user <- User.get_cached_by_nickname(username) do
  39       {:ok, represent_user(user, fmt)}
  40     else
  41       _e ->
  42         with %User{} = user <- User.get_cached_by_ap_id(resource) do
  43           {:ok, represent_user(user, fmt)}
  44         else
  45           _e ->
  46             {:error, "Couldn't find user"}
  47         end
  48     end
  49   end
  50
  51   defp gather_links(%User{} = user) do
  52     [
  53       %{
  54         "rel" => "http://webfinger.net/rel/profile-page",
  55         "type" => "text/html",
  56         "href" => user.ap_id
  57       }
  58     ] ++ Publisher.gather_webfinger_links(user)
  59   end
  60
  61   def represent_user(user, "JSON") do
  62     {:ok, user} = User.ensure_keys_present(user)
  63
  64     %{
  65       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  66       "aliases" => [user.ap_id],
  67       "links" => gather_links(user)
  68     }
  69   end
  70
  71   def represent_user(user, "XML") do
  72     {:ok, user} = User.ensure_keys_present(user)
  73
  74     links =
  75       gather_links(user)
  76       |> Enum.map(fn link -> {:Link, link} end)
  77
  78     {
  79       :XRD,
  80       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  81       [
  82         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
  83         {:Alias, user.ap_id}
  84       ] ++ links
  85     }
  86     |> XmlBuilder.to_doc()
  87   end
  88
  89   defp get_magic_key("data:application/magic-public-key," <> magic_key) do
  90     {:ok, magic_key}
  91   end
  92
  93   defp get_magic_key(nil) do
  94     Logger.debug("Undefined magic key.")
  95     {:ok, nil}
  96   end
  97
  98   defp get_magic_key(_) do
  99     {:error, "Missing magic key data."}
 100   end
 101
 102   defp webfinger_from_xml(doc) do
 103     with magic_key <- XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc),
 104          {:ok, magic_key} <- get_magic_key(magic_key),
 105          topic <-
 106            XML.string_from_xpath(
 107              ~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href},
 108              doc
 109            ),
 110          subject <- XML.string_from_xpath("//Subject", doc),
 111          subscribe_address <-
 112            XML.string_from_xpath(
 113              ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template},
 114              doc
 115            ),
 116          ap_id <-
 117            XML.string_from_xpath(
 118              ~s{//Link[@rel="self" and @type="application/activity+json"]/@href},
 119              doc
 120            ) do
 121       data = %{
 122         "magic_key" => magic_key,
 123         "topic" => topic,
 124         "subject" => subject,
 125         "subscribe_address" => subscribe_address,
 126         "ap_id" => ap_id
 127       }
 128
 129       {:ok, data}
 130     else
 131       {:error, e} ->
 132         {:error, e}
 133
 134       e ->
 135         {:error, e}
 136     end
 137   end
 138
 139   defp webfinger_from_json(doc) do
 140     data =
 141       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 142         case {link["type"], link["rel"]} do
 143           {"application/activity+json", "self"} ->
 144             Map.put(data, "ap_id", link["href"])
 145
 146           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 147             Map.put(data, "ap_id", link["href"])
 148
 149           {_, "http://ostatus.org/schema/1.0/subscribe"} ->
 150             Map.put(data, "subscribe_address", link["template"])
 151
 152           _ ->
 153             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 154             data
 155         end
 156       end)
 157
 158     {:ok, data}
 159   end
 160
 161   def get_template_from_xml(body) do
 162     xpath = "//Link[@rel='lrdd']/@template"
 163
 164     with doc when doc != :error <- XML.parse_document(body),
 165          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 166       {:ok, template}
 167     end
 168   end
 169
 170   def find_lrdd_template(domain) do
 171     with {:ok, %{status: status, body: body}} when status in 200..299 <-
 172            HTTP.get("http://#{domain}/.well-known/host-meta", []) do
 173       get_template_from_xml(body)
 174     else
 175       _ ->
 176         with {:ok, %{body: body}} <- HTTP.get("https://#{domain}/.well-known/host-meta", []) do
 177           get_template_from_xml(body)
 178         else
 179           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 180         end
 181     end
 182   end
 183
 184   @spec finger(String.t()) :: {:ok, map()} | {:error, any()}
 185   def finger(account) do
 186     account = String.trim_leading(account, "@")
 187
 188     domain =
 189       with [_name, domain] <- String.split(account, "@") do
 190         domain
 191       else
 192         _e ->
 193           URI.parse(account).host
 194       end
 195
 196     address =
 197       case find_lrdd_template(domain) do
 198         {:ok, template} ->
 199           String.replace(template, "{uri}", URI.encode(account))
 200
 201         _ ->
 202           "https://#{domain}/.well-known/webfinger?resource=acct:#{account}"
 203       end
 204
 205     with response <-
 206            HTTP.get(
 207              address,
 208              [{"accept", "application/xrd+xml,application/jrd+json"}]
 209            ),
 210          {:ok, %{status: status, body: body}} when status in 200..299 <- response do
 211       doc = XML.parse_document(body)
 212
 213       if doc != :error do
 214         webfinger_from_xml(doc)
 215       else
 216         with {:ok, doc} <- Jason.decode(body) do
 217           webfinger_from_json(doc)
 218         end
 219       end
 220     else
 221       e ->
 222         Logger.debug(fn -> "Couldn't finger #{account}" end)
 223         Logger.debug(fn -> inspect(e) end)
 224         {:error, e}
 225     end
 226   end
 227 end