git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   alias Pleroma.{Repo, User, XmlBuilder}
   5   alias Pleroma.Web
   6   alias Pleroma.Web.{XML, Salmon, OStatus}
   7   require Logger
   8
   9   def host_meta do
  10     base_url  = Web.base_url
  11     {
  12       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  13       {
  14         :Link, %{rel: "lrdd", type: "application/xrd+xml", template: "#{base_url}/.well-known/webfinger?resource={uri}"}
  15       }
  16     }
  17     |> XmlBuilder.to_doc
  18   end
  19
  20   def webfinger(resource) do
  21     host = Pleroma.Web.Endpoint.host
  22     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  23     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  24       user = User.get_by_nickname(username)
  25       {:ok, represent_user(user)}
  26     else _e ->
  27       with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  28         {:ok, represent_user(user)}
  29       else _e ->
  30         {:error, "Couldn't find user"}
  31       end
  32     end
  33   end
  34
  35   def represent_user(user) do
  36     {:ok, user} = ensure_keys_present(user)
  37     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  38     magic_key = Salmon.encode_key(public)
  39     {
  40       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  41       [
  42         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host}"},
  43         {:Alias, user.ap_id},
  44         {:Link, %{rel: "http://schemas.google.com/g/2010#updates-from", type: "application/atom+xml", href: OStatus.feed_path(user)}},
  45         {:Link, %{rel: "http://webfinger.net/rel/profile-page", type: "text/html", href: user.ap_id}},
  46         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
  47         {:Link, %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}},
  48         {:Link, %{rel: "self", type: "application/activity+json", href: user.ap_id}},
  49         {:Link, %{rel: "http://ostatus.org/schema/1.0/subscribe", template: OStatus.remote_follow_path()}}
  50       ]
  51     }
  52     |> XmlBuilder.to_doc
  53   end
  54
  55   # This seems a better fit in Salmon
  56   def ensure_keys_present(user) do
  57     info = user.info || %{}
  58     if info["keys"] do
  59       {:ok, user}
  60     else
  61       {:ok, pem} = Salmon.generate_rsa_pem
  62       info = Map.put(info, "keys", pem)
  63       Ecto.Changeset.change(user, info: info)
  64       |> User.update_and_set_cache()
  65     end
  66   end
  67
  68   defp webfinger_from_xml(doc) do
  69     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
  70     "data:application/magic-public-key," <> magic_key = magic_key
  71     topic = XML.string_from_xpath(~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href}, doc)
  72     subject = XML.string_from_xpath("//Subject", doc)
  73     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
  74     subscribe_address = XML.string_from_xpath(~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template}, doc)
  75     ap_id = XML.string_from_xpath(~s{//Link[@rel="self" and @type="application/activity+json"]/@href}, doc)
  76     data = %{
  77       "magic_key" => magic_key,
  78       "topic" => topic,
  79       "subject" => subject,
  80       "salmon" => salmon,
  81       "subscribe_address" => subscribe_address,
  82       "ap_id" => ap_id
  83     }
  84     {:ok, data}
  85   end
  86
  87   def get_template_from_xml(body) do
  88     xpath = "//Link[@rel='lrdd' and @type='application/xrd+xml']/@template"
  89     with doc when doc != :error <- XML.parse_document(body),
  90       template when template != nil <- XML.string_from_xpath(xpath, doc) do
  91       {:ok, template}
  92     end
  93   end
  94
  95   def find_lrdd_template(domain) do
  96     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- @httpoison.get("http://#{domain}/.well-known/host-meta", [], follow_redirect: true) do
  97       get_template_from_xml(body)
  98     else
  99       _ ->
 100         with {:ok, %{body: body}} <- @httpoison.get("https://#{domain}/.well-known/host-meta", []) do
 101           get_template_from_xml(body)
 102         else
 103           e -> {:error, "Can't find lrdd template: #{inspect(e)}"}
 104         end
 105     end
 106   end
 107
 108   def finger(account) do
 109     account = String.trim_leading(account, "@")
 110     domain = with [_name, domain] <- String.split(account, "@") do
 111                domain
 112              else _e ->
 113                URI.parse(account).host
 114              end
 115
 116     with {:ok, template} <- find_lrdd_template(domain),
 117          address <- String.replace(template, "{uri}", URI.encode(account)),
 118          response <- @httpoison.get(address, ["Accept": "application/xrd+xml"]),
 119          {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response,
 120          doc when doc != :error<- XML.parse_document(body),
 121          {:ok, data} <- webfinger_from_xml(doc) do
 122       {:ok, data}
 123     else
 124       e ->
 125         Logger.debug(fn -> "Couldn't finger #{account}" end)
 126         Logger.debug(fn -> inspect(e) end)
 127         {:error, e}
 128     end
 129   end
 130 end