git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   alias Pleroma.{User, XmlBuilder}
   5   alias Pleroma.Web
   6   alias Pleroma.Web.{XML, Salmon, OStatus}
   7   require Jason
   8   require Logger
   9
  10   def host_meta do
  11     base_url = Web.base_url()
  12
  13     {
  14       :XRD,
  15       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  16       {
  17         :Link,
  18         %{
  19           rel: "lrdd",
  20           type: "application/xrd+xml",
  21           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  22         }
  23       }
  24     }
  25     |> XmlBuilder.to_doc()
  26   end
  27
  28   def webfinger(resource, "JSON") do
  29     host = Pleroma.Web.Endpoint.host()
  30     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  31
  32     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  33       user = User.get_by_nickname(username)
  34       {:ok, represent_user(user, "JSON")}
  35     else
  36       _e ->
  37         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  38           {:ok, represent_user(user, "JSON")}
  39         else
  40           _e ->
  41             {:error, "Couldn't find user"}
  42         end
  43     end
  44   end
  45
  46   def webfinger(resource, "XML") do
  47     host = Pleroma.Web.Endpoint.host()
  48     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  49
  50     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  51       user = User.get_by_nickname(username)
  52       {:ok, represent_user(user, "XML")}
  53     else
  54       _e ->
  55         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  56           {:ok, represent_user(user, "XML")}
  57         else
  58           _e ->
  59             {:error, "Couldn't find user"}
  60         end
  61     end
  62   end
  63
  64   def represent_user(user, "JSON") do
  65     {:ok, user} = ensure_keys_present(user)
  66     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  67     magic_key = Salmon.encode_key(public)
  68
  69     %{
  70       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  71       "aliases" => [user.ap_id],
  72       "links" => [
  73         %{
  74           "rel" => "http://schemas.google.com/g/2010#updates-from",
  75           "type" => "application/atom+xml",
  76           "href" => OStatus.feed_path(user)
  77         },
  78         %{
  79           "rel" => "http://webfinger.net/rel/profile-page",
  80           "type" => "text/html",
  81           "href" => user.ap_id
  82         },
  83         %{"rel" => "salmon", "href" => OStatus.salmon_path(user)},
  84         %{
  85           "rel" => "magic-public-key",
  86           "href" => "data:application/magic-public-key,#{magic_key}"
  87         },
  88         %{"rel" => "self", "type" => "application/activity+json", "href" => user.ap_id},
  89         %{"rel" => "self", "type" => "application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "href" => user.ap_id},
  90         %{
  91           "rel" => "http://ostatus.org/schema/1.0/subscribe",
  92           "template" => OStatus.remote_follow_path()
  93         }
  94       ]
  95     }
  96   end
  97
  98   def represent_user(user, "XML") do
  99     {:ok, user} = ensure_keys_present(user)
 100     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
 101     magic_key = Salmon.encode_key(public)
 102
 103     {
 104       :XRD,
 105       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
 106       [
 107         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
 108         {:Alias, user.ap_id},
 109         {:Link,
 110          %{
 111            rel: "http://schemas.google.com/g/2010#updates-from",
 112            type: "application/atom+xml",
 113            href: OStatus.feed_path(user)
 114          }},
 115         {:Link,
 116          %{rel: "http://webfinger.net/rel/profile-page", type: "text/html", href: user.ap_id}},
 117         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
 118         {:Link,
 119          %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}},
 120         {:Link, %{rel: "self", type: "application/activity+json", href: user.ap_id}},
 121         {:Link, %{rel: "self", type: "application/ld+json; profile=&quot;https://www.w3.org/ns/activitystreams&quot;", href: user.ap_id}},
 122         {:Link,
 123          %{rel: "http://ostatus.org/schema/1.0/subscribe", template: OStatus.remote_follow_path()}}
 124       ]
 125     }
 126     |> XmlBuilder.to_doc()
 127   end
 128
 129   # This seems a better fit in Salmon
 130   def ensure_keys_present(user) do
 131     info = user.info || %{}
 132
 133     if info["keys"] do
 134       {:ok, user}
 135     else
 136       {:ok, pem} = Salmon.generate_rsa_pem()
 137       info = Map.put(info, "keys", pem)
 138
 139       Ecto.Changeset.change(user, info: info)
 140       |> User.update_and_set_cache()
 141     end
 142   end
 143
 144   defp webfinger_from_xml(doc) do
 145     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
 146     "data:application/magic-public-key," <> magic_key = magic_key
 147
 148     topic =
 149       XML.string_from_xpath(
 150         ~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href},
 151         doc
 152       )
 153
 154     subject = XML.string_from_xpath("//Subject", doc)
 155     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
 156
 157     subscribe_address =
 158       XML.string_from_xpath(
 159         ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template},
 160         doc
 161       )
 162
 163     ap_id =
 164       XML.string_from_xpath(
 165         ~s{//Link[@rel="self" and @type="application/activity+json"]/@href},
 166         doc
 167       )
 168
 169     data = %{
 170       "magic_key" => magic_key,
 171       "topic" => topic,
 172       "subject" => subject,
 173       "salmon" => salmon,
 174       "subscribe_address" => subscribe_address,
 175       "ap_id" => ap_id
 176     }
 177
 178     {:ok, data}
 179   end
 180
 181   defp webfinger_from_json(doc) do
 182     data =
 183       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 184         case {link["type"], link["rel"]} do
 185           {"application/activity+json", "self"} ->
 186             Map.put(data, "ap_id", link["href"])
 187
 188           {_, "magic-public-key"} ->
 189             "data:application/magic-public-key," <> magic_key = link["href"]
 190             Map.put(data, "magic_key", magic_key)
 191
 192           {"application/atom+xml", "http://schemas.google.com/g/2010#updates-from"} ->
 193             Map.put(data, "topic", link["href"])
 194
 195           {_, "salmon"} ->
 196             Map.put(data, "salmon", link["href"])
 197
 198           {_, "http://ostatus.org/schema/1.0/subscribe"} ->
 199             Map.put(data, "subscribe_address", link["template"])
 200
 201           _ ->
 202             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 203             data
 204         end
 205       end)
 206
 207     {:ok, data}
 208   end
 209
 210   def get_template_from_xml(body) do
 211     xpath = "//Link[@rel='lrdd' and @type='application/xrd+xml']/@template"
 212
 213     with doc when doc != :error <- XML.parse_document(body),
 214          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 215       {:ok, template}
 216     end
 217   end
 218
 219   def find_lrdd_template(domain) do
 220     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <-
 221            @httpoison.get("http://#{domain}/.well-known/host-meta", [], follow_redirect: true) do
 222       get_template_from_xml(body)
 223     else
 224       _ ->
 225         with {:ok, %{body: body}} <- @httpoison.get("https://#{domain}/.well-known/host-meta", []) do
 226           get_template_from_xml(body)
 227         else
 228           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 229         end
 230     end
 231   end
 232
 233   def finger(account) do
 234     account = String.trim_leading(account, "@")
 235
 236     domain =
 237       with [_name, domain] <- String.split(account, "@") do
 238         domain
 239       else
 240         _e ->
 241           URI.parse(account).host
 242       end
 243
 244     address =
 245       case find_lrdd_template(domain) do
 246         {:ok, template} ->
 247           String.replace(template, "{uri}", URI.encode(account))
 248
 249         _ ->
 250           "http://#{domain}/.well-known/webfinger?resource=acct:#{account}"
 251       end
 252
 253     with response <-
 254            @httpoison.get(
 255              address,
 256              [Accept: "application/xrd+xml,application/jrd+json"],
 257              follow_redirect: true
 258            ),
 259          {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response do
 260       doc = XML.parse_document(body)
 261
 262       if doc != :error do
 263         webfinger_from_xml(doc)
 264       else
 265         {:ok, doc} = Jason.decode(body)
 266         webfinger_from_json(doc)
 267       end
 268     else
 269       e ->
 270         Logger.debug(fn -> "Couldn't finger #{account}" end)
 271         Logger.debug(fn -> inspect(e) end)
 272         {:error, e}
 273     end
 274   end
 275 end