git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 defmodule Pleroma.Web.TwitterAPI.UserView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Formatter
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7   alias Pleroma.HTML
   8
   9   def render("show.json", %{user: user = %User{}} = assigns) do
  10     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
  11   end
  12
  13   def render("index.json", %{users: users, for: user}) do
  14     render_many(users, Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  15   end
  16
  17   def render("user.json", %{user: user = %User{}} = assigns) do
  18     image = User.avatar_url(user) |> MediaProxy.url()
  19
  20     {following, follows_you, statusnet_blocking} =
  21       if assigns[:for] do
  22         {
  23           User.following?(assigns[:for], user),
  24           User.following?(user, assigns[:for]),
  25           User.blocks?(assigns[:for], user)
  26         }
  27       else
  28         {false, false, false}
  29       end
  30
  31     user_info = User.get_cached_user_info(user)
  32
  33     emoji =
  34       (user.info.source_data["tag"] || [])
  35       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  36       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  37         {String.trim(name, ":"), url}
  38       end)
  39
  40     # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
  41     # For example: [{"name": "Pronoun", "value": "she/her"}, …]
  42     fields =
  43       (user.info.source_data["attachment"] || [])
  44       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  45       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  46
  47     data = %{
  48       "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  49       "description" => HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
  50       "description_html" => HTML.filter_tags(user.bio, User.html_filter_policy(assigns[:for])),
  51       "favourites_count" => 0,
  52       "followers_count" => user_info[:follower_count],
  53       "following" => following,
  54       "follows_you" => follows_you,
  55       "statusnet_blocking" => statusnet_blocking,
  56       "friends_count" => user_info[:following_count],
  57       "id" => user.id,
  58       "name" => user.name || user.nickname,
  59       "name_html" =>
  60         if(user.name,
  61           do: HTML.strip_tags(user.name) |> Formatter.emojify(emoji),
  62           else: user.nickname
  63         ),
  64       "profile_image_url" => image,
  65       "profile_image_url_https" => image,
  66       "profile_image_url_profile_size" => image,
  67       "profile_image_url_original" => image,
  68       "rights" => %{
  69         "delete_others_notice" => !!user.info.is_moderator
  70       },
  71       "screen_name" => user.nickname,
  72       "statuses_count" => user_info[:note_count],
  73       "statusnet_profile_url" => user.ap_id,
  74       "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
  75       "background_image" => image_url(user.info.background) |> MediaProxy.url(),
  76       "is_local" => user.local,
  77       "locked" => user.info.locked,
  78       "default_scope" => user.info.default_scope,
  79       "no_rich_text" => user.info.no_rich_text,
  80       "fields" => fields
  81     }
  82
  83     if assigns[:token] do
  84       Map.put(data, "token", assigns[:token])
  85     else
  86       data
  87     end
  88   end
  89
  90   def render("short.json", %{
  91         user: %User{
  92           nickname: nickname,
  93           id: id,
  94           ap_id: ap_id,
  95           name: name
  96         }
  97       }) do
  98     %{
  99       "fullname" => name,
 100       "id" => id,
 101       "ostatus_uri" => ap_id,
 102       "profile_url" => ap_id,
 103       "screen_name" => nickname
 104     }
 105   end
 106
 107   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 108   defp image_url(_), do: nil
 109 end