git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 defmodule Pleroma.Web.TwitterAPI.UserView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Web.CommonAPI.Utils
   5   alias Pleroma.Web.MediaProxy
   6
   7   def render("show.json", %{user: user = %User{}} = assigns) do
   8     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
   9   end
  10
  11   def render("index.json", %{users: users, for: user}) do
  12     render_many(users, Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  13   end
  14
  15   def render("user.json", %{user: user = %User{}} = assigns) do
  16     image = User.avatar_url(user) |> MediaProxy.url()
  17
  18     {following, follows_you, statusnet_blocking} =
  19       if assigns[:for] do
  20         {
  21           User.following?(assigns[:for], user),
  22           User.following?(user, assigns[:for]),
  23           User.blocks?(assigns[:for], user)
  24         }
  25       else
  26         {false, false, false}
  27       end
  28
  29     user_info = User.get_cached_user_info(user)
  30
  31     data = %{
  32       "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  33       "description" => HtmlSanitizeEx.strip_tags(user.bio),
  34       "favourites_count" => 0,
  35       "followers_count" => user_info[:follower_count],
  36       "following" => following,
  37       "follows_you" => follows_you,
  38       "statusnet_blocking" => statusnet_blocking,
  39       "friends_count" => user_info[:following_count],
  40       "id" => user.id,
  41       "name" => user.name,
  42       "profile_image_url" => image,
  43       "profile_image_url_https" => image,
  44       "profile_image_url_profile_size" => image,
  45       "profile_image_url_original" => image,
  46       "rights" => %{
  47         "delete_others_notice" => !!user.info["is_moderator"]
  48       },
  49       "screen_name" => user.nickname,
  50       "statuses_count" => user_info[:note_count],
  51       "statusnet_profile_url" => user.ap_id,
  52       "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
  53       "background_image" => image_url(user.info["background"]) |> MediaProxy.url(),
  54       "is_local" => user.local,
  55       "locked" => !!user.info["locked"]
  56     }
  57
  58     if assigns[:token] do
  59       Map.put(data, "token", assigns[:token])
  60     else
  61       data
  62     end
  63   end
  64
  65   def render("short.json", %{
  66         user: %User{
  67           nickname: nickname,
  68           id: id,
  69           ap_id: ap_id,
  70           name: name
  71         }
  72       }) do
  73     %{
  74       "fullname" => name,
  75       "id" => id,
  76       "ostatus_uri" => ap_id,
  77       "profile_url" => ap_id,
  78       "screen_name" => nickname
  79     }
  80   end
  81
  82   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
  83   defp image_url(_), do: nil
  84 end