git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 defmodule Pleroma.Web.TwitterAPI.UserView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Formatter
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7
   8   def render("show.json", %{user: user = %User{}} = assigns) do
   9     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
  10   end
  11
  12   def render("index.json", %{users: users, for: user}) do
  13     render_many(users, Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  14   end
  15
  16   def render("user.json", %{user: user = %User{}} = assigns) do
  17     image = User.avatar_url(user) |> MediaProxy.url()
  18
  19     {following, follows_you, statusnet_blocking} =
  20       if assigns[:for] do
  21         {
  22           User.following?(assigns[:for], user),
  23           User.following?(user, assigns[:for]),
  24           User.blocks?(assigns[:for], user)
  25         }
  26       else
  27         {false, false, false}
  28       end
  29
  30     user_info = User.get_cached_user_info(user)
  31
  32     emoji =
  33       (user.info["source_data"]["tag"] || [])
  34       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  35       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  36         {String.trim(name, ":"), url}
  37       end)
  38
  39     bio = HtmlSanitizeEx.strip_tags(user.bio)
  40
  41     data = %{
  42       "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  43       "description" => bio,
  44       "description_html" => bio |> Formatter.emojify(emoji),
  45       "favourites_count" => 0,
  46       "followers_count" => user_info[:follower_count],
  47       "following" => following,
  48       "follows_you" => follows_you,
  49       "statusnet_blocking" => statusnet_blocking,
  50       "friends_count" => user_info[:following_count],
  51       "id" => user.id,
  52       "name" => user.name,
  53       "name_html" => HtmlSanitizeEx.strip_tags(user.name) |> Formatter.emojify(emoji),
  54       "profile_image_url" => image,
  55       "profile_image_url_https" => image,
  56       "profile_image_url_profile_size" => image,
  57       "profile_image_url_original" => image,
  58       "rights" => %{
  59         "delete_others_notice" => !!user.info["is_moderator"]
  60       },
  61       "screen_name" => user.nickname,
  62       "statuses_count" => user_info[:note_count],
  63       "statusnet_profile_url" => user.ap_id,
  64       "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
  65       "background_image" => image_url(user.info["background"]) |> MediaProxy.url(),
  66       "is_local" => user.local,
  67       "locked" => !!user.info["locked"],
  68       "default_scope" => user.info["default_scope"] || "public"
  69     }
  70
  71     if assigns[:token] do
  72       Map.put(data, "token", assigns[:token])
  73     else
  74       data
  75     end
  76   end
  77
  78   def render("short.json", %{
  79         user: %User{
  80           nickname: nickname,
  81           id: id,
  82           ap_id: ap_id,
  83           name: name
  84         }
  85       }) do
  86     %{
  87       "fullname" => name,
  88       "id" => id,
  89       "ostatus_uri" => ap_id,
  90       "profile_url" => ap_id,
  91       "screen_name" => nickname
  92     }
  93   end
  94
  95   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
  96   defp image_url(_), do: nil
  97 end