git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UserView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.User
   8   alias Pleroma.Formatter
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MediaProxy
  11   alias Pleroma.HTML
  12
  13   def render("show.json", %{user: user = %User{}} = assigns) do
  14     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
  15   end
  16
  17   def render("index.json", %{users: users, for: user}) do
  18     users
  19     |> render_many(Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  20     |> Enum.filter(&Enum.any?/1)
  21   end
  22
  23   def render("user.json", %{user: user = %User{}} = assigns) do
  24     if User.visible_for?(user, assigns[:for]),
  25       do: render("valid_user.json", assigns),
  26       else: render("invalid_user.json", assigns)
  27   end
  28
  29   def render("invalid_user.json", _assigns) do
  30     %{}
  31   end
  32
  33   def render("valid_user.json", %{user: user = %User{}} = assigns) do
  34     for_user = assigns[:for]
  35     image = User.avatar_url(user) |> MediaProxy.url()
  36
  37     {following, follows_you, statusnet_blocking} =
  38       if for_user do
  39         {
  40           User.following?(for_user, user),
  41           User.following?(user, for_user),
  42           User.blocks?(for_user, user)
  43         }
  44       else
  45         {false, false, false}
  46       end
  47
  48     user_info = User.get_cached_user_info(user)
  49
  50     emoji =
  51       (user.info.source_data["tag"] || [])
  52       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  53       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  54         {String.trim(name, ":"), url}
  55       end)
  56
  57     # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
  58     # For example: [{"name": "Pronoun", "value": "she/her"}, …]
  59     fields =
  60       (user.info.source_data["attachment"] || [])
  61       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  62       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  63
  64     data = %{
  65       "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  66       "description" => HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
  67       "description_html" => HTML.filter_tags(user.bio, User.html_filter_policy(for_user)),
  68       "favourites_count" => 0,
  69       "followers_count" => user_info[:follower_count],
  70       "following" => following,
  71       "follows_you" => follows_you,
  72       "statusnet_blocking" => statusnet_blocking,
  73       "friends_count" => user_info[:following_count],
  74       "id" => user.id,
  75       "name" => user.name || user.nickname,
  76       "name_html" =>
  77         if(user.name,
  78           do: HTML.strip_tags(user.name) |> Formatter.emojify(emoji),
  79           else: user.nickname
  80         ),
  81       "profile_image_url" => image,
  82       "profile_image_url_https" => image,
  83       "profile_image_url_profile_size" => image,
  84       "profile_image_url_original" => image,
  85       "rights" => %{
  86         "delete_others_notice" => !!user.info.is_moderator
  87       },
  88       "screen_name" => user.nickname,
  89       "statuses_count" => user_info[:note_count],
  90       "statusnet_profile_url" => user.ap_id,
  91       "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
  92       "background_image" => image_url(user.info.background) |> MediaProxy.url(),
  93       "is_local" => user.local,
  94       "locked" => user.info.locked,
  95       "default_scope" => user.info.default_scope,
  96       "no_rich_text" => user.info.no_rich_text,
  97       "fields" => fields,
  98
  99       # Pleroma extension
 100       "pleroma" => %{
 101         "confirmation_pending" => user_info.confirmation_pending,
 102         "tags" => user.tags
 103       }
 104     }
 105
 106     if assigns[:token] do
 107       Map.put(data, "token", token_string(assigns[:token]))
 108     else
 109       data
 110     end
 111   end
 112
 113   def render("short.json", %{
 114         user: %User{
 115           nickname: nickname,
 116           id: id,
 117           ap_id: ap_id,
 118           name: name
 119         }
 120       }) do
 121     %{
 122       "fullname" => name,
 123       "id" => id,
 124       "ostatus_uri" => ap_id,
 125       "profile_url" => ap_id,
 126       "screen_name" => nickname
 127     }
 128   end
 129
 130   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 131   defp image_url(_), do: nil
 132
 133   defp token_string(%Pleroma.Web.OAuth.Token{token: token_str}), do: token_str
 134   defp token_string(token), do: token
 135 end