git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UserView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.Formatter
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MediaProxy
  12
  13   def render("show.json", %{user: user = %User{}} = assigns) do
  14     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
  15   end
  16
  17   def render("index.json", %{users: users, for: user}) do
  18     users
  19     |> render_many(Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  20     |> Enum.filter(&Enum.any?/1)
  21   end
  22
  23   def render("user.json", %{user: user = %User{}} = assigns) do
  24     if User.visible_for?(user, assigns[:for]),
  25       do: do_render("user.json", assigns),
  26       else: %{}
  27   end
  28
  29   def render("short.json", %{
  30         user: %User{
  31           nickname: nickname,
  32           id: id,
  33           ap_id: ap_id,
  34           name: name
  35         }
  36       }) do
  37     %{
  38       "fullname" => name,
  39       "id" => id,
  40       "ostatus_uri" => ap_id,
  41       "profile_url" => ap_id,
  42       "screen_name" => nickname
  43     }
  44   end
  45
  46   defp do_render("user.json", %{user: user = %User{}} = assigns) do
  47     for_user = assigns[:for]
  48     image = User.avatar_url(user) |> MediaProxy.url()
  49
  50     {following, follows_you, statusnet_blocking} =
  51       if for_user do
  52         {
  53           User.following?(for_user, user),
  54           User.following?(user, for_user),
  55           User.blocks?(for_user, user)
  56         }
  57       else
  58         {false, false, false}
  59       end
  60
  61     user_info = User.get_cached_user_info(user)
  62
  63     emoji =
  64       (user.info.source_data["tag"] || [])
  65       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  66       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  67         {String.trim(name, ":"), url}
  68       end)
  69
  70     emoji = Enum.dedup(emoji ++ user.info.emoji)
  71
  72     description_html =
  73       (user.bio || "")
  74       |> HTML.filter_tags(User.html_filter_policy(for_user))
  75       |> Formatter.emojify(emoji)
  76
  77     # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
  78     # For example: [{"name": "Pronoun", "value": "she/her"}, …]
  79     fields =
  80       (user.info.source_data["attachment"] || [])
  81       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  82       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  83
  84     data =
  85       %{
  86         "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  87         "description" => HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
  88         "description_html" => description_html,
  89         "favourites_count" => 0,
  90         "followers_count" => user_info[:follower_count],
  91         "following" => following,
  92         "follows_you" => follows_you,
  93         "statusnet_blocking" => statusnet_blocking,
  94         "friends_count" => user_info[:following_count],
  95         "id" => user.id,
  96         "name" => user.name || user.nickname,
  97         "name_html" =>
  98           if(user.name,
  99             do: HTML.strip_tags(user.name) |> Formatter.emojify(emoji),
 100             else: user.nickname
 101           ),
 102         "profile_image_url" => image,
 103         "profile_image_url_https" => image,
 104         "profile_image_url_profile_size" => image,
 105         "profile_image_url_original" => image,
 106         "screen_name" => user.nickname,
 107         "statuses_count" => user_info[:note_count],
 108         "statusnet_profile_url" => user.ap_id,
 109         "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
 110         "background_image" => image_url(user.info.background) |> MediaProxy.url(),
 111         "is_local" => user.local,
 112         "locked" => user.info.locked,
 113         "hide_followers" => user.info.hide_followers,
 114         "hide_follows" => user.info.hide_follows,
 115         "fields" => fields,
 116
 117         # Pleroma extension
 118         "pleroma" =>
 119           %{
 120             "confirmation_pending" => user_info.confirmation_pending,
 121             "tags" => user.tags
 122           }
 123           |> maybe_with_activation_status(user, for_user)
 124           |> with_notification_settings(user, for_user)
 125       }
 126       |> maybe_with_user_settings(user, for_user)
 127       |> maybe_with_role(user, for_user)
 128
 129     if assigns[:token] do
 130       Map.put(data, "token", token_string(assigns[:token]))
 131     else
 132       data
 133     end
 134   end
 135
 136   defp with_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 137     Map.put(data, "notification_settings", user.info.notification_settings)
 138   end
 139
 140   defp with_notification_settings(data, _, _), do: data
 141
 142   defp maybe_with_activation_status(data, user, %User{info: %{is_admin: true}}) do
 143     Map.put(data, "deactivated", user.info.deactivated)
 144   end
 145
 146   defp maybe_with_activation_status(data, _, _), do: data
 147
 148   defp maybe_with_role(data, %User{id: id} = user, %User{id: id}) do
 149     Map.merge(data, %{
 150       "role" => role(user),
 151       "show_role" => user.info.show_role,
 152       "rights" => %{
 153         "delete_others_notice" => !!user.info.is_moderator,
 154         "admin" => !!user.info.is_admin
 155       }
 156     })
 157   end
 158
 159   defp maybe_with_role(data, %User{info: %{show_role: true}} = user, _user) do
 160     Map.merge(data, %{
 161       "role" => role(user),
 162       "rights" => %{
 163         "delete_others_notice" => !!user.info.is_moderator,
 164         "admin" => !!user.info.is_admin
 165       }
 166     })
 167   end
 168
 169   defp maybe_with_role(data, _, _), do: data
 170
 171   defp maybe_with_user_settings(data, %User{info: info, id: id} = _user, %User{id: id}) do
 172     data
 173     |> Kernel.put_in(["default_scope"], info.default_scope)
 174     |> Kernel.put_in(["no_rich_text"], info.no_rich_text)
 175   end
 176
 177   defp maybe_with_user_settings(data, _, _), do: data
 178   defp role(%User{info: %{:is_admin => true}}), do: "admin"
 179   defp role(%User{info: %{:is_moderator => true}}), do: "moderator"
 180   defp role(_), do: "member"
 181
 182   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 183   defp image_url(_), do: nil
 184
 185   defp token_string(%Pleroma.Web.OAuth.Token{token: token_str}), do: token_str
 186   defp token_string(token), do: token
 187 end