git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UserView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.User
   8   alias Pleroma.Formatter
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MediaProxy
  11   alias Pleroma.HTML
  12
  13   def render("show.json", %{user: user = %User{}} = assigns) do
  14     render_one(user, Pleroma.Web.TwitterAPI.UserView, "user.json", assigns)
  15   end
  16
  17   def render("index.json", %{users: users, for: user}) do
  18     users
  19     |> render_many(Pleroma.Web.TwitterAPI.UserView, "user.json", for: user)
  20     |> Enum.filter(&Enum.any?/1)
  21   end
  22
  23   def render("user.json", %{user: user = %User{}} = assigns) do
  24     for_user = assigns[:for]
  25
  26     allow_render =
  27       User.remote_or_auth_active?(user) ||
  28         (for_user && (for_user.id == user.id || User.superuser?(for_user)))
  29
  30     if allow_render do
  31       render("valid_user.json", assigns)
  32     else
  33       render("invalid_user.json", assigns)
  34     end
  35   end
  36
  37   def render("invalid_user.json", _assigns) do
  38     %{}
  39   end
  40
  41   def render("valid_user.json", %{user: user = %User{}} = assigns) do
  42     for_user = assigns[:for]
  43     image = User.avatar_url(user) |> MediaProxy.url()
  44
  45     {following, follows_you, statusnet_blocking} =
  46       if for_user do
  47         {
  48           User.following?(for_user, user),
  49           User.following?(user, for_user),
  50           User.blocks?(for_user, user)
  51         }
  52       else
  53         {false, false, false}
  54       end
  55
  56     user_info = User.get_cached_user_info(user)
  57
  58     emoji =
  59       (user.info.source_data["tag"] || [])
  60       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  61       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  62         {String.trim(name, ":"), url}
  63       end)
  64
  65     # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
  66     # For example: [{"name": "Pronoun", "value": "she/her"}, …]
  67     fields =
  68       (user.info.source_data["attachment"] || [])
  69       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  70       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  71
  72     data = %{
  73       "created_at" => user.inserted_at |> Utils.format_naive_asctime(),
  74       "description" => HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
  75       "description_html" => HTML.filter_tags(user.bio, User.html_filter_policy(for_user)),
  76       "favourites_count" => 0,
  77       "followers_count" => user_info[:follower_count],
  78       "following" => following,
  79       "follows_you" => follows_you,
  80       "statusnet_blocking" => statusnet_blocking,
  81       "friends_count" => user_info[:following_count],
  82       "id" => user.id,
  83       "name" => user.name || user.nickname,
  84       "name_html" =>
  85         if(user.name,
  86           do: HTML.strip_tags(user.name) |> Formatter.emojify(emoji),
  87           else: user.nickname
  88         ),
  89       "profile_image_url" => image,
  90       "profile_image_url_https" => image,
  91       "profile_image_url_profile_size" => image,
  92       "profile_image_url_original" => image,
  93       "rights" => %{
  94         "delete_others_notice" => !!user.info.is_moderator
  95       },
  96       "screen_name" => user.nickname,
  97       "statuses_count" => user_info[:note_count],
  98       "statusnet_profile_url" => user.ap_id,
  99       "cover_photo" => User.banner_url(user) |> MediaProxy.url(),
 100       "background_image" => image_url(user.info.background) |> MediaProxy.url(),
 101       "is_local" => user.local,
 102       "locked" => user.info.locked,
 103       "default_scope" => user.info.default_scope,
 104       "no_rich_text" => user.info.no_rich_text,
 105       "fields" => fields,
 106
 107       # Pleroma extension
 108       "pleroma" => %{
 109         "confirmation_pending" => user_info.confirmation_pending,
 110         "tags" => user.tags
 111       }
 112     }
 113
 114     if assigns[:token] do
 115       Map.put(data, "token", token_string(assigns[:token]))
 116     else
 117       data
 118     end
 119   end
 120
 121   def render("short.json", %{
 122         user: %User{
 123           nickname: nickname,
 124           id: id,
 125           ap_id: ap_id,
 126           name: name
 127         }
 128       }) do
 129     %{
 130       "fullname" => name,
 131       "id" => id,
 132       "ostatus_uri" => ap_id,
 133       "profile_url" => ap_id,
 134       "screen_name" => nickname
 135     }
 136   end
 137
 138   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 139   defp image_url(_), do: nil
 140
 141   defp token_string(%Pleroma.Web.OAuth.Token{token: token_str}), do: token_str
 142   defp token_string(token), do: token
 143 end