git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Formatter
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   7   alias Pleroma.{Repo, Activity, Object, User, Notification}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Utils
  10   alias Ecto.Changeset
  11
  12   require Logger
  13
  14   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  15   action_fallback(:errors)
  16
  17   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  18     token = Phoenix.Token.sign(conn, "user socket", user.id)
  19     render(conn, UserView, "show.json", %{user: user, token: token})
  20   end
  21
  22   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  23     with media_ids <- extract_media_ids(status_data),
  24          {:ok, activity} <-
  25            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  26       conn
  27       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  28     else
  29       _ -> empty_status_reply(conn)
  30     end
  31   end
  32
  33   def status_update(conn, _status_data) do
  34     empty_status_reply(conn)
  35   end
  36
  37   defp empty_status_reply(conn) do
  38     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  39   end
  40
  41   defp extract_media_ids(status_data) do
  42     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  43          split_ids <- String.split(media_ids, ","),
  44          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  45       clean_ids
  46     else
  47       _e -> []
  48     end
  49   end
  50
  51   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  52     params =
  53       params
  54       |> Map.put("type", ["Create", "Announce"])
  55       |> Map.put("blocking_user", user)
  56
  57     activities = ActivityPub.fetch_public_activities(params)
  58
  59     conn
  60     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  61   end
  62
  63   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  64     params =
  65       params
  66       |> Map.put("type", ["Create", "Announce"])
  67       |> Map.put("local_only", true)
  68       |> Map.put("blocking_user", user)
  69
  70     activities = ActivityPub.fetch_public_activities(params)
  71
  72     conn
  73     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  74   end
  75
  76   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  77     params =
  78       params
  79       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  80       |> Map.put("blocking_user", user)
  81       |> Map.put("user", user)
  82
  83     activities =
  84       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  85       |> ActivityPub.contain_timeline(user)
  86
  87     conn
  88     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  89   end
  90
  91   def show_user(conn, params) do
  92     with {:ok, shown} <- TwitterAPI.get_user(params) do
  93       if user = conn.assigns.user do
  94         render(conn, UserView, "show.json", %{user: shown, for: user})
  95       else
  96         render(conn, UserView, "show.json", %{user: shown})
  97       end
  98     else
  99       {:error, msg} ->
 100         bad_request_reply(conn, msg)
 101     end
 102   end
 103
 104   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 105     case TwitterAPI.get_user(user, params) do
 106       {:ok, target_user} ->
 107         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 108
 109         conn
 110         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 111
 112       {:error, msg} ->
 113         bad_request_reply(conn, msg)
 114     end
 115   end
 116
 117   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 118     params =
 119       params
 120       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 121       |> Map.put("blocking_user", user)
 122
 123     activities = ActivityPub.fetch_activities([user.ap_id], params)
 124
 125     conn
 126     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 127   end
 128
 129   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 130     query =
 131       ActivityPub.fetch_activities_query(
 132         [user.ap_id],
 133         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 134       )
 135
 136     activities = Repo.all(query)
 137
 138     conn
 139     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 140   end
 141
 142   def notifications(%{assigns: %{user: user}} = conn, params) do
 143     notifications = Notification.for_user(user, params)
 144
 145     conn
 146     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 147   end
 148
 149   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 150     Notification.set_read_up_to(user, latest_id)
 151
 152     notifications = Notification.for_user(user, params)
 153
 154     conn
 155     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 156   end
 157
 158   def notifications_read(%{assigns: %{user: user}} = conn, _) do
 159     bad_request_reply(conn, "You need to specify latest_id")
 160   end
 161
 162   def follow(%{assigns: %{user: user}} = conn, params) do
 163     case TwitterAPI.follow(user, params) do
 164       {:ok, user, followed, _activity} ->
 165         render(conn, UserView, "show.json", %{user: followed, for: user})
 166
 167       {:error, msg} ->
 168         forbidden_json_reply(conn, msg)
 169     end
 170   end
 171
 172   def block(%{assigns: %{user: user}} = conn, params) do
 173     case TwitterAPI.block(user, params) do
 174       {:ok, user, blocked} ->
 175         render(conn, UserView, "show.json", %{user: blocked, for: user})
 176
 177       {:error, msg} ->
 178         forbidden_json_reply(conn, msg)
 179     end
 180   end
 181
 182   def unblock(%{assigns: %{user: user}} = conn, params) do
 183     case TwitterAPI.unblock(user, params) do
 184       {:ok, user, blocked} ->
 185         render(conn, UserView, "show.json", %{user: blocked, for: user})
 186
 187       {:error, msg} ->
 188         forbidden_json_reply(conn, msg)
 189     end
 190   end
 191
 192   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 193     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 194       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 195     end
 196   end
 197
 198   def unfollow(%{assigns: %{user: user}} = conn, params) do
 199     case TwitterAPI.unfollow(user, params) do
 200       {:ok, user, unfollowed} ->
 201         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 202
 203       {:error, msg} ->
 204         forbidden_json_reply(conn, msg)
 205     end
 206   end
 207
 208   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 209     with %Activity{} = activity <- Repo.get(Activity, id),
 210          true <- ActivityPub.visible_for_user?(activity, user) do
 211       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 212     end
 213   end
 214
 215   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 216     id = String.to_integer(id)
 217
 218     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 219          activities <-
 220            ActivityPub.fetch_activities_for_context(context, %{
 221              "blocking_user" => user,
 222              "user" => user
 223            }) do
 224       conn
 225       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 226     end
 227   end
 228
 229   @doc """
 230   Updates metadata of uploaded media object.
 231   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 232   """
 233   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 234     object = Repo.get(Object, id)
 235     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 236
 237     {conn, status, response_body} =
 238       cond do
 239         !object ->
 240           {halt(conn), :not_found, ""}
 241
 242         !Object.authorize_mutation(object, user) ->
 243           {halt(conn), :forbidden, "You can only update your own uploads."}
 244
 245         !is_binary(description) ->
 246           {conn, :not_modified, ""}
 247
 248         true ->
 249           new_data = Map.put(object.data, "name", description)
 250
 251           {:ok, _} =
 252             object
 253             |> Object.change(%{data: new_data})
 254             |> Repo.update()
 255
 256           {conn, :no_content, ""}
 257       end
 258
 259     conn
 260     |> put_status(status)
 261     |> json(response_body)
 262   end
 263
 264   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 265     response = TwitterAPI.upload(media, user)
 266
 267     conn
 268     |> put_resp_content_type("application/atom+xml")
 269     |> send_resp(200, response)
 270   end
 271
 272   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 273     response = TwitterAPI.upload(media, user, "json")
 274
 275     conn
 276     |> json_reply(200, response)
 277   end
 278
 279   def get_by_id_or_ap_id(id) do
 280     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 281
 282     if activity.data["type"] == "Create" do
 283       activity
 284     else
 285       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 286     end
 287   end
 288
 289   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 290     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 291          {:ok, activity} <- TwitterAPI.fav(user, id) do
 292       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 293     end
 294   end
 295
 296   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 297     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 298          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 299       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 300     end
 301   end
 302
 303   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 304     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 305          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 306       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 307     end
 308   end
 309
 310   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 311     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 312          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 313       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 314     end
 315   end
 316
 317   def register(conn, params) do
 318     with {:ok, user} <- TwitterAPI.register_user(params) do
 319       render(conn, UserView, "show.json", %{user: user})
 320     else
 321       {:error, errors} ->
 322         conn
 323         |> json_reply(400, Jason.encode!(errors))
 324     end
 325   end
 326
 327   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 328     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 329     change = Changeset.change(user, %{avatar: object.data})
 330     {:ok, user} = User.update_and_set_cache(change)
 331     CommonAPI.update(user)
 332
 333     render(conn, UserView, "show.json", %{user: user, for: user})
 334   end
 335
 336   def update_banner(%{assigns: %{user: user}} = conn, params) do
 337     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 338          new_info <- %{"banner" => object.data},
 339          info_cng <- User.Info.profile_update(user.info, new_info),
 340          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 341          {:ok, user} <- User.update_and_set_cache(changeset) do
 342       CommonAPI.update(user)
 343       %{"url" => [%{"href" => href} | _]} = object.data
 344       response = %{url: href} |> Jason.encode!()
 345
 346       conn
 347       |> json_reply(200, response)
 348     end
 349   end
 350
 351   def update_background(%{assigns: %{user: user}} = conn, params) do
 352     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 353          new_info <- %{"background" => object.data},
 354          info_cng <- User.Info.profile_update(user.info, new_info),
 355          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 356          {:ok, _user} <- User.update_and_set_cache(changeset) do
 357       %{"url" => [%{"href" => href} | _]} = object.data
 358       response = %{url: href} |> Jason.encode!()
 359
 360       conn
 361       |> json_reply(200, response)
 362     end
 363   end
 364
 365   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 366     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 367          response <- Jason.encode!(user_map) do
 368       conn
 369       |> json_reply(200, response)
 370     else
 371       _e ->
 372         conn
 373         |> put_status(404)
 374         |> json(%{error: "Can't find user"})
 375     end
 376   end
 377
 378   def followers(%{assigns: %{user: for_user}} = conn, params) do
 379     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 380          {:ok, followers} <- User.get_followers(user) do
 381       followers =
 382         cond do
 383           for_user && user.id == for_user.id -> followers
 384           user.info.hide_network -> []
 385           true -> followers
 386         end
 387
 388       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 389     else
 390       _e -> bad_request_reply(conn, "Can't get followers")
 391     end
 392   end
 393
 394   def friends(%{assigns: %{user: for_user}} = conn, params) do
 395     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 396          {:ok, friends} <- User.get_friends(user) do
 397       friends =
 398         cond do
 399           for_user && user.id == for_user.id -> friends
 400           user.info.hide_network -> []
 401           true -> friends
 402         end
 403
 404       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 405     else
 406       _e -> bad_request_reply(conn, "Can't get friends")
 407     end
 408   end
 409
 410   def friend_requests(conn, params) do
 411     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 412          {:ok, friend_requests} <- User.get_follow_requests(user) do
 413       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 414     else
 415       _e -> bad_request_reply(conn, "Can't get friend requests")
 416     end
 417   end
 418
 419   def approve_friend_request(conn, %{"user_id" => uid} = params) do
 420     with followed <- conn.assigns[:user],
 421          uid when is_number(uid) <- String.to_integer(uid),
 422          %User{} = follower <- Repo.get(User, uid),
 423          {:ok, follower} <- User.maybe_follow(follower, followed),
 424          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 425          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 426          {:ok, _activity} <-
 427            ActivityPub.accept(%{
 428              to: [follower.ap_id],
 429              actor: followed.ap_id,
 430              object: follow_activity.data["id"],
 431              type: "Accept"
 432            }) do
 433       render(conn, UserView, "show.json", %{user: follower, for: followed})
 434     else
 435       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 436     end
 437   end
 438
 439   def deny_friend_request(conn, %{"user_id" => uid} = params) do
 440     with followed <- conn.assigns[:user],
 441          uid when is_number(uid) <- String.to_integer(uid),
 442          %User{} = follower <- Repo.get(User, uid),
 443          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 444          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 445          {:ok, _activity} <-
 446            ActivityPub.reject(%{
 447              to: [follower.ap_id],
 448              actor: followed.ap_id,
 449              object: follow_activity.data["id"],
 450              type: "Reject"
 451            }) do
 452       render(conn, UserView, "show.json", %{user: follower, for: followed})
 453     else
 454       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 455     end
 456   end
 457
 458   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 459     with {:ok, friends} <- User.get_friends(user) do
 460       ids =
 461         friends
 462         |> Enum.map(fn x -> x.id end)
 463         |> Jason.encode!()
 464
 465       json(conn, ids)
 466     else
 467       _e -> bad_request_reply(conn, "Can't get friends")
 468     end
 469   end
 470
 471   def empty_array(conn, _params) do
 472     json(conn, Jason.encode!([]))
 473   end
 474
 475   def raw_empty_array(conn, _params) do
 476     json(conn, [])
 477   end
 478
 479   defp build_info_cng(user, params) do
 480     info_params =
 481       ["no_rich_text", "locked", "hide_network"]
 482       |> Enum.reduce(%{}, fn key, res ->
 483         if value = params[key] do
 484           Map.put(res, key, value == "true")
 485         else
 486           res
 487         end
 488       end)
 489
 490     info_params =
 491       if value = params["default_scope"] do
 492         Map.put(info_params, "default_scope", value)
 493       else
 494         info_params
 495       end
 496
 497     User.Info.profile_update(user.info, info_params)
 498   end
 499
 500   defp parse_profile_bio(user, params) do
 501     if bio = params["description"] do
 502       Map.put(params, "bio", User.parse_bio(bio, user))
 503     else
 504       params
 505     end
 506   end
 507
 508   def update_profile(%{assigns: %{user: user}} = conn, params) do
 509     params = parse_profile_bio(user, params)
 510     info_cng = build_info_cng(user, params)
 511
 512     with changeset <- User.update_changeset(user, params),
 513          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 514          {:ok, user} <- User.update_and_set_cache(changeset) do
 515       CommonAPI.update(user)
 516       render(conn, UserView, "user.json", %{user: user, for: user})
 517     else
 518       error ->
 519         Logger.debug("Can't update user: #{inspect(error)}")
 520         bad_request_reply(conn, "Can't update user")
 521     end
 522   end
 523
 524   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 525     activities = TwitterAPI.search(user, params)
 526
 527     conn
 528     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 529   end
 530
 531   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 532     users = User.search(query, true)
 533
 534     conn
 535     |> render(UserView, "index.json", %{users: users, for: user})
 536   end
 537
 538   defp bad_request_reply(conn, error_message) do
 539     json = error_json(conn, error_message)
 540     json_reply(conn, 400, json)
 541   end
 542
 543   defp json_reply(conn, status, json) do
 544     conn
 545     |> put_resp_content_type("application/json")
 546     |> send_resp(status, json)
 547   end
 548
 549   defp forbidden_json_reply(conn, error_message) do
 550     json = error_json(conn, error_message)
 551     json_reply(conn, 403, json)
 552   end
 553
 554   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 555
 556   def only_if_public_instance(conn, _) do
 557     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 558       conn
 559     else
 560       conn
 561       |> forbidden_json_reply("Invalid credentials.")
 562       |> halt()
 563     end
 564   end
 565
 566   defp error_json(conn, error_message) do
 567     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 568   end
 569
 570   def errors(conn, {:param_cast, _}) do
 571     conn
 572     |> put_status(400)
 573     |> json("Invalid parameters")
 574   end
 575
 576   def errors(conn, _) do
 577     conn
 578     |> put_status(500)
 579     |> json("Something went wrong")
 580   end
 581 end