git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   action_fallback(:errors)
  17
  18   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  19     token = Phoenix.Token.sign(conn, "user socket", user.id)
  20     render(conn, UserView, "show.json", %{user: user, token: token})
  21   end
  22
  23   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  24     with media_ids <- extract_media_ids(status_data),
  25          {:ok, activity} <-
  26            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  27       conn
  28       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  29     else
  30       _ -> empty_status_reply(conn)
  31     end
  32   end
  33
  34   def status_update(conn, _status_data) do
  35     empty_status_reply(conn)
  36   end
  37
  38   defp empty_status_reply(conn) do
  39     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  40   end
  41
  42   defp extract_media_ids(status_data) do
  43     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  44          split_ids <- String.split(media_ids, ","),
  45          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  46       clean_ids
  47     else
  48       _e -> []
  49     end
  50   end
  51
  52   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  53     params =
  54       params
  55       |> Map.put("type", ["Create", "Announce"])
  56       |> Map.put("blocking_user", user)
  57
  58     activities = ActivityPub.fetch_public_activities(params)
  59
  60     conn
  61     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  62   end
  63
  64   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  65     params =
  66       params
  67       |> Map.put("type", ["Create", "Announce"])
  68       |> Map.put("local_only", true)
  69       |> Map.put("blocking_user", user)
  70
  71     activities = ActivityPub.fetch_public_activities(params)
  72
  73     conn
  74     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  75   end
  76
  77   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  78     params =
  79       params
  80       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  81       |> Map.put("blocking_user", user)
  82       |> Map.put("user", user)
  83
  84     activities =
  85       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  86       |> ActivityPub.contain_timeline(user)
  87
  88     conn
  89     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  90   end
  91
  92   def show_user(conn, params) do
  93     with {:ok, shown} <- TwitterAPI.get_user(params) do
  94       if user = conn.assigns.user do
  95         render(conn, UserView, "show.json", %{user: shown, for: user})
  96       else
  97         render(conn, UserView, "show.json", %{user: shown})
  98       end
  99     else
 100       {:error, msg} ->
 101         bad_request_reply(conn, msg)
 102     end
 103   end
 104
 105   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 106     case TwitterAPI.get_user(user, params) do
 107       {:ok, target_user} ->
 108         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 109
 110         conn
 111         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 112
 113       {:error, msg} ->
 114         bad_request_reply(conn, msg)
 115     end
 116   end
 117
 118   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 119     params =
 120       params
 121       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 122       |> Map.put("blocking_user", user)
 123
 124     activities = ActivityPub.fetch_activities([user.ap_id], params)
 125
 126     conn
 127     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 128   end
 129
 130   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 131     query =
 132       ActivityPub.fetch_activities_query(
 133         [user.ap_id],
 134         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 135       )
 136
 137     activities = Repo.all(query)
 138
 139     conn
 140     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 141   end
 142
 143   def notifications(%{assigns: %{user: user}} = conn, params) do
 144     notifications = Notification.for_user(user, params)
 145
 146     conn
 147     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 148   end
 149
 150   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 151     Notification.set_read_up_to(user, latest_id)
 152
 153     notifications = Notification.for_user(user, params)
 154
 155     conn
 156     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 157   end
 158
 159   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 160     bad_request_reply(conn, "You need to specify latest_id")
 161   end
 162
 163   def follow(%{assigns: %{user: user}} = conn, params) do
 164     case TwitterAPI.follow(user, params) do
 165       {:ok, user, followed, _activity} ->
 166         render(conn, UserView, "show.json", %{user: followed, for: user})
 167
 168       {:error, msg} ->
 169         forbidden_json_reply(conn, msg)
 170     end
 171   end
 172
 173   def block(%{assigns: %{user: user}} = conn, params) do
 174     case TwitterAPI.block(user, params) do
 175       {:ok, user, blocked} ->
 176         render(conn, UserView, "show.json", %{user: blocked, for: user})
 177
 178       {:error, msg} ->
 179         forbidden_json_reply(conn, msg)
 180     end
 181   end
 182
 183   def unblock(%{assigns: %{user: user}} = conn, params) do
 184     case TwitterAPI.unblock(user, params) do
 185       {:ok, user, blocked} ->
 186         render(conn, UserView, "show.json", %{user: blocked, for: user})
 187
 188       {:error, msg} ->
 189         forbidden_json_reply(conn, msg)
 190     end
 191   end
 192
 193   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 194     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 195       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 196     end
 197   end
 198
 199   def unfollow(%{assigns: %{user: user}} = conn, params) do
 200     case TwitterAPI.unfollow(user, params) do
 201       {:ok, user, unfollowed} ->
 202         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 203
 204       {:error, msg} ->
 205         forbidden_json_reply(conn, msg)
 206     end
 207   end
 208
 209   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 210     with %Activity{} = activity <- Repo.get(Activity, id),
 211          true <- ActivityPub.visible_for_user?(activity, user) do
 212       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 213     end
 214   end
 215
 216   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 217     id = String.to_integer(id)
 218
 219     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 220          activities <-
 221            ActivityPub.fetch_activities_for_context(context, %{
 222              "blocking_user" => user,
 223              "user" => user
 224            }) do
 225       conn
 226       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 227     end
 228   end
 229
 230   @doc """
 231   Updates metadata of uploaded media object.
 232   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 233   """
 234   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 235     object = Repo.get(Object, id)
 236     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 237
 238     {conn, status, response_body} =
 239       cond do
 240         !object ->
 241           {halt(conn), :not_found, ""}
 242
 243         !Object.authorize_mutation(object, user) ->
 244           {halt(conn), :forbidden, "You can only update your own uploads."}
 245
 246         !is_binary(description) ->
 247           {conn, :not_modified, ""}
 248
 249         true ->
 250           new_data = Map.put(object.data, "name", description)
 251
 252           {:ok, _} =
 253             object
 254             |> Object.change(%{data: new_data})
 255             |> Repo.update()
 256
 257           {conn, :no_content, ""}
 258       end
 259
 260     conn
 261     |> put_status(status)
 262     |> json(response_body)
 263   end
 264
 265   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 266     response = TwitterAPI.upload(media, user)
 267
 268     conn
 269     |> put_resp_content_type("application/atom+xml")
 270     |> send_resp(200, response)
 271   end
 272
 273   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 274     response = TwitterAPI.upload(media, user, "json")
 275
 276     conn
 277     |> json_reply(200, response)
 278   end
 279
 280   def get_by_id_or_ap_id(id) do
 281     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 282
 283     if activity.data["type"] == "Create" do
 284       activity
 285     else
 286       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 287     end
 288   end
 289
 290   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 291     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 292          {:ok, activity} <- TwitterAPI.fav(user, id) do
 293       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 294     end
 295   end
 296
 297   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 298     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 299          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 300       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 301     end
 302   end
 303
 304   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 305     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 306          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 307       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 308     end
 309   end
 310
 311   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 312     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 313          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 314       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 315     end
 316   end
 317
 318   def register(conn, params) do
 319     with {:ok, user} <- TwitterAPI.register_user(params) do
 320       render(conn, UserView, "show.json", %{user: user})
 321     else
 322       {:error, errors} ->
 323         conn
 324         |> json_reply(400, Jason.encode!(errors))
 325     end
 326   end
 327
 328   def password_reset(conn, params) do
 329     nickname_or_email = params["email"] || params["nickname"]
 330
 331     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 332       json_response(conn, :no_content, "")
 333     end
 334   end
 335
 336   def confirm_email(_conn, _params), do: :noop
 337
 338   def email_invite(%{assigns: %{user: user}} = conn, %{"email" => email} = params) do
 339     with true <- Pleroma.Config.get([:instance, :invites_enabled]),
 340          email <- Pleroma.UserEmail.user_invitation_email(user, email, params["name"]),
 341          {:ok, _} <- Pleroma.Mailer.deliver(email) do
 342       json_response(conn, :no_content, "")
 343     end
 344   end
 345
 346   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 347     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 348     change = Changeset.change(user, %{avatar: object.data})
 349     {:ok, user} = User.update_and_set_cache(change)
 350     CommonAPI.update(user)
 351
 352     render(conn, UserView, "show.json", %{user: user, for: user})
 353   end
 354
 355   def update_banner(%{assigns: %{user: user}} = conn, params) do
 356     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 357          new_info <- %{"banner" => object.data},
 358          info_cng <- User.Info.profile_update(user.info, new_info),
 359          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 360          {:ok, user} <- User.update_and_set_cache(changeset) do
 361       CommonAPI.update(user)
 362       %{"url" => [%{"href" => href} | _]} = object.data
 363       response = %{url: href} |> Jason.encode!()
 364
 365       conn
 366       |> json_reply(200, response)
 367     end
 368   end
 369
 370   def update_background(%{assigns: %{user: user}} = conn, params) do
 371     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 372          new_info <- %{"background" => object.data},
 373          info_cng <- User.Info.profile_update(user.info, new_info),
 374          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 375          {:ok, _user} <- User.update_and_set_cache(changeset) do
 376       %{"url" => [%{"href" => href} | _]} = object.data
 377       response = %{url: href} |> Jason.encode!()
 378
 379       conn
 380       |> json_reply(200, response)
 381     end
 382   end
 383
 384   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 385     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 386          response <- Jason.encode!(user_map) do
 387       conn
 388       |> json_reply(200, response)
 389     else
 390       _e ->
 391         conn
 392         |> put_status(404)
 393         |> json(%{error: "Can't find user"})
 394     end
 395   end
 396
 397   def followers(%{assigns: %{user: for_user}} = conn, params) do
 398     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 399          {:ok, followers} <- User.get_followers(user) do
 400       followers =
 401         cond do
 402           for_user && user.id == for_user.id -> followers
 403           user.info.hide_network -> []
 404           true -> followers
 405         end
 406
 407       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 408     else
 409       _e -> bad_request_reply(conn, "Can't get followers")
 410     end
 411   end
 412
 413   def friends(%{assigns: %{user: for_user}} = conn, params) do
 414     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 415          {:ok, friends} <- User.get_friends(user) do
 416       friends =
 417         cond do
 418           for_user && user.id == for_user.id -> friends
 419           user.info.hide_network -> []
 420           true -> friends
 421         end
 422
 423       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 424     else
 425       _e -> bad_request_reply(conn, "Can't get friends")
 426     end
 427   end
 428
 429   def friend_requests(conn, params) do
 430     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 431          {:ok, friend_requests} <- User.get_follow_requests(user) do
 432       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 433     else
 434       _e -> bad_request_reply(conn, "Can't get friend requests")
 435     end
 436   end
 437
 438   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 439     with followed <- conn.assigns[:user],
 440          uid when is_number(uid) <- String.to_integer(uid),
 441          %User{} = follower <- Repo.get(User, uid),
 442          {:ok, follower} <- User.maybe_follow(follower, followed),
 443          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 444          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 445          {:ok, _activity} <-
 446            ActivityPub.accept(%{
 447              to: [follower.ap_id],
 448              actor: followed.ap_id,
 449              object: follow_activity.data["id"],
 450              type: "Accept"
 451            }) do
 452       render(conn, UserView, "show.json", %{user: follower, for: followed})
 453     else
 454       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 455     end
 456   end
 457
 458   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 459     with followed <- conn.assigns[:user],
 460          uid when is_number(uid) <- String.to_integer(uid),
 461          %User{} = follower <- Repo.get(User, uid),
 462          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 463          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 464          {:ok, _activity} <-
 465            ActivityPub.reject(%{
 466              to: [follower.ap_id],
 467              actor: followed.ap_id,
 468              object: follow_activity.data["id"],
 469              type: "Reject"
 470            }) do
 471       render(conn, UserView, "show.json", %{user: follower, for: followed})
 472     else
 473       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 474     end
 475   end
 476
 477   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 478     with {:ok, friends} <- User.get_friends(user) do
 479       ids =
 480         friends
 481         |> Enum.map(fn x -> x.id end)
 482         |> Jason.encode!()
 483
 484       json(conn, ids)
 485     else
 486       _e -> bad_request_reply(conn, "Can't get friends")
 487     end
 488   end
 489
 490   def empty_array(conn, _params) do
 491     json(conn, Jason.encode!([]))
 492   end
 493
 494   def raw_empty_array(conn, _params) do
 495     json(conn, [])
 496   end
 497
 498   defp build_info_cng(user, params) do
 499     info_params =
 500       ["no_rich_text", "locked", "hide_network"]
 501       |> Enum.reduce(%{}, fn key, res ->
 502         if value = params[key] do
 503           Map.put(res, key, value == "true")
 504         else
 505           res
 506         end
 507       end)
 508
 509     info_params =
 510       if value = params["default_scope"] do
 511         Map.put(info_params, "default_scope", value)
 512       else
 513         info_params
 514       end
 515
 516     User.Info.profile_update(user.info, info_params)
 517   end
 518
 519   defp parse_profile_bio(user, params) do
 520     if bio = params["description"] do
 521       Map.put(params, "bio", User.parse_bio(bio, user))
 522     else
 523       params
 524     end
 525   end
 526
 527   def update_profile(%{assigns: %{user: user}} = conn, params) do
 528     params = parse_profile_bio(user, params)
 529     info_cng = build_info_cng(user, params)
 530
 531     with changeset <- User.update_changeset(user, params),
 532          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 533          {:ok, user} <- User.update_and_set_cache(changeset) do
 534       CommonAPI.update(user)
 535       render(conn, UserView, "user.json", %{user: user, for: user})
 536     else
 537       error ->
 538         Logger.debug("Can't update user: #{inspect(error)}")
 539         bad_request_reply(conn, "Can't update user")
 540     end
 541   end
 542
 543   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 544     activities = TwitterAPI.search(user, params)
 545
 546     conn
 547     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 548   end
 549
 550   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 551     users = User.search(query, true)
 552
 553     conn
 554     |> render(UserView, "index.json", %{users: users, for: user})
 555   end
 556
 557   defp bad_request_reply(conn, error_message) do
 558     json = error_json(conn, error_message)
 559     json_reply(conn, 400, json)
 560   end
 561
 562   defp json_reply(conn, status, json) do
 563     conn
 564     |> put_resp_content_type("application/json")
 565     |> send_resp(status, json)
 566   end
 567
 568   defp forbidden_json_reply(conn, error_message) do
 569     json = error_json(conn, error_message)
 570     json_reply(conn, 403, json)
 571   end
 572
 573   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 574
 575   def only_if_public_instance(conn, _) do
 576     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 577       conn
 578     else
 579       conn
 580       |> forbidden_json_reply("Invalid credentials.")
 581       |> halt()
 582     end
 583   end
 584
 585   defp error_json(conn, error_message) do
 586     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 587   end
 588
 589   def errors(conn, {:param_cast, _}) do
 590     conn
 591     |> put_status(400)
 592     |> json("Invalid parameters")
 593   end
 594
 595   def errors(conn, _) do
 596     conn
 597     |> put_status(500)
 598     |> json("Something went wrong")
 599   end
 600 end