git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Formatter
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   7   alias Pleroma.{Repo, Activity, Object, User, Notification}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Utils
  10   alias Ecto.Changeset
  11
  12   require Logger
  13
  14   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  15   action_fallback(:errors)
  16
  17   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  18     token = Phoenix.Token.sign(conn, "user socket", user.id)
  19     render(conn, UserView, "show.json", %{user: user, token: token})
  20   end
  21
  22   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  23     with media_ids <- extract_media_ids(status_data),
  24          {:ok, activity} <-
  25            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  26       conn
  27       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  28     else
  29       _ -> empty_status_reply(conn)
  30     end
  31   end
  32
  33   def status_update(conn, _status_data) do
  34     empty_status_reply(conn)
  35   end
  36
  37   defp empty_status_reply(conn) do
  38     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  39   end
  40
  41   defp extract_media_ids(status_data) do
  42     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  43          split_ids <- String.split(media_ids, ","),
  44          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  45       clean_ids
  46     else
  47       _e -> []
  48     end
  49   end
  50
  51   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  52     params =
  53       params
  54       |> Map.put("type", ["Create", "Announce"])
  55       |> Map.put("blocking_user", user)
  56
  57     activities = ActivityPub.fetch_public_activities(params)
  58
  59     conn
  60     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  61   end
  62
  63   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  64     params =
  65       params
  66       |> Map.put("type", ["Create", "Announce"])
  67       |> Map.put("local_only", true)
  68       |> Map.put("blocking_user", user)
  69
  70     activities = ActivityPub.fetch_public_activities(params)
  71
  72     conn
  73     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  74   end
  75
  76   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  77     params =
  78       params
  79       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  80       |> Map.put("blocking_user", user)
  81       |> Map.put("user", user)
  82
  83     activities =
  84       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  85       |> ActivityPub.contain_timeline(user)
  86
  87     conn
  88     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  89   end
  90
  91   def show_user(conn, params) do
  92     with {:ok, shown} <- TwitterAPI.get_user(params) do
  93       if user = conn.assigns.user do
  94         render(conn, UserView, "show.json", %{user: shown, for: user})
  95       else
  96         render(conn, UserView, "show.json", %{user: shown})
  97       end
  98     else
  99       {:error, msg} ->
 100         bad_request_reply(conn, msg)
 101     end
 102   end
 103
 104   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 105     case TwitterAPI.get_user(user, params) do
 106       {:ok, target_user} ->
 107         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 108
 109         conn
 110         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 111
 112       {:error, msg} ->
 113         bad_request_reply(conn, msg)
 114     end
 115   end
 116
 117   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 118     params =
 119       params
 120       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 121       |> Map.put("blocking_user", user)
 122
 123     activities = ActivityPub.fetch_activities([user.ap_id], params)
 124
 125     conn
 126     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 127   end
 128
 129   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 130     query =
 131       ActivityPub.fetch_activities_query(
 132         [user.ap_id],
 133         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 134       )
 135
 136     activities = Repo.all(query)
 137
 138     conn
 139     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 140   end
 141
 142   def notifications(%{assigns: %{user: user}} = conn, params) do
 143     notifications = Notification.for_user(user, params)
 144
 145     conn
 146     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 147   end
 148
 149   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 150     Notification.set_read_up_to(user, latest_id)
 151
 152     notifications = Notification.for_user(user, params)
 153
 154     conn
 155     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 156   end
 157
 158   def notifications_read(%{assigns: %{user: user}} = conn, _) do
 159     bad_request_reply(conn, "You need to specify latest_id")
 160   end
 161
 162   def follow(%{assigns: %{user: user}} = conn, params) do
 163     case TwitterAPI.follow(user, params) do
 164       {:ok, user, followed, _activity} ->
 165         render(conn, UserView, "show.json", %{user: followed, for: user})
 166
 167       {:error, msg} ->
 168         forbidden_json_reply(conn, msg)
 169     end
 170   end
 171
 172   def block(%{assigns: %{user: user}} = conn, params) do
 173     case TwitterAPI.block(user, params) do
 174       {:ok, user, blocked} ->
 175         render(conn, UserView, "show.json", %{user: blocked, for: user})
 176
 177       {:error, msg} ->
 178         forbidden_json_reply(conn, msg)
 179     end
 180   end
 181
 182   def unblock(%{assigns: %{user: user}} = conn, params) do
 183     case TwitterAPI.unblock(user, params) do
 184       {:ok, user, blocked} ->
 185         render(conn, UserView, "show.json", %{user: blocked, for: user})
 186
 187       {:error, msg} ->
 188         forbidden_json_reply(conn, msg)
 189     end
 190   end
 191
 192   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 193     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 194       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 195     end
 196   end
 197
 198   def unfollow(%{assigns: %{user: user}} = conn, params) do
 199     case TwitterAPI.unfollow(user, params) do
 200       {:ok, user, unfollowed} ->
 201         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 202
 203       {:error, msg} ->
 204         forbidden_json_reply(conn, msg)
 205     end
 206   end
 207
 208   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 209     with %Activity{} = activity <- Repo.get(Activity, id),
 210          true <- ActivityPub.visible_for_user?(activity, user) do
 211       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 212     end
 213   end
 214
 215   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 216     id = String.to_integer(id)
 217
 218     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 219          activities <-
 220            ActivityPub.fetch_activities_for_context(context, %{
 221              "blocking_user" => user,
 222              "user" => user
 223            }) do
 224       conn
 225       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 226     end
 227   end
 228
 229   @doc """
 230   Updates metadata of uploaded media object.
 231   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 232   """
 233   def update_media(%{assigns: %{user: _}} = conn, %{"media_id" => id} = data) do
 234     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 235
 236     with %Object{} = object <- Repo.get(Object, id),
 237          is_binary(description) do
 238       new_data = Map.put(object.data, "name", description)
 239
 240       {:ok, _} =
 241         object
 242         |> Object.change(%{data: new_data})
 243         |> Repo.update()
 244     end
 245
 246     conn
 247     |> put_status(:no_content)
 248     |> json("")
 249   end
 250
 251   def upload(conn, %{"media" => media}) do
 252     response = TwitterAPI.upload(media)
 253
 254     conn
 255     |> put_resp_content_type("application/atom+xml")
 256     |> send_resp(200, response)
 257   end
 258
 259   def upload_json(conn, %{"media" => media}) do
 260     response = TwitterAPI.upload(media, "json")
 261
 262     conn
 263     |> json_reply(200, response)
 264   end
 265
 266   def get_by_id_or_ap_id(id) do
 267     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 268
 269     if activity.data["type"] == "Create" do
 270       activity
 271     else
 272       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 273     end
 274   end
 275
 276   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 277     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 278          {:ok, activity} <- TwitterAPI.fav(user, id) do
 279       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 280     end
 281   end
 282
 283   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 284     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 285          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 286       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 287     end
 288   end
 289
 290   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 291     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 292          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 293       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 294     end
 295   end
 296
 297   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 298     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 299          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 300       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 301     end
 302   end
 303
 304   def register(conn, params) do
 305     with {:ok, user} <- TwitterAPI.register_user(params) do
 306       render(conn, UserView, "show.json", %{user: user})
 307     else
 308       {:error, errors} ->
 309         conn
 310         |> json_reply(400, Jason.encode!(errors))
 311     end
 312   end
 313
 314   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 315     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 316     change = Changeset.change(user, %{avatar: object.data})
 317     {:ok, user} = User.update_and_set_cache(change)
 318     CommonAPI.update(user)
 319
 320     render(conn, UserView, "show.json", %{user: user, for: user})
 321   end
 322
 323   def update_banner(%{assigns: %{user: user}} = conn, params) do
 324     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 325          new_info <- %{"banner" => object.data},
 326          info_cng <- User.Info.profile_update(user.info, new_info),
 327          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 328          {:ok, user} <- User.update_and_set_cache(changeset) do
 329       CommonAPI.update(user)
 330       %{"url" => [%{"href" => href} | _]} = object.data
 331       response = %{url: href} |> Jason.encode!()
 332
 333       conn
 334       |> json_reply(200, response)
 335     end
 336   end
 337
 338   def update_background(%{assigns: %{user: user}} = conn, params) do
 339     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 340          new_info <- %{"background" => object.data},
 341          info_cng <- User.Info.profile_update(user.info, new_info),
 342          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 343          {:ok, _user} <- User.update_and_set_cache(changeset) do
 344       %{"url" => [%{"href" => href} | _]} = object.data
 345       response = %{url: href} |> Jason.encode!()
 346
 347       conn
 348       |> json_reply(200, response)
 349     end
 350   end
 351
 352   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 353     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 354          response <- Jason.encode!(user_map) do
 355       conn
 356       |> json_reply(200, response)
 357     else
 358       _e ->
 359         conn
 360         |> put_status(404)
 361         |> json(%{error: "Can't find user"})
 362     end
 363   end
 364
 365   def followers(conn, params) do
 366     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 367          {:ok, followers} <- User.get_followers(user) do
 368       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 369     else
 370       _e -> bad_request_reply(conn, "Can't get followers")
 371     end
 372   end
 373
 374   def friends(conn, params) do
 375     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 376          {:ok, friends} <- User.get_friends(user) do
 377       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 378     else
 379       _e -> bad_request_reply(conn, "Can't get friends")
 380     end
 381   end
 382
 383   def friend_requests(conn, params) do
 384     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 385          {:ok, friend_requests} <- User.get_follow_requests(user) do
 386       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 387     else
 388       _e -> bad_request_reply(conn, "Can't get friend requests")
 389     end
 390   end
 391
 392   def approve_friend_request(conn, %{"user_id" => uid} = params) do
 393     with followed <- conn.assigns[:user],
 394          uid when is_number(uid) <- String.to_integer(uid),
 395          %User{} = follower <- Repo.get(User, uid),
 396          {:ok, follower} <- User.maybe_follow(follower, followed),
 397          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 398          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 399          {:ok, _activity} <-
 400            ActivityPub.accept(%{
 401              to: [follower.ap_id],
 402              actor: followed.ap_id,
 403              object: follow_activity.data["id"],
 404              type: "Accept"
 405            }) do
 406       render(conn, UserView, "show.json", %{user: follower, for: followed})
 407     else
 408       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 409     end
 410   end
 411
 412   def deny_friend_request(conn, %{"user_id" => uid} = params) do
 413     with followed <- conn.assigns[:user],
 414          uid when is_number(uid) <- String.to_integer(uid),
 415          %User{} = follower <- Repo.get(User, uid),
 416          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 417          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 418          {:ok, _activity} <-
 419            ActivityPub.reject(%{
 420              to: [follower.ap_id],
 421              actor: followed.ap_id,
 422              object: follow_activity.data["id"],
 423              type: "Reject"
 424            }) do
 425       render(conn, UserView, "show.json", %{user: follower, for: followed})
 426     else
 427       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 428     end
 429   end
 430
 431   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 432     with {:ok, friends} <- User.get_friends(user) do
 433       ids =
 434         friends
 435         |> Enum.map(fn x -> x.id end)
 436         |> Jason.encode!()
 437
 438       json(conn, ids)
 439     else
 440       _e -> bad_request_reply(conn, "Can't get friends")
 441     end
 442   end
 443
 444   def empty_array(conn, _params) do
 445     json(conn, Jason.encode!([]))
 446   end
 447
 448   def raw_empty_array(conn, _params) do
 449     json(conn, [])
 450   end
 451
 452   defp build_info_cng(user, params) do
 453     info_params =
 454       ["no_rich_text", "locked"]
 455       |> Enum.reduce(%{}, fn key, res ->
 456         if value = params[key] do
 457           Map.put(res, key, value == "true")
 458         else
 459           res
 460         end
 461       end)
 462
 463     info_params =
 464       if value = params["default_scope"] do
 465         Map.put(info_params, "default_scope", value)
 466       else
 467         info_params
 468       end
 469
 470     User.Info.profile_update(user.info, info_params)
 471   end
 472
 473   defp parse_profile_bio(user, params) do
 474     if bio = params["description"] do
 475       Map.put(params, "bio", User.parse_bio(bio, user))
 476     else
 477       params
 478     end
 479   end
 480
 481   def update_profile(%{assigns: %{user: user}} = conn, params) do
 482     params = parse_profile_bio(user, params)
 483     info_cng = build_info_cng(user, params)
 484
 485     with changeset <- User.update_changeset(user, params),
 486          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 487          {:ok, user} <- User.update_and_set_cache(changeset) do
 488       CommonAPI.update(user)
 489       render(conn, UserView, "user.json", %{user: user, for: user})
 490     else
 491       error ->
 492         Logger.debug("Can't update user: #{inspect(error)}")
 493         bad_request_reply(conn, "Can't update user")
 494     end
 495   end
 496
 497   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 498     activities = TwitterAPI.search(user, params)
 499
 500     conn
 501     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 502   end
 503
 504   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 505     users = User.search(query, true)
 506
 507     conn
 508     |> render(UserView, "index.json", %{users: users, for: user})
 509   end
 510
 511   defp bad_request_reply(conn, error_message) do
 512     json = error_json(conn, error_message)
 513     json_reply(conn, 400, json)
 514   end
 515
 516   defp json_reply(conn, status, json) do
 517     conn
 518     |> put_resp_content_type("application/json")
 519     |> send_resp(status, json)
 520   end
 521
 522   defp forbidden_json_reply(conn, error_message) do
 523     json = error_json(conn, error_message)
 524     json_reply(conn, 403, json)
 525   end
 526
 527   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 528
 529   def only_if_public_instance(conn, _) do
 530     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 531       conn
 532     else
 533       conn
 534       |> forbidden_json_reply("Invalid credentials.")
 535       |> halt()
 536     end
 537   end
 538
 539   defp error_json(conn, error_message) do
 540     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 541   end
 542
 543   def errors(conn, {:param_cast, _}) do
 544     conn
 545     |> put_status(400)
 546     |> json("Invalid parameters")
 547   end
 548
 549   def errors(conn, _) do
 550     conn
 551     |> put_status(500)
 552     |> json("Something went wrong")
 553   end
 554 end