git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Formatter
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   7   alias Pleroma.{Repo, Activity, User, Notification}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Utils
  10   alias Ecto.Changeset
  11
  12   require Logger
  13
  14   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  15   action_fallback(:errors)
  16
  17   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  18     token = Phoenix.Token.sign(conn, "user socket", user.id)
  19     render(conn, UserView, "show.json", %{user: user, token: token})
  20   end
  21
  22   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  23     with media_ids <- extract_media_ids(status_data),
  24          {:ok, activity} <-
  25            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  26       conn
  27       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  28     else
  29       _ -> empty_status_reply(conn)
  30     end
  31   end
  32
  33   def status_update(conn, _status_data) do
  34     empty_status_reply(conn)
  35   end
  36
  37   defp empty_status_reply(conn) do
  38     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  39   end
  40
  41   defp extract_media_ids(status_data) do
  42     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  43          split_ids <- String.split(media_ids, ","),
  44          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  45       clean_ids
  46     else
  47       _e -> []
  48     end
  49   end
  50
  51   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  52     params =
  53       params
  54       |> Map.put("type", ["Create", "Announce"])
  55       |> Map.put("blocking_user", user)
  56
  57     activities = ActivityPub.fetch_public_activities(params)
  58
  59     conn
  60     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  61   end
  62
  63   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  64     params =
  65       params
  66       |> Map.put("type", ["Create", "Announce"])
  67       |> Map.put("local_only", true)
  68       |> Map.put("blocking_user", user)
  69
  70     activities = ActivityPub.fetch_public_activities(params)
  71
  72     conn
  73     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  74   end
  75
  76   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  77     params =
  78       params
  79       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  80       |> Map.put("blocking_user", user)
  81       |> Map.put("user", user)
  82
  83     activities =
  84       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  85       |> ActivityPub.contain_timeline(user)
  86
  87     conn
  88     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  89   end
  90
  91   def show_user(conn, params) do
  92     with {:ok, shown} <- TwitterAPI.get_user(params) do
  93       if user = conn.assigns.user do
  94         render(conn, UserView, "show.json", %{user: shown, for: user})
  95       else
  96         render(conn, UserView, "show.json", %{user: shown})
  97       end
  98     else
  99       {:error, msg} ->
 100         bad_request_reply(conn, msg)
 101     end
 102   end
 103
 104   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 105     case TwitterAPI.get_user(user, params) do
 106       {:ok, target_user} ->
 107         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 108
 109         conn
 110         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 111
 112       {:error, msg} ->
 113         bad_request_reply(conn, msg)
 114     end
 115   end
 116
 117   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 118     params =
 119       params
 120       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 121       |> Map.put("blocking_user", user)
 122
 123     activities = ActivityPub.fetch_activities([user.ap_id], params)
 124
 125     conn
 126     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 127   end
 128
 129   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 130     query =
 131       ActivityPub.fetch_activities_query(
 132         [user.ap_id],
 133         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 134       )
 135
 136     activities = Repo.all(query)
 137
 138     conn
 139     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 140   end
 141
 142   def notifications(%{assigns: %{user: user}} = conn, params) do
 143     notifications = Notification.for_user(user, params)
 144
 145     conn
 146     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 147   end
 148
 149   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 150     Notification.set_read_up_to(user, latest_id)
 151
 152     notifications = Notification.for_user(user, params)
 153
 154     conn
 155     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 156   end
 157
 158   def notifications_read(%{assigns: %{user: user}} = conn, _) do
 159     bad_request_reply(conn, "You need to specify latest_id")
 160   end
 161
 162   def follow(%{assigns: %{user: user}} = conn, params) do
 163     case TwitterAPI.follow(user, params) do
 164       {:ok, user, followed, _activity} ->
 165         render(conn, UserView, "show.json", %{user: followed, for: user})
 166
 167       {:error, msg} ->
 168         forbidden_json_reply(conn, msg)
 169     end
 170   end
 171
 172   def block(%{assigns: %{user: user}} = conn, params) do
 173     case TwitterAPI.block(user, params) do
 174       {:ok, user, blocked} ->
 175         render(conn, UserView, "show.json", %{user: blocked, for: user})
 176
 177       {:error, msg} ->
 178         forbidden_json_reply(conn, msg)
 179     end
 180   end
 181
 182   def unblock(%{assigns: %{user: user}} = conn, params) do
 183     case TwitterAPI.unblock(user, params) do
 184       {:ok, user, blocked} ->
 185         render(conn, UserView, "show.json", %{user: blocked, for: user})
 186
 187       {:error, msg} ->
 188         forbidden_json_reply(conn, msg)
 189     end
 190   end
 191
 192   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 193     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 194       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 195     end
 196   end
 197
 198   def unfollow(%{assigns: %{user: user}} = conn, params) do
 199     case TwitterAPI.unfollow(user, params) do
 200       {:ok, user, unfollowed} ->
 201         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 202
 203       {:error, msg} ->
 204         forbidden_json_reply(conn, msg)
 205     end
 206   end
 207
 208   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 209     with %Activity{} = activity <- Repo.get(Activity, id),
 210          true <- ActivityPub.visible_for_user?(activity, user) do
 211       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 212     end
 213   end
 214
 215   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 216     id = String.to_integer(id)
 217
 218     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 219          activities <-
 220            ActivityPub.fetch_activities_for_context(context, %{
 221              "blocking_user" => user,
 222              "user" => user
 223            }) do
 224       conn
 225       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 226     end
 227   end
 228
 229   def upload(conn, %{"media" => media}) do
 230     response = TwitterAPI.upload(media)
 231
 232     conn
 233     |> put_resp_content_type("application/atom+xml")
 234     |> send_resp(200, response)
 235   end
 236
 237   def upload_json(conn, %{"media" => media}) do
 238     response = TwitterAPI.upload(media, "json")
 239
 240     conn
 241     |> json_reply(200, response)
 242   end
 243
 244   def get_by_id_or_ap_id(id) do
 245     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 246
 247     if activity.data["type"] == "Create" do
 248       activity
 249     else
 250       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 251     end
 252   end
 253
 254   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 255     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 256          {:ok, activity} <- TwitterAPI.fav(user, id) do
 257       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 258     end
 259   end
 260
 261   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 262     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 263          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 264       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 265     end
 266   end
 267
 268   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 269     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 270          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 271       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 272     end
 273   end
 274
 275   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 276     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 277          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 278       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 279     end
 280   end
 281
 282   def register(conn, params) do
 283     with {:ok, user} <- TwitterAPI.register_user(params) do
 284       render(conn, UserView, "show.json", %{user: user})
 285     else
 286       {:error, errors} ->
 287         conn
 288         |> json_reply(400, Jason.encode!(errors))
 289     end
 290   end
 291
 292   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 293     upload_limit =
 294       Application.get_env(:pleroma, :instance)
 295       |> Keyword.fetch(:avatar_upload_limit)
 296
 297     {:ok, object} = ActivityPub.upload(params, upload_limit)
 298     change = Changeset.change(user, %{avatar: object.data})
 299     {:ok, user} = User.update_and_set_cache(change)
 300     CommonAPI.update(user)
 301
 302     render(conn, UserView, "show.json", %{user: user, for: user})
 303   end
 304
 305   def update_banner(%{assigns: %{user: user}} = conn, params) do
 306     upload_limit =
 307       Application.get_env(:pleroma, :instance)
 308       |> Keyword.fetch(:banner_upload_limit)
 309
 310     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, upload_limit),
 311          new_info <- Map.put(user.info, "banner", object.data),
 312          change <- User.info_changeset(user, %{info: new_info}),
 313          {:ok, user} <- User.update_and_set_cache(change) do
 314       CommonAPI.update(user)
 315       %{"url" => [%{"href" => href} | _]} = object.data
 316       response = %{url: href} |> Jason.encode!()
 317
 318       conn
 319       |> json_reply(200, response)
 320     end
 321   end
 322
 323   def update_background(%{assigns: %{user: user}} = conn, params) do
 324     upload_limit =
 325       Application.get_env(:pleroma, :instance)
 326       |> Keyword.fetch(:background_upload_limit)
 327
 328     with {:ok, object} <- ActivityPub.upload(params, upload_limit),
 329          new_info <- Map.put(user.info, "background", object.data),
 330          change <- User.info_changeset(user, %{info: new_info}),
 331          {:ok, _user} <- User.update_and_set_cache(change) do
 332       %{"url" => [%{"href" => href} | _]} = object.data
 333       response = %{url: href} |> Jason.encode!()
 334
 335       conn
 336       |> json_reply(200, response)
 337     end
 338   end
 339
 340   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 341     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 342          response <- Jason.encode!(user_map) do
 343       conn
 344       |> json_reply(200, response)
 345     else
 346       _e ->
 347         conn
 348         |> put_status(404)
 349         |> json(%{error: "Can't find user"})
 350     end
 351   end
 352
 353   def update_most_recent_notification(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 354     with id when is_number(id) <- String.to_integer(id),
 355          info <- user.info,
 356          mrn <- max(id, user.info["most_recent_notification"] || 0),
 357          updated_info <- Map.put(info, "most_recent_notification", mrn),
 358          changeset <- User.info_changeset(user, %{info: updated_info}),
 359          {:ok, _user} <- User.update_and_set_cache(changeset) do
 360       conn
 361       |> json_reply(200, Jason.encode!(mrn))
 362     else
 363       _e -> bad_request_reply(conn, "Can't update.")
 364     end
 365   end
 366
 367   def followers(conn, params) do
 368     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 369          {:ok, followers} <- User.get_followers(user) do
 370       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 371     else
 372       _e -> bad_request_reply(conn, "Can't get followers")
 373     end
 374   end
 375
 376   def friends(conn, params) do
 377     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 378          {:ok, friends} <- User.get_friends(user) do
 379       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 380     else
 381       _e -> bad_request_reply(conn, "Can't get friends")
 382     end
 383   end
 384
 385   def friend_requests(conn, params) do
 386     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 387          {:ok, friend_requests} <- User.get_follow_requests(user) do
 388       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 389     else
 390       _e -> bad_request_reply(conn, "Can't get friend requests")
 391     end
 392   end
 393
 394   def approve_friend_request(conn, %{"user_id" => uid} = params) do
 395     with followed <- conn.assigns[:user],
 396          uid when is_number(uid) <- String.to_integer(uid),
 397          %User{} = follower <- Repo.get(User, uid),
 398          {:ok, follower} <- User.maybe_follow(follower, followed),
 399          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 400          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 401          {:ok, _activity} <-
 402            ActivityPub.accept(%{
 403              to: [follower.ap_id],
 404              actor: followed.ap_id,
 405              object: follow_activity.data["id"],
 406              type: "Accept"
 407            }) do
 408       render(conn, UserView, "show.json", %{user: follower, for: followed})
 409     else
 410       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 411     end
 412   end
 413
 414   def deny_friend_request(conn, %{"user_id" => uid} = params) do
 415     with followed <- conn.assigns[:user],
 416          uid when is_number(uid) <- String.to_integer(uid),
 417          %User{} = follower <- Repo.get(User, uid),
 418          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 419          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 420          {:ok, _activity} <-
 421            ActivityPub.reject(%{
 422              to: [follower.ap_id],
 423              actor: followed.ap_id,
 424              object: follow_activity.data["id"],
 425              type: "Reject"
 426            }) do
 427       render(conn, UserView, "show.json", %{user: follower, for: followed})
 428     else
 429       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 430     end
 431   end
 432
 433   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 434     with {:ok, friends} <- User.get_friends(user) do
 435       ids =
 436         friends
 437         |> Enum.map(fn x -> x.id end)
 438         |> Jason.encode!()
 439
 440       json(conn, ids)
 441     else
 442       _e -> bad_request_reply(conn, "Can't get friends")
 443     end
 444   end
 445
 446   def empty_array(conn, _params) do
 447     json(conn, Jason.encode!([]))
 448   end
 449
 450   def raw_empty_array(conn, _params) do
 451     json(conn, [])
 452   end
 453
 454   def update_profile(%{assigns: %{user: user}} = conn, params) do
 455     params =
 456       if bio = params["description"] do
 457         mentions = Formatter.parse_mentions(bio)
 458         tags = Formatter.parse_tags(bio)
 459
 460         emoji =
 461           (user.info["source_data"]["tag"] || [])
 462           |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 463           |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 464             {String.trim(name, ":"), url}
 465           end)
 466
 467         bio_html = CommonUtils.format_input(bio, mentions, tags, "text/plain")
 468         Map.put(params, "bio", bio_html |> Formatter.emojify(emoji))
 469       else
 470         params
 471       end
 472
 473     user =
 474       if locked = params["locked"] do
 475         with locked <- locked == "true",
 476              new_info <- Map.put(user.info, "locked", locked),
 477              change <- User.info_changeset(user, %{info: new_info}),
 478              {:ok, user} <- User.update_and_set_cache(change) do
 479           user
 480         else
 481           _e -> user
 482         end
 483       else
 484         user
 485       end
 486
 487     user =
 488       if no_rich_text = params["no_rich_text"] do
 489         with no_rich_text <- no_rich_text == "true",
 490              new_info <- Map.put(user.info, "no_rich_text", no_rich_text),
 491              change <- User.info_changeset(user, %{info: new_info}),
 492              {:ok, user} <- User.update_and_set_cache(change) do
 493           user
 494         else
 495           _e -> user
 496         end
 497       else
 498         user
 499       end
 500
 501     user =
 502       if default_scope = params["default_scope"] do
 503         with new_info <- Map.put(user.info, "default_scope", default_scope),
 504              change <- User.info_changeset(user, %{info: new_info}),
 505              {:ok, user} <- User.update_and_set_cache(change) do
 506           user
 507         else
 508           _e -> user
 509         end
 510       else
 511         user
 512       end
 513
 514     with changeset <- User.update_changeset(user, params),
 515          {:ok, user} <- User.update_and_set_cache(changeset) do
 516       CommonAPI.update(user)
 517       render(conn, UserView, "user.json", %{user: user, for: user})
 518     else
 519       error ->
 520         Logger.debug("Can't update user: #{inspect(error)}")
 521         bad_request_reply(conn, "Can't update user")
 522     end
 523   end
 524
 525   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 526     activities = TwitterAPI.search(user, params)
 527
 528     conn
 529     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 530   end
 531
 532   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 533     users = User.search(query, true)
 534
 535     conn
 536     |> render(UserView, "index.json", %{users: users, for: user})
 537   end
 538
 539   defp bad_request_reply(conn, error_message) do
 540     json = error_json(conn, error_message)
 541     json_reply(conn, 400, json)
 542   end
 543
 544   defp json_reply(conn, status, json) do
 545     conn
 546     |> put_resp_content_type("application/json")
 547     |> send_resp(status, json)
 548   end
 549
 550   defp forbidden_json_reply(conn, error_message) do
 551     json = error_json(conn, error_message)
 552     json_reply(conn, 403, json)
 553   end
 554
 555   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 556
 557   def only_if_public_instance(conn, _) do
 558     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 559       conn
 560     else
 561       conn
 562       |> forbidden_json_reply("Invalid credentials.")
 563       |> halt()
 564     end
 565   end
 566
 567   defp error_json(conn, error_message) do
 568     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 569   end
 570
 571   def errors(conn, {:param_cast, _}) do
 572     conn
 573     |> put_status(400)
 574     |> json("Invalid parameters")
 575   end
 576
 577   def errors(conn, _) do
 578     conn
 579     |> put_status(500)
 580     |> json("Something went wrong")
 581   end
 582 end