git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   action_fallback(:errors)
  17
  18   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  19     token = Phoenix.Token.sign(conn, "user socket", user.id)
  20     render(conn, UserView, "show.json", %{user: user, token: token})
  21   end
  22
  23   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  24     with media_ids <- extract_media_ids(status_data),
  25          {:ok, activity} <-
  26            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  27       conn
  28       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  29     else
  30       _ -> empty_status_reply(conn)
  31     end
  32   end
  33
  34   def status_update(conn, _status_data) do
  35     empty_status_reply(conn)
  36   end
  37
  38   defp empty_status_reply(conn) do
  39     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  40   end
  41
  42   defp extract_media_ids(status_data) do
  43     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  44          split_ids <- String.split(media_ids, ","),
  45          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  46       clean_ids
  47     else
  48       _e -> []
  49     end
  50   end
  51
  52   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  53     params =
  54       params
  55       |> Map.put("type", ["Create", "Announce"])
  56       |> Map.put("blocking_user", user)
  57
  58     activities = ActivityPub.fetch_public_activities(params)
  59
  60     conn
  61     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  62   end
  63
  64   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  65     params =
  66       params
  67       |> Map.put("type", ["Create", "Announce"])
  68       |> Map.put("local_only", true)
  69       |> Map.put("blocking_user", user)
  70
  71     activities = ActivityPub.fetch_public_activities(params)
  72
  73     conn
  74     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  75   end
  76
  77   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  78     params =
  79       params
  80       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  81       |> Map.put("blocking_user", user)
  82       |> Map.put("user", user)
  83
  84     activities =
  85       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  86       |> ActivityPub.contain_timeline(user)
  87
  88     conn
  89     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  90   end
  91
  92   def show_user(conn, params) do
  93     with {:ok, shown} <- TwitterAPI.get_user(params) do
  94       if user = conn.assigns.user do
  95         render(conn, UserView, "show.json", %{user: shown, for: user})
  96       else
  97         render(conn, UserView, "show.json", %{user: shown})
  98       end
  99     else
 100       {:error, msg} ->
 101         bad_request_reply(conn, msg)
 102     end
 103   end
 104
 105   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 106     case TwitterAPI.get_user(user, params) do
 107       {:ok, target_user} ->
 108         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 109
 110         conn
 111         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 112
 113       {:error, msg} ->
 114         bad_request_reply(conn, msg)
 115     end
 116   end
 117
 118   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 119     params =
 120       params
 121       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 122       |> Map.put("blocking_user", user)
 123
 124     activities = ActivityPub.fetch_activities([user.ap_id], params)
 125
 126     conn
 127     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 128   end
 129
 130   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 131     query =
 132       ActivityPub.fetch_activities_query(
 133         [user.ap_id],
 134         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 135       )
 136
 137     activities = Repo.all(query)
 138
 139     conn
 140     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 141   end
 142
 143   def notifications(%{assigns: %{user: user}} = conn, params) do
 144     notifications = Notification.for_user(user, params)
 145
 146     conn
 147     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 148   end
 149
 150   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 151     Notification.set_read_up_to(user, latest_id)
 152
 153     notifications = Notification.for_user(user, params)
 154
 155     conn
 156     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 157   end
 158
 159   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 160     bad_request_reply(conn, "You need to specify latest_id")
 161   end
 162
 163   def follow(%{assigns: %{user: user}} = conn, params) do
 164     case TwitterAPI.follow(user, params) do
 165       {:ok, user, followed, _activity} ->
 166         render(conn, UserView, "show.json", %{user: followed, for: user})
 167
 168       {:error, msg} ->
 169         forbidden_json_reply(conn, msg)
 170     end
 171   end
 172
 173   def block(%{assigns: %{user: user}} = conn, params) do
 174     case TwitterAPI.block(user, params) do
 175       {:ok, user, blocked} ->
 176         render(conn, UserView, "show.json", %{user: blocked, for: user})
 177
 178       {:error, msg} ->
 179         forbidden_json_reply(conn, msg)
 180     end
 181   end
 182
 183   def unblock(%{assigns: %{user: user}} = conn, params) do
 184     case TwitterAPI.unblock(user, params) do
 185       {:ok, user, blocked} ->
 186         render(conn, UserView, "show.json", %{user: blocked, for: user})
 187
 188       {:error, msg} ->
 189         forbidden_json_reply(conn, msg)
 190     end
 191   end
 192
 193   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 194     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 195       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 196     end
 197   end
 198
 199   def unfollow(%{assigns: %{user: user}} = conn, params) do
 200     case TwitterAPI.unfollow(user, params) do
 201       {:ok, user, unfollowed} ->
 202         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 203
 204       {:error, msg} ->
 205         forbidden_json_reply(conn, msg)
 206     end
 207   end
 208
 209   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 210     with %Activity{} = activity <- Repo.get(Activity, id),
 211          true <- ActivityPub.visible_for_user?(activity, user) do
 212       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 213     end
 214   end
 215
 216   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 217     id = String.to_integer(id)
 218
 219     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 220          activities <-
 221            ActivityPub.fetch_activities_for_context(context, %{
 222              "blocking_user" => user,
 223              "user" => user
 224            }) do
 225       conn
 226       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 227     end
 228   end
 229
 230   @doc """
 231   Updates metadata of uploaded media object.
 232   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 233   """
 234   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 235     object = Repo.get(Object, id)
 236     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 237
 238     {conn, status, response_body} =
 239       cond do
 240         !object ->
 241           {halt(conn), :not_found, ""}
 242
 243         !Object.authorize_mutation(object, user) ->
 244           {halt(conn), :forbidden, "You can only update your own uploads."}
 245
 246         !is_binary(description) ->
 247           {conn, :not_modified, ""}
 248
 249         true ->
 250           new_data = Map.put(object.data, "name", description)
 251
 252           {:ok, _} =
 253             object
 254             |> Object.change(%{data: new_data})
 255             |> Repo.update()
 256
 257           {conn, :no_content, ""}
 258       end
 259
 260     conn
 261     |> put_status(status)
 262     |> json(response_body)
 263   end
 264
 265   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 266     response = TwitterAPI.upload(media, user)
 267
 268     conn
 269     |> put_resp_content_type("application/atom+xml")
 270     |> send_resp(200, response)
 271   end
 272
 273   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 274     response = TwitterAPI.upload(media, user, "json")
 275
 276     conn
 277     |> json_reply(200, response)
 278   end
 279
 280   def get_by_id_or_ap_id(id) do
 281     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 282
 283     if activity.data["type"] == "Create" do
 284       activity
 285     else
 286       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 287     end
 288   end
 289
 290   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 291     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 292          {:ok, activity} <- TwitterAPI.fav(user, id) do
 293       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 294     end
 295   end
 296
 297   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 298     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 299          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 300       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 301     end
 302   end
 303
 304   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 305     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 306          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 307       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 308     end
 309   end
 310
 311   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 312     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 313          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 314       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 315     end
 316   end
 317
 318   def register(conn, params) do
 319     with {:ok, user} <- TwitterAPI.register_user(params) do
 320       render(conn, UserView, "show.json", %{user: user})
 321     else
 322       {:error, errors} ->
 323         conn
 324         |> json_reply(400, Jason.encode!(errors))
 325     end
 326   end
 327
 328   def password_reset(conn, params) do
 329     nickname_or_email = params["email"] || params["nickname"]
 330
 331     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 332       json_response(conn, :no_content, "")
 333     end
 334   end
 335
 336   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 337     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 338     change = Changeset.change(user, %{avatar: object.data})
 339     {:ok, user} = User.update_and_set_cache(change)
 340     CommonAPI.update(user)
 341
 342     render(conn, UserView, "show.json", %{user: user, for: user})
 343   end
 344
 345   def update_banner(%{assigns: %{user: user}} = conn, params) do
 346     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 347          new_info <- %{"banner" => object.data},
 348          info_cng <- User.Info.profile_update(user.info, new_info),
 349          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 350          {:ok, user} <- User.update_and_set_cache(changeset) do
 351       CommonAPI.update(user)
 352       %{"url" => [%{"href" => href} | _]} = object.data
 353       response = %{url: href} |> Jason.encode!()
 354
 355       conn
 356       |> json_reply(200, response)
 357     end
 358   end
 359
 360   def update_background(%{assigns: %{user: user}} = conn, params) do
 361     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 362          new_info <- %{"background" => object.data},
 363          info_cng <- User.Info.profile_update(user.info, new_info),
 364          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 365          {:ok, _user} <- User.update_and_set_cache(changeset) do
 366       %{"url" => [%{"href" => href} | _]} = object.data
 367       response = %{url: href} |> Jason.encode!()
 368
 369       conn
 370       |> json_reply(200, response)
 371     end
 372   end
 373
 374   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 375     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 376          response <- Jason.encode!(user_map) do
 377       conn
 378       |> json_reply(200, response)
 379     else
 380       _e ->
 381         conn
 382         |> put_status(404)
 383         |> json(%{error: "Can't find user"})
 384     end
 385   end
 386
 387   def followers(%{assigns: %{user: for_user}} = conn, params) do
 388     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 389          {:ok, followers} <- User.get_followers(user) do
 390       followers =
 391         cond do
 392           for_user && user.id == for_user.id -> followers
 393           user.info.hide_network -> []
 394           true -> followers
 395         end
 396
 397       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 398     else
 399       _e -> bad_request_reply(conn, "Can't get followers")
 400     end
 401   end
 402
 403   def friends(%{assigns: %{user: for_user}} = conn, params) do
 404     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 405          {:ok, friends} <- User.get_friends(user) do
 406       friends =
 407         cond do
 408           for_user && user.id == for_user.id -> friends
 409           user.info.hide_network -> []
 410           true -> friends
 411         end
 412
 413       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 414     else
 415       _e -> bad_request_reply(conn, "Can't get friends")
 416     end
 417   end
 418
 419   def friend_requests(conn, params) do
 420     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 421          {:ok, friend_requests} <- User.get_follow_requests(user) do
 422       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 423     else
 424       _e -> bad_request_reply(conn, "Can't get friend requests")
 425     end
 426   end
 427
 428   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 429     with followed <- conn.assigns[:user],
 430          uid when is_number(uid) <- String.to_integer(uid),
 431          %User{} = follower <- Repo.get(User, uid),
 432          {:ok, follower} <- User.maybe_follow(follower, followed),
 433          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 434          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 435          {:ok, _activity} <-
 436            ActivityPub.accept(%{
 437              to: [follower.ap_id],
 438              actor: followed.ap_id,
 439              object: follow_activity.data["id"],
 440              type: "Accept"
 441            }) do
 442       render(conn, UserView, "show.json", %{user: follower, for: followed})
 443     else
 444       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 445     end
 446   end
 447
 448   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 449     with followed <- conn.assigns[:user],
 450          uid when is_number(uid) <- String.to_integer(uid),
 451          %User{} = follower <- Repo.get(User, uid),
 452          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 453          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 454          {:ok, _activity} <-
 455            ActivityPub.reject(%{
 456              to: [follower.ap_id],
 457              actor: followed.ap_id,
 458              object: follow_activity.data["id"],
 459              type: "Reject"
 460            }) do
 461       render(conn, UserView, "show.json", %{user: follower, for: followed})
 462     else
 463       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 464     end
 465   end
 466
 467   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 468     with {:ok, friends} <- User.get_friends(user) do
 469       ids =
 470         friends
 471         |> Enum.map(fn x -> x.id end)
 472         |> Jason.encode!()
 473
 474       json(conn, ids)
 475     else
 476       _e -> bad_request_reply(conn, "Can't get friends")
 477     end
 478   end
 479
 480   def empty_array(conn, _params) do
 481     json(conn, Jason.encode!([]))
 482   end
 483
 484   def raw_empty_array(conn, _params) do
 485     json(conn, [])
 486   end
 487
 488   defp build_info_cng(user, params) do
 489     info_params =
 490       ["no_rich_text", "locked", "hide_network"]
 491       |> Enum.reduce(%{}, fn key, res ->
 492         if value = params[key] do
 493           Map.put(res, key, value == "true")
 494         else
 495           res
 496         end
 497       end)
 498
 499     info_params =
 500       if value = params["default_scope"] do
 501         Map.put(info_params, "default_scope", value)
 502       else
 503         info_params
 504       end
 505
 506     User.Info.profile_update(user.info, info_params)
 507   end
 508
 509   defp parse_profile_bio(user, params) do
 510     if bio = params["description"] do
 511       Map.put(params, "bio", User.parse_bio(bio, user))
 512     else
 513       params
 514     end
 515   end
 516
 517   def update_profile(%{assigns: %{user: user}} = conn, params) do
 518     params = parse_profile_bio(user, params)
 519     info_cng = build_info_cng(user, params)
 520
 521     with changeset <- User.update_changeset(user, params),
 522          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 523          {:ok, user} <- User.update_and_set_cache(changeset) do
 524       CommonAPI.update(user)
 525       render(conn, UserView, "user.json", %{user: user, for: user})
 526     else
 527       error ->
 528         Logger.debug("Can't update user: #{inspect(error)}")
 529         bad_request_reply(conn, "Can't update user")
 530     end
 531   end
 532
 533   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 534     activities = TwitterAPI.search(user, params)
 535
 536     conn
 537     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 538   end
 539
 540   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 541     users = User.search(query, true)
 542
 543     conn
 544     |> render(UserView, "index.json", %{users: users, for: user})
 545   end
 546
 547   defp bad_request_reply(conn, error_message) do
 548     json = error_json(conn, error_message)
 549     json_reply(conn, 400, json)
 550   end
 551
 552   defp json_reply(conn, status, json) do
 553     conn
 554     |> put_resp_content_type("application/json")
 555     |> send_resp(status, json)
 556   end
 557
 558   defp forbidden_json_reply(conn, error_message) do
 559     json = error_json(conn, error_message)
 560     json_reply(conn, 403, json)
 561   end
 562
 563   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 564
 565   def only_if_public_instance(conn, _) do
 566     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 567       conn
 568     else
 569       conn
 570       |> forbidden_json_reply("Invalid credentials.")
 571       |> halt()
 572     end
 573   end
 574
 575   defp error_json(conn, error_message) do
 576     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 577   end
 578
 579   def errors(conn, {:param_cast, _}) do
 580     conn
 581     |> put_status(400)
 582     |> json("Invalid parameters")
 583   end
 584
 585   def errors(conn, _) do
 586     conn
 587     |> put_status(500)
 588     |> json("Something went wrong")
 589   end
 590 end