git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Formatter
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   7   alias Pleroma.{Repo, Activity, User, Notification}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Utils
  10   alias Ecto.Changeset
  11
  12   require Logger
  13
  14   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  15   action_fallback(:errors)
  16
  17   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  18     token = Phoenix.Token.sign(conn, "user socket", user.id)
  19     render(conn, UserView, "show.json", %{user: user, token: token})
  20   end
  21
  22   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  23     with media_ids <- extract_media_ids(status_data),
  24          {:ok, activity} <-
  25            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  26       conn
  27       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  28     else
  29       _ -> empty_status_reply(conn)
  30     end
  31   end
  32
  33   def status_update(conn, _status_data) do
  34     empty_status_reply(conn)
  35   end
  36
  37   defp empty_status_reply(conn) do
  38     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  39   end
  40
  41   defp extract_media_ids(status_data) do
  42     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  43          split_ids <- String.split(media_ids, ","),
  44          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  45       clean_ids
  46     else
  47       _e -> []
  48     end
  49   end
  50
  51   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  52     params =
  53       params
  54       |> Map.put("type", ["Create", "Announce"])
  55       |> Map.put("blocking_user", user)
  56
  57     activities = ActivityPub.fetch_public_activities(params)
  58
  59     conn
  60     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  61   end
  62
  63   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  64     params =
  65       params
  66       |> Map.put("type", ["Create", "Announce"])
  67       |> Map.put("local_only", true)
  68       |> Map.put("blocking_user", user)
  69
  70     activities = ActivityPub.fetch_public_activities(params)
  71
  72     conn
  73     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  74   end
  75
  76   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  77     params =
  78       params
  79       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  80       |> Map.put("blocking_user", user)
  81       |> Map.put("user", user)
  82
  83     activities =
  84       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  85       |> ActivityPub.contain_timeline(user)
  86
  87     conn
  88     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  89   end
  90
  91   def show_user(conn, params) do
  92     with {:ok, shown} <- TwitterAPI.get_user(params) do
  93       if user = conn.assigns.user do
  94         render(conn, UserView, "show.json", %{user: shown, for: user})
  95       else
  96         render(conn, UserView, "show.json", %{user: shown})
  97       end
  98     else
  99       {:error, msg} ->
 100         bad_request_reply(conn, msg)
 101     end
 102   end
 103
 104   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 105     case TwitterAPI.get_user(user, params) do
 106       {:ok, target_user} ->
 107         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 108
 109         conn
 110         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 111
 112       {:error, msg} ->
 113         bad_request_reply(conn, msg)
 114     end
 115   end
 116
 117   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 118     params =
 119       params
 120       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 121       |> Map.put("blocking_user", user)
 122
 123     activities = ActivityPub.fetch_activities([user.ap_id], params)
 124
 125     conn
 126     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 127   end
 128
 129   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 130     query =
 131       ActivityPub.fetch_activities_query(
 132         [user.ap_id],
 133         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 134       )
 135
 136     activities = Repo.all(query)
 137
 138     conn
 139     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 140   end
 141
 142   def notifications(%{assigns: %{user: user}} = conn, params) do
 143     notifications = Notification.for_user(user, params)
 144
 145     conn
 146     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 147   end
 148
 149   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 150     Notification.set_read_up_to(user, latest_id)
 151
 152     notifications = Notification.for_user(user, params)
 153
 154     conn
 155     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 156   end
 157
 158   def notifications_read(%{assigns: %{user: user}} = conn, _) do
 159     bad_request_reply(conn, "You need to specify latest_id")
 160   end
 161
 162   def follow(%{assigns: %{user: user}} = conn, params) do
 163     case TwitterAPI.follow(user, params) do
 164       {:ok, user, followed, _activity} ->
 165         render(conn, UserView, "show.json", %{user: followed, for: user})
 166
 167       {:error, msg} ->
 168         forbidden_json_reply(conn, msg)
 169     end
 170   end
 171
 172   def block(%{assigns: %{user: user}} = conn, params) do
 173     case TwitterAPI.block(user, params) do
 174       {:ok, user, blocked} ->
 175         render(conn, UserView, "show.json", %{user: blocked, for: user})
 176
 177       {:error, msg} ->
 178         forbidden_json_reply(conn, msg)
 179     end
 180   end
 181
 182   def unblock(%{assigns: %{user: user}} = conn, params) do
 183     case TwitterAPI.unblock(user, params) do
 184       {:ok, user, blocked} ->
 185         render(conn, UserView, "show.json", %{user: blocked, for: user})
 186
 187       {:error, msg} ->
 188         forbidden_json_reply(conn, msg)
 189     end
 190   end
 191
 192   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 193     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 194       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 195     end
 196   end
 197
 198   def unfollow(%{assigns: %{user: user}} = conn, params) do
 199     case TwitterAPI.unfollow(user, params) do
 200       {:ok, user, unfollowed} ->
 201         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 202
 203       {:error, msg} ->
 204         forbidden_json_reply(conn, msg)
 205     end
 206   end
 207
 208   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 209     with %Activity{} = activity <- Repo.get(Activity, id),
 210          true <- ActivityPub.visible_for_user?(activity, user) do
 211       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 212     end
 213   end
 214
 215   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 216     id = String.to_integer(id)
 217
 218     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 219          activities <-
 220            ActivityPub.fetch_activities_for_context(context, %{
 221              "blocking_user" => user,
 222              "user" => user
 223            }) do
 224       conn
 225       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 226     end
 227   end
 228
 229   def upload(conn, %{"media" => media}) do
 230     response = TwitterAPI.upload(media)
 231
 232     conn
 233     |> put_resp_content_type("application/atom+xml")
 234     |> send_resp(200, response)
 235   end
 236
 237   def upload_json(conn, %{"media" => media}) do
 238     response = TwitterAPI.upload(media, "json")
 239
 240     conn
 241     |> json_reply(200, response)
 242   end
 243
 244   def get_by_id_or_ap_id(id) do
 245     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 246
 247     if activity.data["type"] == "Create" do
 248       activity
 249     else
 250       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 251     end
 252   end
 253
 254   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 255     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 256          {:ok, activity} <- TwitterAPI.fav(user, id) do
 257       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 258     end
 259   end
 260
 261   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 262     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 263          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 264       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 265     end
 266   end
 267
 268   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 269     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 270          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 271       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 272     end
 273   end
 274
 275   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 276     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 277          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 278       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 279     end
 280   end
 281
 282   def register(conn, params) do
 283     with {:ok, user} <- TwitterAPI.register_user(params) do
 284       render(conn, UserView, "show.json", %{user: user})
 285     else
 286       {:error, errors} ->
 287         conn
 288         |> json_reply(400, Jason.encode!(errors))
 289     end
 290   end
 291
 292   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 293     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 294     change = Changeset.change(user, %{avatar: object.data})
 295     {:ok, user} = User.update_and_set_cache(change)
 296     CommonAPI.update(user)
 297
 298     render(conn, UserView, "show.json", %{user: user, for: user})
 299   end
 300
 301   def update_banner(%{assigns: %{user: user}} = conn, params) do
 302     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 303          new_info <- %{"banner" => object.data},
 304          info_cng <- User.Info.profile_update(user.info, new_info),
 305          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 306          {:ok, user} <- User.update_and_set_cache(changeset) do
 307       CommonAPI.update(user)
 308       %{"url" => [%{"href" => href} | _]} = object.data
 309       response = %{url: href} |> Jason.encode!()
 310
 311       conn
 312       |> json_reply(200, response)
 313     end
 314   end
 315
 316   def update_background(%{assigns: %{user: user}} = conn, params) do
 317     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 318          new_info <- %{"background" => object.data},
 319          info_cng <- User.Info.profile_update(user.info, new_info),
 320          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 321          {:ok, _user} <- User.update_and_set_cache(changeset) do
 322       %{"url" => [%{"href" => href} | _]} = object.data
 323       response = %{url: href} |> Jason.encode!()
 324
 325       conn
 326       |> json_reply(200, response)
 327     end
 328   end
 329
 330   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 331     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 332          response <- Jason.encode!(user_map) do
 333       conn
 334       |> json_reply(200, response)
 335     else
 336       _e ->
 337         conn
 338         |> put_status(404)
 339         |> json(%{error: "Can't find user"})
 340     end
 341   end
 342
 343   def followers(conn, params) do
 344     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 345          {:ok, followers} <- User.get_followers(user) do
 346       followers = if(user.info.hide_network, do: [], else: followers)
 347       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 348     else
 349       _e -> bad_request_reply(conn, "Can't get followers")
 350     end
 351   end
 352
 353   def friends(conn, params) do
 354     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 355          {:ok, friends} <- User.get_friends(user) do
 356       friends = if(user.info.hide_network, do: [], else: friends)
 357       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 358     else
 359       _e -> bad_request_reply(conn, "Can't get friends")
 360     end
 361   end
 362
 363   def friend_requests(conn, params) do
 364     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 365          {:ok, friend_requests} <- User.get_follow_requests(user) do
 366       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 367     else
 368       _e -> bad_request_reply(conn, "Can't get friend requests")
 369     end
 370   end
 371
 372   def approve_friend_request(conn, %{"user_id" => uid} = params) do
 373     with followed <- conn.assigns[:user],
 374          uid when is_number(uid) <- String.to_integer(uid),
 375          %User{} = follower <- Repo.get(User, uid),
 376          {:ok, follower} <- User.maybe_follow(follower, followed),
 377          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 378          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 379          {:ok, _activity} <-
 380            ActivityPub.accept(%{
 381              to: [follower.ap_id],
 382              actor: followed.ap_id,
 383              object: follow_activity.data["id"],
 384              type: "Accept"
 385            }) do
 386       render(conn, UserView, "show.json", %{user: follower, for: followed})
 387     else
 388       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 389     end
 390   end
 391
 392   def deny_friend_request(conn, %{"user_id" => uid} = params) do
 393     with followed <- conn.assigns[:user],
 394          uid when is_number(uid) <- String.to_integer(uid),
 395          %User{} = follower <- Repo.get(User, uid),
 396          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 397          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 398          {:ok, _activity} <-
 399            ActivityPub.reject(%{
 400              to: [follower.ap_id],
 401              actor: followed.ap_id,
 402              object: follow_activity.data["id"],
 403              type: "Reject"
 404            }) do
 405       render(conn, UserView, "show.json", %{user: follower, for: followed})
 406     else
 407       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 408     end
 409   end
 410
 411   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 412     with {:ok, friends} <- User.get_friends(user) do
 413       ids =
 414         friends
 415         |> Enum.map(fn x -> x.id end)
 416         |> Jason.encode!()
 417
 418       json(conn, ids)
 419     else
 420       _e -> bad_request_reply(conn, "Can't get friends")
 421     end
 422   end
 423
 424   def empty_array(conn, _params) do
 425     json(conn, Jason.encode!([]))
 426   end
 427
 428   def raw_empty_array(conn, _params) do
 429     json(conn, [])
 430   end
 431
 432   defp build_info_cng(user, params) do
 433     info_params =
 434       ["no_rich_text", "locked", "hide_network"]
 435       |> Enum.reduce(%{}, fn key, res ->
 436         if value = params[key] do
 437           Map.put(res, key, value == "true")
 438         else
 439           res
 440         end
 441       end)
 442
 443     info_params =
 444       if value = params["default_scope"] do
 445         Map.put(info_params, "default_scope", value)
 446       else
 447         info_params
 448       end
 449
 450     User.Info.profile_update(user.info, info_params)
 451   end
 452
 453   defp add_profile_emoji(user, params) do
 454     if bio = params["description"] do
 455       mentions = Formatter.parse_mentions(bio)
 456       tags = Formatter.parse_tags(bio)
 457
 458       emoji =
 459         (user.info.source_data["tag"] || [])
 460         |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 461         |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 462           {String.trim(name, ":"), url}
 463         end)
 464
 465       bio_html = CommonUtils.format_input(bio, mentions, tags, "text/plain")
 466       Map.put(params, "bio", bio_html |> Formatter.emojify(emoji))
 467     else
 468       params
 469     end
 470   end
 471
 472   def update_profile(%{assigns: %{user: user}} = conn, params) do
 473     params = add_profile_emoji(user, params)
 474     info_cng = build_info_cng(user, params)
 475
 476     with changeset <- User.update_changeset(user, params),
 477          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 478          {:ok, user} <- User.update_and_set_cache(changeset) do
 479       CommonAPI.update(user)
 480       render(conn, UserView, "user.json", %{user: user, for: user})
 481     else
 482       error ->
 483         Logger.debug("Can't update user: #{inspect(error)}")
 484         bad_request_reply(conn, "Can't update user")
 485     end
 486   end
 487
 488   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 489     activities = TwitterAPI.search(user, params)
 490
 491     conn
 492     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 493   end
 494
 495   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 496     users = User.search(query, true)
 497
 498     conn
 499     |> render(UserView, "index.json", %{users: users, for: user})
 500   end
 501
 502   defp bad_request_reply(conn, error_message) do
 503     json = error_json(conn, error_message)
 504     json_reply(conn, 400, json)
 505   end
 506
 507   defp json_reply(conn, status, json) do
 508     conn
 509     |> put_resp_content_type("application/json")
 510     |> send_resp(status, json)
 511   end
 512
 513   defp forbidden_json_reply(conn, error_message) do
 514     json = error_json(conn, error_message)
 515     json_reply(conn, 403, json)
 516   end
 517
 518   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 519
 520   def only_if_public_instance(conn, _) do
 521     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 522       conn
 523     else
 524       conn
 525       |> forbidden_json_reply("Invalid credentials.")
 526       |> halt()
 527     end
 528   end
 529
 530   defp error_json(conn, error_message) do
 531     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 532   end
 533
 534   def errors(conn, {:param_cast, _}) do
 535     conn
 536     |> put_status(400)
 537     |> json("Invalid parameters")
 538   end
 539
 540   def errors(conn, _) do
 541     conn
 542     |> put_status(500)
 543     |> json("Something went wrong")
 544   end
 545 end