git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView}
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.{Repo, Activity, User}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Ecto.Changeset
   8
   9   require Logger
  10
  11   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  12     render(conn, UserView, "show.json", %{user: user})
  13   end
  14
  15   def status_update(%{assigns: %{user: user}} = conn, %{"status" => status_text} = status_data) do
  16     l = status_text |> String.trim |> String.length
  17     if l > 0 && l < 5000 do
  18       media_ids = extract_media_ids(status_data)
  19       {:ok, activity} = TwitterAPI.create_status(user, Map.put(status_data, "media_ids",  media_ids))
  20       conn
  21       |> json_reply(200, ActivityRepresenter.to_json(activity, %{user: user}))
  22     else
  23       empty_status_reply(conn)
  24     end
  25   end
  26
  27   def status_update(conn, _status_data) do
  28     empty_status_reply(conn)
  29   end
  30
  31   defp empty_status_reply(conn) do
  32     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  33   end
  34
  35   defp extract_media_ids(status_data) do
  36     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  37          split_ids <- String.split(media_ids, ","),
  38          clean_ids <- Enum.reject(split_ids, fn (id) -> String.length(id) == 0 end)
  39       do
  40         clean_ids
  41       else _e -> []
  42     end
  43   end
  44
  45   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  46     statuses = TwitterAPI.fetch_public_and_external_statuses(user, params)
  47     {:ok, json} = Poison.encode(statuses)
  48
  49     conn
  50     |> json_reply(200, json)
  51   end
  52
  53   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  54     statuses = TwitterAPI.fetch_public_statuses(user, params)
  55     {:ok, json} = Poison.encode(statuses)
  56
  57     conn
  58     |> json_reply(200, json)
  59   end
  60
  61   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  62     statuses = TwitterAPI.fetch_friend_statuses(user, params)
  63     {:ok, json} = Poison.encode(statuses)
  64
  65     conn
  66     |> json_reply(200, json)
  67   end
  68
  69   def user_timeline(%{assigns: %{user: user}} = conn, params) do
  70     case TwitterAPI.get_user(user, params) do
  71       {:ok, target_user} ->
  72         params = Map.merge(params, %{"actor_id" => target_user.ap_id})
  73         statuses  = TwitterAPI.fetch_user_statuses(user, params)
  74         conn
  75         |> json_reply(200, statuses |> Poison.encode!)
  76       {:error, msg} ->
  77         bad_request_reply(conn, msg)
  78     end
  79   end
  80
  81   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
  82     statuses = TwitterAPI.fetch_mentions(user, params)
  83     {:ok, json} = Poison.encode(statuses)
  84
  85     conn
  86     |> json_reply(200, json)
  87   end
  88
  89   def follow(%{assigns: %{user: user}} = conn, params) do
  90     case TwitterAPI.follow(user, params) do
  91       {:ok, user, followed, _activity} ->
  92         render(conn, UserView, "show.json", %{user: followed, for: user})
  93       {:error, msg} -> forbidden_json_reply(conn, msg)
  94     end
  95   end
  96
  97   def unfollow(%{assigns: %{user: user}} = conn, params) do
  98     case TwitterAPI.unfollow(user, params) do
  99       {:ok, user, unfollowed} ->
 100         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 101       {:error, msg} -> forbidden_json_reply(conn, msg)
 102     end
 103   end
 104
 105   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 106     response = Poison.encode!(TwitterAPI.fetch_status(user, id))
 107
 108     conn
 109     |> json_reply(200, response)
 110   end
 111
 112   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 113     id = String.to_integer(id)
 114     response = Poison.encode!(TwitterAPI.fetch_conversation(user, id))
 115
 116     conn
 117     |> json_reply(200, response)
 118   end
 119
 120   def upload(conn, %{"media" => media}) do
 121     response = TwitterAPI.upload(media)
 122     conn
 123     |> put_resp_content_type("application/atom+xml")
 124     |> send_resp(200, response)
 125   end
 126
 127   def upload_json(conn, %{"media" => media}) do
 128     response = TwitterAPI.upload(media, "json")
 129     conn
 130     |> json_reply(200, response)
 131   end
 132
 133   def get_by_id_or_ap_id(id) do
 134     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 135     if activity.data["type"] == "Create" do
 136       activity
 137     else
 138       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 139     end
 140   end
 141
 142   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 143     activity = get_by_id_or_ap_id(id)
 144     {:ok, status} = TwitterAPI.favorite(user, activity)
 145     response = Poison.encode!(status)
 146
 147     conn
 148     |> json_reply(200, response)
 149   end
 150
 151   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 152     activity = get_by_id_or_ap_id(id)
 153     {:ok, status} = TwitterAPI.unfavorite(user, activity)
 154     response = Poison.encode!(status)
 155
 156     conn
 157     |> json_reply(200, response)
 158   end
 159
 160   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 161     activity = get_by_id_or_ap_id(id)
 162     if activity.data["actor"] == user.ap_id do
 163       bad_request_reply(conn, "You cannot repeat your own notice.")
 164     else
 165       {:ok, status} = TwitterAPI.retweet(user, activity)
 166       response = Poison.encode!(status)
 167
 168       conn
 169
 170       |> json_reply(200, response)
 171     end
 172   end
 173
 174   def register(conn, params) do
 175     with {:ok, user} <- TwitterAPI.register_user(params) do
 176
 177       render(conn, UserView, "show.json", %{user: user})
 178     else
 179       {:error, errors} ->
 180       conn
 181       |> json_reply(400, Poison.encode!(errors))
 182     end
 183   end
 184
 185   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 186     {:ok, object} = ActivityPub.upload(params)
 187     change = Changeset.change(user, %{avatar: object.data})
 188     {:ok, user} = Repo.update(change)
 189
 190     render(conn, UserView, "show.json", %{user: user, for: user})
 191   end
 192
 193   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 194     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 195          response <- Poison.encode!(user_map) do
 196       conn
 197       |> json_reply(200, response)
 198     end
 199   end
 200
 201   def update_most_recent_notification(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 202     with id when is_number(id) <- String.to_integer(id),
 203          info <- user.info,
 204          mrn <- max(id, user.info["most_recent_notification"] || 0),
 205          updated_info <- Map.put(info, "most_recent_notification", mrn),
 206          changeset <- User.info_changeset(user, %{info: updated_info}),
 207          {:ok, user} <- Repo.update(changeset) do
 208       conn
 209       |> json_reply(200, Poison.encode!(mrn))
 210     else
 211       _e -> bad_request_reply(conn, "Can't update.")
 212     end
 213   end
 214
 215   def followers(%{assigns: %{user: user}} = conn, _params) do
 216     with {:ok, followers} <- User.get_followers(user) do
 217       render(conn, UserView, "index.json", %{users: followers, for: user})
 218     else
 219       _e -> bad_request_reply(conn, "Can't get followers")
 220     end
 221   end
 222
 223   def friends(%{assigns: %{user: user}} = conn, _params) do
 224     with {:ok, friends} <- User.get_friends(user) do
 225       render(conn, UserView, "index.json", %{users: friends, for: user})
 226     else
 227       _e -> bad_request_reply(conn, "Can't get friends")
 228     end
 229   end
 230
 231   def update_profile(%{assigns: %{user: user}} = conn, params) do
 232     if bio = params["description"] do
 233       params = Map.put(params, "bio", bio)
 234     end
 235
 236     with changeset <- User.update_changeset(user, params),
 237          {:ok, user} <- Repo.update(changeset) do
 238       render(conn, UserView, "user.json", %{user: user, for: user})
 239     else
 240       error ->
 241         Logger.debug("Can't update user: #{inspect(error)}")
 242         bad_request_reply(conn, "Can't update user")
 243     end
 244   end
 245
 246   defp bad_request_reply(conn, error_message) do
 247     json = error_json(conn, error_message)
 248     json_reply(conn, 400, json)
 249   end
 250
 251   defp json_reply(conn, status, json) do
 252     conn
 253     |> put_resp_content_type("application/json")
 254     |> send_resp(status, json)
 255   end
 256
 257   defp forbidden_json_reply(conn, error_message) do
 258     json = error_json(conn, error_message)
 259     json_reply(conn, 403, json)
 260   end
 261
 262   defp error_json(conn, error_message) do
 263     %{"error" => error_message, "request" => conn.request_path} |> Poison.encode!
 264   end
 265 end