git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   action_fallback(:errors)
  17
  18   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  19     token = Phoenix.Token.sign(conn, "user socket", user.id)
  20     render(conn, UserView, "show.json", %{user: user, token: token})
  21   end
  22
  23   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  24     with media_ids <- extract_media_ids(status_data),
  25          {:ok, activity} <-
  26            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  27       conn
  28       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  29     else
  30       _ -> empty_status_reply(conn)
  31     end
  32   end
  33
  34   def status_update(conn, _status_data) do
  35     empty_status_reply(conn)
  36   end
  37
  38   defp empty_status_reply(conn) do
  39     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  40   end
  41
  42   defp extract_media_ids(status_data) do
  43     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  44          split_ids <- String.split(media_ids, ","),
  45          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  46       clean_ids
  47     else
  48       _e -> []
  49     end
  50   end
  51
  52   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  53     params =
  54       params
  55       |> Map.put("type", ["Create", "Announce"])
  56       |> Map.put("blocking_user", user)
  57
  58     activities = ActivityPub.fetch_public_activities(params)
  59
  60     conn
  61     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  62   end
  63
  64   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  65     params =
  66       params
  67       |> Map.put("type", ["Create", "Announce"])
  68       |> Map.put("local_only", true)
  69       |> Map.put("blocking_user", user)
  70
  71     activities = ActivityPub.fetch_public_activities(params)
  72
  73     conn
  74     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  75   end
  76
  77   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  78     params =
  79       params
  80       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  81       |> Map.put("blocking_user", user)
  82       |> Map.put("user", user)
  83
  84     activities =
  85       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  86       |> ActivityPub.contain_timeline(user)
  87
  88     conn
  89     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  90   end
  91
  92   def show_user(conn, params) do
  93     with {:ok, shown} <- TwitterAPI.get_user(params) do
  94       if user = conn.assigns.user do
  95         render(conn, UserView, "show.json", %{user: shown, for: user})
  96       else
  97         render(conn, UserView, "show.json", %{user: shown})
  98       end
  99     else
 100       {:error, msg} ->
 101         bad_request_reply(conn, msg)
 102     end
 103   end
 104
 105   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 106     case TwitterAPI.get_user(user, params) do
 107       {:ok, target_user} ->
 108         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 109
 110         conn
 111         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 112
 113       {:error, msg} ->
 114         bad_request_reply(conn, msg)
 115     end
 116   end
 117
 118   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 119     params =
 120       params
 121       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 122       |> Map.put("blocking_user", user)
 123
 124     activities = ActivityPub.fetch_activities([user.ap_id], params)
 125
 126     conn
 127     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 128   end
 129
 130   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 131     query =
 132       ActivityPub.fetch_activities_query(
 133         [user.ap_id],
 134         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 135       )
 136
 137     activities = Repo.all(query)
 138
 139     conn
 140     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 141   end
 142
 143   def notifications(%{assigns: %{user: user}} = conn, params) do
 144     notifications = Notification.for_user(user, params)
 145
 146     conn
 147     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 148   end
 149
 150   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 151     Notification.set_read_up_to(user, latest_id)
 152
 153     notifications = Notification.for_user(user, params)
 154
 155     conn
 156     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 157   end
 158
 159   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 160     bad_request_reply(conn, "You need to specify latest_id")
 161   end
 162
 163   def follow(%{assigns: %{user: user}} = conn, params) do
 164     case TwitterAPI.follow(user, params) do
 165       {:ok, user, followed, _activity} ->
 166         render(conn, UserView, "show.json", %{user: followed, for: user})
 167
 168       {:error, msg} ->
 169         forbidden_json_reply(conn, msg)
 170     end
 171   end
 172
 173   def block(%{assigns: %{user: user}} = conn, params) do
 174     case TwitterAPI.block(user, params) do
 175       {:ok, user, blocked} ->
 176         render(conn, UserView, "show.json", %{user: blocked, for: user})
 177
 178       {:error, msg} ->
 179         forbidden_json_reply(conn, msg)
 180     end
 181   end
 182
 183   def unblock(%{assigns: %{user: user}} = conn, params) do
 184     case TwitterAPI.unblock(user, params) do
 185       {:ok, user, blocked} ->
 186         render(conn, UserView, "show.json", %{user: blocked, for: user})
 187
 188       {:error, msg} ->
 189         forbidden_json_reply(conn, msg)
 190     end
 191   end
 192
 193   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 194     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 195       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 196     end
 197   end
 198
 199   def unfollow(%{assigns: %{user: user}} = conn, params) do
 200     case TwitterAPI.unfollow(user, params) do
 201       {:ok, user, unfollowed} ->
 202         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 203
 204       {:error, msg} ->
 205         forbidden_json_reply(conn, msg)
 206     end
 207   end
 208
 209   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 210     with %Activity{} = activity <- Repo.get(Activity, id),
 211          true <- ActivityPub.visible_for_user?(activity, user) do
 212       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 213     end
 214   end
 215
 216   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 217     id = String.to_integer(id)
 218
 219     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 220          activities <-
 221            ActivityPub.fetch_activities_for_context(context, %{
 222              "blocking_user" => user,
 223              "user" => user
 224            }) do
 225       conn
 226       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 227     end
 228   end
 229
 230   @doc """
 231   Updates metadata of uploaded media object.
 232   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 233   """
 234   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 235     object = Repo.get(Object, id)
 236     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 237
 238     {conn, status, response_body} =
 239       cond do
 240         !object ->
 241           {halt(conn), :not_found, ""}
 242
 243         !Object.authorize_mutation(object, user) ->
 244           {halt(conn), :forbidden, "You can only update your own uploads."}
 245
 246         !is_binary(description) ->
 247           {conn, :not_modified, ""}
 248
 249         true ->
 250           new_data = Map.put(object.data, "name", description)
 251
 252           {:ok, _} =
 253             object
 254             |> Object.change(%{data: new_data})
 255             |> Repo.update()
 256
 257           {conn, :no_content, ""}
 258       end
 259
 260     conn
 261     |> put_status(status)
 262     |> json(response_body)
 263   end
 264
 265   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 266     response = TwitterAPI.upload(media, user)
 267
 268     conn
 269     |> put_resp_content_type("application/atom+xml")
 270     |> send_resp(200, response)
 271   end
 272
 273   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 274     response = TwitterAPI.upload(media, user, "json")
 275
 276     conn
 277     |> json_reply(200, response)
 278   end
 279
 280   def get_by_id_or_ap_id(id) do
 281     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 282
 283     if activity.data["type"] == "Create" do
 284       activity
 285     else
 286       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 287     end
 288   end
 289
 290   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 291     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 292          {:ok, activity} <- TwitterAPI.fav(user, id) do
 293       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 294     end
 295   end
 296
 297   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 298     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 299          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 300       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 301     end
 302   end
 303
 304   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 305     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 306          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 307       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 308     end
 309   end
 310
 311   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 312     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 313          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 314       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 315     end
 316   end
 317
 318   def register(conn, params) do
 319     with {:ok, user} <- TwitterAPI.register_user(params) do
 320       render(conn, UserView, "show.json", %{user: user})
 321     else
 322       {:error, errors} ->
 323         conn
 324         |> json_reply(400, Jason.encode!(errors))
 325     end
 326   end
 327
 328   def password_reset(conn, params) do
 329     nickname_or_email = params["email"] || params["nickname"]
 330
 331     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 332       json_response(conn, :no_content, "")
 333     end
 334   end
 335
 336   def confirm_email(_conn, _params), do: :noop
 337
 338   def email_invite(_conn, _params), do: :noop
 339
 340   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 341     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 342     change = Changeset.change(user, %{avatar: object.data})
 343     {:ok, user} = User.update_and_set_cache(change)
 344     CommonAPI.update(user)
 345
 346     render(conn, UserView, "show.json", %{user: user, for: user})
 347   end
 348
 349   def update_banner(%{assigns: %{user: user}} = conn, params) do
 350     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 351          new_info <- %{"banner" => object.data},
 352          info_cng <- User.Info.profile_update(user.info, new_info),
 353          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 354          {:ok, user} <- User.update_and_set_cache(changeset) do
 355       CommonAPI.update(user)
 356       %{"url" => [%{"href" => href} | _]} = object.data
 357       response = %{url: href} |> Jason.encode!()
 358
 359       conn
 360       |> json_reply(200, response)
 361     end
 362   end
 363
 364   def update_background(%{assigns: %{user: user}} = conn, params) do
 365     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 366          new_info <- %{"background" => object.data},
 367          info_cng <- User.Info.profile_update(user.info, new_info),
 368          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 369          {:ok, _user} <- User.update_and_set_cache(changeset) do
 370       %{"url" => [%{"href" => href} | _]} = object.data
 371       response = %{url: href} |> Jason.encode!()
 372
 373       conn
 374       |> json_reply(200, response)
 375     end
 376   end
 377
 378   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 379     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 380          response <- Jason.encode!(user_map) do
 381       conn
 382       |> json_reply(200, response)
 383     else
 384       _e ->
 385         conn
 386         |> put_status(404)
 387         |> json(%{error: "Can't find user"})
 388     end
 389   end
 390
 391   def followers(%{assigns: %{user: for_user}} = conn, params) do
 392     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 393          {:ok, followers} <- User.get_followers(user) do
 394       followers =
 395         cond do
 396           for_user && user.id == for_user.id -> followers
 397           user.info.hide_network -> []
 398           true -> followers
 399         end
 400
 401       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 402     else
 403       _e -> bad_request_reply(conn, "Can't get followers")
 404     end
 405   end
 406
 407   def friends(%{assigns: %{user: for_user}} = conn, params) do
 408     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 409          {:ok, friends} <- User.get_friends(user) do
 410       friends =
 411         cond do
 412           for_user && user.id == for_user.id -> friends
 413           user.info.hide_network -> []
 414           true -> friends
 415         end
 416
 417       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 418     else
 419       _e -> bad_request_reply(conn, "Can't get friends")
 420     end
 421   end
 422
 423   def friend_requests(conn, params) do
 424     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 425          {:ok, friend_requests} <- User.get_follow_requests(user) do
 426       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 427     else
 428       _e -> bad_request_reply(conn, "Can't get friend requests")
 429     end
 430   end
 431
 432   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 433     with followed <- conn.assigns[:user],
 434          uid when is_number(uid) <- String.to_integer(uid),
 435          %User{} = follower <- Repo.get(User, uid),
 436          {:ok, follower} <- User.maybe_follow(follower, followed),
 437          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 438          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 439          {:ok, _activity} <-
 440            ActivityPub.accept(%{
 441              to: [follower.ap_id],
 442              actor: followed.ap_id,
 443              object: follow_activity.data["id"],
 444              type: "Accept"
 445            }) do
 446       render(conn, UserView, "show.json", %{user: follower, for: followed})
 447     else
 448       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 449     end
 450   end
 451
 452   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 453     with followed <- conn.assigns[:user],
 454          uid when is_number(uid) <- String.to_integer(uid),
 455          %User{} = follower <- Repo.get(User, uid),
 456          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 457          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 458          {:ok, _activity} <-
 459            ActivityPub.reject(%{
 460              to: [follower.ap_id],
 461              actor: followed.ap_id,
 462              object: follow_activity.data["id"],
 463              type: "Reject"
 464            }) do
 465       render(conn, UserView, "show.json", %{user: follower, for: followed})
 466     else
 467       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 468     end
 469   end
 470
 471   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 472     with {:ok, friends} <- User.get_friends(user) do
 473       ids =
 474         friends
 475         |> Enum.map(fn x -> x.id end)
 476         |> Jason.encode!()
 477
 478       json(conn, ids)
 479     else
 480       _e -> bad_request_reply(conn, "Can't get friends")
 481     end
 482   end
 483
 484   def empty_array(conn, _params) do
 485     json(conn, Jason.encode!([]))
 486   end
 487
 488   def raw_empty_array(conn, _params) do
 489     json(conn, [])
 490   end
 491
 492   defp build_info_cng(user, params) do
 493     info_params =
 494       ["no_rich_text", "locked", "hide_network"]
 495       |> Enum.reduce(%{}, fn key, res ->
 496         if value = params[key] do
 497           Map.put(res, key, value == "true")
 498         else
 499           res
 500         end
 501       end)
 502
 503     info_params =
 504       if value = params["default_scope"] do
 505         Map.put(info_params, "default_scope", value)
 506       else
 507         info_params
 508       end
 509
 510     User.Info.profile_update(user.info, info_params)
 511   end
 512
 513   defp parse_profile_bio(user, params) do
 514     if bio = params["description"] do
 515       Map.put(params, "bio", User.parse_bio(bio, user))
 516     else
 517       params
 518     end
 519   end
 520
 521   def update_profile(%{assigns: %{user: user}} = conn, params) do
 522     params = parse_profile_bio(user, params)
 523     info_cng = build_info_cng(user, params)
 524
 525     with changeset <- User.update_changeset(user, params),
 526          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 527          {:ok, user} <- User.update_and_set_cache(changeset) do
 528       CommonAPI.update(user)
 529       render(conn, UserView, "user.json", %{user: user, for: user})
 530     else
 531       error ->
 532         Logger.debug("Can't update user: #{inspect(error)}")
 533         bad_request_reply(conn, "Can't update user")
 534     end
 535   end
 536
 537   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 538     activities = TwitterAPI.search(user, params)
 539
 540     conn
 541     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 542   end
 543
 544   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 545     users = User.search(query, true)
 546
 547     conn
 548     |> render(UserView, "index.json", %{users: users, for: user})
 549   end
 550
 551   defp bad_request_reply(conn, error_message) do
 552     json = error_json(conn, error_message)
 553     json_reply(conn, 400, json)
 554   end
 555
 556   defp json_reply(conn, status, json) do
 557     conn
 558     |> put_resp_content_type("application/json")
 559     |> send_resp(status, json)
 560   end
 561
 562   defp forbidden_json_reply(conn, error_message) do
 563     json = error_json(conn, error_message)
 564     json_reply(conn, 403, json)
 565   end
 566
 567   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 568
 569   def only_if_public_instance(conn, _) do
 570     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 571       conn
 572     else
 573       conn
 574       |> forbidden_json_reply("Invalid credentials.")
 575       |> halt()
 576     end
 577   end
 578
 579   defp error_json(conn, error_message) do
 580     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 581   end
 582
 583   def errors(conn, {:param_cast, _}) do
 584     conn
 585     |> put_status(400)
 586     |> json("Invalid parameters")
 587   end
 588
 589   def errors(conn, _) do
 590     conn
 591     |> put_status(500)
 592     |> json("Something went wrong")
 593   end
 594 end