git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView}
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.{Repo, Activity, User}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Ecto.Changeset
   9
  10   require Logger
  11
  12   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  13     token = Phoenix.Token.sign(conn, "user socket", user.id)
  14     render(conn, UserView, "show.json", %{user: user, token: token})
  15   end
  16
  17   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  18     with media_ids <- extract_media_ids(status_data),
  19          {:ok, activity} <- TwitterAPI.create_status(user, Map.put(status_data, "media_ids",  media_ids)) do
  20       conn
  21       |> json(ActivityRepresenter.to_map(activity, %{user: user}))
  22     else
  23       _ -> empty_status_reply(conn)
  24     end
  25   end
  26
  27   def status_update(conn, _status_data) do
  28     empty_status_reply(conn)
  29   end
  30
  31   defp empty_status_reply(conn) do
  32     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  33   end
  34
  35   defp extract_media_ids(status_data) do
  36     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  37          split_ids <- String.split(media_ids, ","),
  38          clean_ids <- Enum.reject(split_ids, fn (id) -> String.length(id) == 0 end)
  39       do
  40         clean_ids
  41       else _e -> []
  42     end
  43   end
  44
  45   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  46     statuses = TwitterAPI.fetch_public_and_external_statuses(user, params)
  47     {:ok, json} = Poison.encode(statuses)
  48
  49     conn
  50     |> json_reply(200, json)
  51   end
  52
  53   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  54     statuses = TwitterAPI.fetch_public_statuses(user, params)
  55     {:ok, json} = Poison.encode(statuses)
  56
  57     conn
  58     |> json_reply(200, json)
  59   end
  60
  61   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  62     statuses = TwitterAPI.fetch_friend_statuses(user, params)
  63     {:ok, json} = Poison.encode(statuses)
  64
  65     conn
  66     |> json_reply(200, json)
  67   end
  68
  69   def show_user(conn, params) do
  70     with {:ok, shown} <- TwitterAPI.get_user(params) do
  71       if user = conn.assigns.user do
  72         render conn, UserView, "show.json", %{user: shown, for: user}
  73       else
  74         render conn, UserView, "show.json", %{user: shown}
  75       end
  76     else
  77       {:error, msg} ->
  78         bad_request_reply(conn, msg)
  79     end
  80   end
  81
  82   def user_timeline(%{assigns: %{user: user}} = conn, params) do
  83     case TwitterAPI.get_user(user, params) do
  84       {:ok, target_user} ->
  85         params = Map.merge(params, %{"actor_id" => target_user.ap_id, "whole_db" => true})
  86         statuses  = TwitterAPI.fetch_user_statuses(user, params)
  87         conn
  88         |> json_reply(200, statuses |> Poison.encode!)
  89       {:error, msg} ->
  90         bad_request_reply(conn, msg)
  91     end
  92   end
  93
  94   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
  95     statuses = TwitterAPI.fetch_mentions(user, params)
  96     {:ok, json} = Poison.encode(statuses)
  97
  98     conn
  99     |> json_reply(200, json)
 100   end
 101
 102   def follow(%{assigns: %{user: user}} = conn, params) do
 103     case TwitterAPI.follow(user, params) do
 104       {:ok, user, followed, _activity} ->
 105         render(conn, UserView, "show.json", %{user: followed, for: user})
 106       {:error, msg} -> forbidden_json_reply(conn, msg)
 107     end
 108   end
 109
 110   def block(%{assigns: %{user: user}} = conn, params) do
 111     case TwitterAPI.block(user, params) do
 112       {:ok, user, blocked} ->
 113         render conn, UserView, "show.json", %{user: blocked, for: user}
 114       {:error, msg} -> forbidden_json_reply(conn, msg)
 115     end
 116   end
 117
 118   def unblock(%{assigns: %{user: user}} = conn, params) do
 119     case TwitterAPI.unblock(user, params) do
 120       {:ok, user, blocked} ->
 121         render conn, UserView, "show.json", %{user: blocked, for: user}
 122       {:error, msg} -> forbidden_json_reply(conn, msg)
 123     end
 124   end
 125
 126   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 127     with {:ok, delete} <- CommonAPI.delete(id, user) do
 128       json = ActivityRepresenter.to_json(delete, %{user: user, for: user})
 129       conn
 130       |> json_reply(200, json)
 131     end
 132   end
 133
 134   def unfollow(%{assigns: %{user: user}} = conn, params) do
 135     case TwitterAPI.unfollow(user, params) do
 136       {:ok, user, unfollowed} ->
 137         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 138       {:error, msg} -> forbidden_json_reply(conn, msg)
 139     end
 140   end
 141
 142   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 143     response = Poison.encode!(TwitterAPI.fetch_status(user, id))
 144
 145     conn
 146     |> json_reply(200, response)
 147   end
 148
 149   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 150     id = String.to_integer(id)
 151     response = Poison.encode!(TwitterAPI.fetch_conversation(user, id))
 152
 153     conn
 154     |> json_reply(200, response)
 155   end
 156
 157   def upload(conn, %{"media" => media}) do
 158     response = TwitterAPI.upload(media)
 159     conn
 160     |> put_resp_content_type("application/atom+xml")
 161     |> send_resp(200, response)
 162   end
 163
 164   def upload_json(conn, %{"media" => media}) do
 165     response = TwitterAPI.upload(media, "json")
 166     conn
 167     |> json_reply(200, response)
 168   end
 169
 170   def get_by_id_or_ap_id(id) do
 171     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 172     if activity.data["type"] == "Create" do
 173       activity
 174     else
 175       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 176     end
 177   end
 178
 179   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 180     with {:ok, status} <- TwitterAPI.fav(user, id) do
 181       json(conn, status)
 182     end
 183   end
 184
 185   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 186     with {:ok, status} <- TwitterAPI.unfav(user, id) do
 187       json(conn, status)
 188     end
 189   end
 190
 191   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 192     with {:ok, status} <- TwitterAPI.repeat(user, id) do
 193       json(conn, status)
 194     end
 195   end
 196
 197   def register(conn, params) do
 198     with {:ok, user} <- TwitterAPI.register_user(params) do
 199       render(conn, UserView, "show.json", %{user: user})
 200     else
 201       {:error, errors} ->
 202       conn
 203       |> json_reply(400, Poison.encode!(errors))
 204     end
 205   end
 206
 207   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 208     {:ok, object} = ActivityPub.upload(params)
 209     change = Changeset.change(user, %{avatar: object.data})
 210     {:ok, user} = Repo.update(change)
 211
 212     render(conn, UserView, "show.json", %{user: user, for: user})
 213   end
 214
 215   def update_banner(%{assigns: %{user: user}} = conn, params) do
 216     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}),
 217          new_info <- Map.put(user.info, "banner", object.data),
 218          change <- User.info_changeset(user, %{info: new_info}),
 219          {:ok, _user} <- Repo.update(change) do
 220       %{"url" => [ %{ "href" => href } | _ ]} = object.data
 221       response = %{ url: href } |> Poison.encode!
 222       conn
 223       |> json_reply(200, response)
 224     end
 225   end
 226
 227   def update_background(%{assigns: %{user: user}} = conn, params) do
 228     with {:ok, object} <- ActivityPub.upload(params),
 229          new_info <- Map.put(user.info, "background", object.data),
 230          change <- User.info_changeset(user, %{info: new_info}),
 231          {:ok, _user} <- Repo.update(change) do
 232       %{"url" => [ %{ "href" => href } | _ ]} = object.data
 233       response = %{ url: href } |> Poison.encode!
 234       conn
 235       |> json_reply(200, response)
 236     end
 237   end
 238
 239   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 240     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 241          response <- Poison.encode!(user_map) do
 242       conn
 243       |> json_reply(200, response)
 244     else
 245       _e ->
 246         conn
 247         |> put_status(404)
 248         |> json(%{error: "Can't find user"})
 249     end
 250   end
 251
 252   def update_most_recent_notification(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 253     with id when is_number(id) <- String.to_integer(id),
 254          info <- user.info,
 255          mrn <- max(id, user.info["most_recent_notification"] || 0),
 256          updated_info <- Map.put(info, "most_recent_notification", mrn),
 257          changeset <- User.info_changeset(user, %{info: updated_info}),
 258          {:ok, _user} <- Repo.update(changeset) do
 259       conn
 260       |> json_reply(200, Poison.encode!(mrn))
 261     else
 262       _e -> bad_request_reply(conn, "Can't update.")
 263     end
 264   end
 265
 266   def followers(%{assigns: %{user: user}} = conn, _params) do
 267     with {:ok, followers} <- User.get_followers(user) do
 268       render(conn, UserView, "index.json", %{users: followers, for: user})
 269     else
 270       _e -> bad_request_reply(conn, "Can't get followers")
 271     end
 272   end
 273
 274   def friends(%{assigns: %{user: user}} = conn, _params) do
 275     with {:ok, friends} <- User.get_friends(user) do
 276       render(conn, UserView, "index.json", %{users: friends, for: user})
 277     else
 278       _e -> bad_request_reply(conn, "Can't get friends")
 279     end
 280   end
 281
 282   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 283     with {:ok, friends} <- User.get_friends(user) do
 284       ids = friends
 285       |> Enum.map(fn x -> x.id end)
 286       |> Poison.encode!
 287
 288       json(conn, ids)
 289     else
 290       _e -> bad_request_reply(conn, "Can't get friends")
 291     end
 292   end
 293
 294   def empty_array(conn, _params) do
 295     json(conn, Poison.encode!([]))
 296   end
 297
 298   def update_profile(%{assigns: %{user: user}} = conn, params) do
 299     params = if bio = params["description"] do
 300       Map.put(params, "bio", bio)
 301     else
 302       params
 303     end
 304
 305     with changeset <- User.update_changeset(user, params),
 306          {:ok, user} <- Repo.update(changeset) do
 307       render(conn, UserView, "user.json", %{user: user, for: user})
 308     else
 309       error ->
 310         Logger.debug("Can't update user: #{inspect(error)}")
 311         bad_request_reply(conn, "Can't update user")
 312     end
 313   end
 314
 315   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 316     conn
 317     |> json(TwitterAPI.search(user, params))
 318   end
 319
 320   defp bad_request_reply(conn, error_message) do
 321     json = error_json(conn, error_message)
 322     json_reply(conn, 400, json)
 323   end
 324
 325   defp json_reply(conn, status, json) do
 326     conn
 327     |> put_resp_content_type("application/json")
 328     |> send_resp(status, json)
 329   end
 330
 331   defp forbidden_json_reply(conn, error_message) do
 332     json = error_json(conn, error_message)
 333     json_reply(conn, 403, json)
 334   end
 335
 336   defp error_json(conn, error_message) do
 337     %{"error" => error_message, "request" => conn.request_path} |> Poison.encode!
 338   end
 339 end