git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   plug(:fetch_flash when action in [:confirm_email, :resend_confirmation_email])
  17   action_fallback(:errors)
  18
  19   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  20     token = Phoenix.Token.sign(conn, "user socket", user.id)
  21
  22     conn
  23     |> put_view(UserView)
  24     |> render("show.json", %{user: user, token: token})
  25   end
  26
  27   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  28     with media_ids <- extract_media_ids(status_data),
  29          {:ok, activity} <-
  30            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  31       conn
  32       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  33     else
  34       _ -> empty_status_reply(conn)
  35     end
  36   end
  37
  38   def status_update(conn, _status_data) do
  39     empty_status_reply(conn)
  40   end
  41
  42   defp empty_status_reply(conn) do
  43     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  44   end
  45
  46   defp extract_media_ids(status_data) do
  47     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  48          split_ids <- String.split(media_ids, ","),
  49          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  50       clean_ids
  51     else
  52       _e -> []
  53     end
  54   end
  55
  56   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  57     params =
  58       params
  59       |> Map.put("type", ["Create", "Announce"])
  60       |> Map.put("blocking_user", user)
  61
  62     activities = ActivityPub.fetch_public_activities(params)
  63
  64     conn
  65     |> put_view(ActivityView)
  66     |> render("index.json", %{activities: activities, for: user})
  67   end
  68
  69   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  70     params =
  71       params
  72       |> Map.put("type", ["Create", "Announce"])
  73       |> Map.put("local_only", true)
  74       |> Map.put("blocking_user", user)
  75
  76     activities = ActivityPub.fetch_public_activities(params)
  77
  78     conn
  79     |> put_view(ActivityView)
  80     |> render("index.json", %{activities: activities, for: user})
  81   end
  82
  83   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  84     params =
  85       params
  86       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  87       |> Map.put("blocking_user", user)
  88       |> Map.put("user", user)
  89
  90     activities =
  91       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  92       |> ActivityPub.contain_timeline(user)
  93
  94     conn
  95     |> put_view(ActivityView)
  96     |> render("index.json", %{activities: activities, for: user})
  97   end
  98
  99   def show_user(conn, params) do
 100     for_user = conn.assigns.user
 101
 102     with {:ok, shown} <- TwitterAPI.get_user(params),
 103          true <- User.auth_active?(shown) || for_user && (for_user.id == shown.id || User.superuser?(for_user)) do
 104       params =
 105         if for_user do
 106           %{user: shown, for: for_user}
 107         else
 108           %{user: shown}
 109         end
 110
 111       conn
 112       |> put_view(UserView)
 113       |> render("show.json", params)
 114     else
 115       {:error, msg} ->
 116         bad_request_reply(conn, msg)
 117
 118       false ->
 119         conn
 120         |> put_status(404)
 121         |> json(%{error: "Unconfirmed user"})
 122     end
 123   end
 124
 125   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 126     case TwitterAPI.get_user(user, params) do
 127       {:ok, target_user} ->
 128         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 129
 130         conn
 131         |> put_view(ActivityView)
 132         |> render("index.json", %{activities: activities, for: user})
 133
 134       {:error, msg} ->
 135         bad_request_reply(conn, msg)
 136     end
 137   end
 138
 139   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 140     params =
 141       params
 142       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 143       |> Map.put("blocking_user", user)
 144
 145     activities = ActivityPub.fetch_activities([user.ap_id], params)
 146
 147     conn
 148     |> put_view(ActivityView)
 149     |> render("index.json", %{activities: activities, for: user})
 150   end
 151
 152   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 153     query =
 154       ActivityPub.fetch_activities_query(
 155         [user.ap_id],
 156         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 157       )
 158
 159     activities = Repo.all(query)
 160
 161     conn
 162     |> put_view(ActivityView)
 163     |> render("index.json", %{activities: activities, for: user})
 164   end
 165
 166   def notifications(%{assigns: %{user: user}} = conn, params) do
 167     notifications = Notification.for_user(user, params)
 168
 169     conn
 170     |> put_view(NotificationView)
 171     |> render("notification.json", %{notifications: notifications, for: user})
 172   end
 173
 174   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 175     Notification.set_read_up_to(user, latest_id)
 176
 177     notifications = Notification.for_user(user, params)
 178
 179     conn
 180     |> put_view(NotificationView)
 181     |> render("notification.json", %{notifications: notifications, for: user})
 182   end
 183
 184   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 185     bad_request_reply(conn, "You need to specify latest_id")
 186   end
 187
 188   def follow(%{assigns: %{user: user}} = conn, params) do
 189     case TwitterAPI.follow(user, params) do
 190       {:ok, user, followed, _activity} ->
 191         conn
 192         |> put_view(UserView)
 193         |> render("show.json", %{user: followed, for: user})
 194
 195       {:error, msg} ->
 196         forbidden_json_reply(conn, msg)
 197     end
 198   end
 199
 200   def block(%{assigns: %{user: user}} = conn, params) do
 201     case TwitterAPI.block(user, params) do
 202       {:ok, user, blocked} ->
 203         conn
 204         |> put_view(UserView)
 205         |> render("show.json", %{user: blocked, for: user})
 206
 207       {:error, msg} ->
 208         forbidden_json_reply(conn, msg)
 209     end
 210   end
 211
 212   def unblock(%{assigns: %{user: user}} = conn, params) do
 213     case TwitterAPI.unblock(user, params) do
 214       {:ok, user, blocked} ->
 215         conn
 216         |> put_view(UserView)
 217         |> render("show.json", %{user: blocked, for: user})
 218
 219       {:error, msg} ->
 220         forbidden_json_reply(conn, msg)
 221     end
 222   end
 223
 224   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 225     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 226       conn
 227       |> put_view(ActivityView)
 228       |> render("activity.json", %{activity: activity, for: user})
 229     end
 230   end
 231
 232   def unfollow(%{assigns: %{user: user}} = conn, params) do
 233     case TwitterAPI.unfollow(user, params) do
 234       {:ok, user, unfollowed} ->
 235         conn
 236         |> put_view(UserView)
 237         |> render("show.json", %{user: unfollowed, for: user})
 238
 239       {:error, msg} ->
 240         forbidden_json_reply(conn, msg)
 241     end
 242   end
 243
 244   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 245     with %Activity{} = activity <- Repo.get(Activity, id),
 246          true <- ActivityPub.visible_for_user?(activity, user) do
 247       conn
 248       |> put_view(ActivityView)
 249       |> render("activity.json", %{activity: activity, for: user})
 250     end
 251   end
 252
 253   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 254     id = String.to_integer(id)
 255
 256     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 257          activities <-
 258            ActivityPub.fetch_activities_for_context(context, %{
 259              "blocking_user" => user,
 260              "user" => user
 261            }) do
 262       conn
 263       |> put_view(ActivityView)
 264       |> render("index.json", %{activities: activities, for: user})
 265     end
 266   end
 267
 268   @doc """
 269   Updates metadata of uploaded media object.
 270   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 271   """
 272   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 273     object = Repo.get(Object, id)
 274     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 275
 276     {conn, status, response_body} =
 277       cond do
 278         !object ->
 279           {halt(conn), :not_found, ""}
 280
 281         !Object.authorize_mutation(object, user) ->
 282           {halt(conn), :forbidden, "You can only update your own uploads."}
 283
 284         !is_binary(description) ->
 285           {conn, :not_modified, ""}
 286
 287         true ->
 288           new_data = Map.put(object.data, "name", description)
 289
 290           {:ok, _} =
 291             object
 292             |> Object.change(%{data: new_data})
 293             |> Repo.update()
 294
 295           {conn, :no_content, ""}
 296       end
 297
 298     conn
 299     |> put_status(status)
 300     |> json(response_body)
 301   end
 302
 303   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 304     response = TwitterAPI.upload(media, user)
 305
 306     conn
 307     |> put_resp_content_type("application/atom+xml")
 308     |> send_resp(200, response)
 309   end
 310
 311   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 312     response = TwitterAPI.upload(media, user, "json")
 313
 314     conn
 315     |> json_reply(200, response)
 316   end
 317
 318   def get_by_id_or_ap_id(id) do
 319     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 320
 321     if activity.data["type"] == "Create" do
 322       activity
 323     else
 324       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 325     end
 326   end
 327
 328   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 329     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 330          {:ok, activity} <- TwitterAPI.fav(user, id) do
 331       conn
 332       |> put_view(ActivityView)
 333       |> render("activity.json", %{activity: activity, for: user})
 334     end
 335   end
 336
 337   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 338     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 339          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 340       conn
 341       |> put_view(ActivityView)
 342       |> render("activity.json", %{activity: activity, for: user})
 343     end
 344   end
 345
 346   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 347     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 348          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 349       conn
 350       |> put_view(ActivityView)
 351       |> render("activity.json", %{activity: activity, for: user})
 352     end
 353   end
 354
 355   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 356     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 357          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 358       conn
 359       |> put_view(ActivityView)
 360       |> render("activity.json", %{activity: activity, for: user})
 361     end
 362   end
 363
 364   def register(conn, params) do
 365     with {:ok, user} <- TwitterAPI.register_user(params) do
 366       conn
 367       |> put_view(UserView)
 368       |> render("show.json", %{user: user})
 369     else
 370       {:error, errors} ->
 371         conn
 372         |> json_reply(400, Jason.encode!(errors))
 373     end
 374   end
 375
 376   def password_reset(conn, params) do
 377     nickname_or_email = params["email"] || params["nickname"]
 378
 379     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 380       json_response(conn, :no_content, "")
 381     end
 382   end
 383
 384   def confirm_email(conn, %{"token" => token}) do
 385     with %User{} = user <- User.get_by_confirmation_token(token),
 386          true <- user.local,
 387          info_change <- User.Info.confirmation_changeset(user.info, :confirmed),
 388          changeset <- Changeset.change(user) |> Changeset.put_embed(:info, info_change),
 389          {:ok, _} <- User.update_and_set_cache(changeset) do
 390       conn
 391       |> put_flash(:info, "Email confirmed. Please sign in.")
 392       |> redirect(to: "/")
 393     end
 394   end
 395
 396   def resend_confirmation_email(conn, params) do
 397     nickname_or_email = params["email"] || params["nickname"]
 398
 399     with %User{} = user <- User.get_by_nickname_or_email(nickname_or_email),
 400          {:ok, _} <- User.try_send_confirmation_email(user) do
 401       conn
 402       |> put_flash(:info, "Email confirmation has been sent.")
 403       |> json_response(:no_content, "")
 404     end
 405   end
 406
 407   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 408     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 409     change = Changeset.change(user, %{avatar: object.data})
 410     {:ok, user} = User.update_and_set_cache(change)
 411     CommonAPI.update(user)
 412
 413     conn
 414     |> put_view(UserView)
 415     |> render("show.json", %{user: user, for: user})
 416   end
 417
 418   def update_banner(%{assigns: %{user: user}} = conn, params) do
 419     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 420          new_info <- %{"banner" => object.data},
 421          info_cng <- User.Info.profile_update(user.info, new_info),
 422          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 423          {:ok, user} <- User.update_and_set_cache(changeset) do
 424       CommonAPI.update(user)
 425       %{"url" => [%{"href" => href} | _]} = object.data
 426       response = %{url: href} |> Jason.encode!()
 427
 428       conn
 429       |> json_reply(200, response)
 430     end
 431   end
 432
 433   def update_background(%{assigns: %{user: user}} = conn, params) do
 434     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 435          new_info <- %{"background" => object.data},
 436          info_cng <- User.Info.profile_update(user.info, new_info),
 437          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 438          {:ok, _user} <- User.update_and_set_cache(changeset) do
 439       %{"url" => [%{"href" => href} | _]} = object.data
 440       response = %{url: href} |> Jason.encode!()
 441
 442       conn
 443       |> json_reply(200, response)
 444     end
 445   end
 446
 447   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 448     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 449          response <- Jason.encode!(user_map) do
 450       conn
 451       |> json_reply(200, response)
 452     else
 453       _e ->
 454         conn
 455         |> put_status(404)
 456         |> json(%{error: "Can't find user"})
 457     end
 458   end
 459
 460   def followers(%{assigns: %{user: for_user}} = conn, params) do
 461     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 462          {:ok, followers} <- User.get_followers(user) do
 463       followers =
 464         cond do
 465           for_user && user.id == for_user.id -> followers
 466           user.info.hide_network -> []
 467           true -> followers
 468         end
 469
 470       conn
 471       |> put_view(UserView)
 472       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 473     else
 474       _e -> bad_request_reply(conn, "Can't get followers")
 475     end
 476   end
 477
 478   def friends(%{assigns: %{user: for_user}} = conn, params) do
 479     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 480          {:ok, friends} <- User.get_friends(user) do
 481       friends =
 482         cond do
 483           for_user && user.id == for_user.id -> friends
 484           user.info.hide_network -> []
 485           true -> friends
 486         end
 487
 488       conn
 489       |> put_view(UserView)
 490       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 491     else
 492       _e -> bad_request_reply(conn, "Can't get friends")
 493     end
 494   end
 495
 496   def friend_requests(conn, params) do
 497     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 498          {:ok, friend_requests} <- User.get_follow_requests(user) do
 499       conn
 500       |> put_view(UserView)
 501       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 502     else
 503       _e -> bad_request_reply(conn, "Can't get friend requests")
 504     end
 505   end
 506
 507   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 508     with followed <- conn.assigns[:user],
 509          uid when is_number(uid) <- String.to_integer(uid),
 510          %User{} = follower <- Repo.get(User, uid),
 511          {:ok, follower} <- User.maybe_follow(follower, followed),
 512          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 513          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 514          {:ok, _activity} <-
 515            ActivityPub.accept(%{
 516              to: [follower.ap_id],
 517              actor: followed.ap_id,
 518              object: follow_activity.data["id"],
 519              type: "Accept"
 520            }) do
 521       conn
 522       |> put_view(UserView)
 523       |> render("show.json", %{user: follower, for: followed})
 524     else
 525       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 526     end
 527   end
 528
 529   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 530     with followed <- conn.assigns[:user],
 531          uid when is_number(uid) <- String.to_integer(uid),
 532          %User{} = follower <- Repo.get(User, uid),
 533          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 534          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 535          {:ok, _activity} <-
 536            ActivityPub.reject(%{
 537              to: [follower.ap_id],
 538              actor: followed.ap_id,
 539              object: follow_activity.data["id"],
 540              type: "Reject"
 541            }) do
 542       conn
 543       |> put_view(UserView)
 544       |> render("show.json", %{user: follower, for: followed})
 545     else
 546       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 547     end
 548   end
 549
 550   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 551     with {:ok, friends} <- User.get_friends(user) do
 552       ids =
 553         friends
 554         |> Enum.map(fn x -> x.id end)
 555         |> Jason.encode!()
 556
 557       json(conn, ids)
 558     else
 559       _e -> bad_request_reply(conn, "Can't get friends")
 560     end
 561   end
 562
 563   def empty_array(conn, _params) do
 564     json(conn, Jason.encode!([]))
 565   end
 566
 567   def raw_empty_array(conn, _params) do
 568     json(conn, [])
 569   end
 570
 571   defp build_info_cng(user, params) do
 572     info_params =
 573       ["no_rich_text", "locked", "hide_network"]
 574       |> Enum.reduce(%{}, fn key, res ->
 575         if value = params[key] do
 576           Map.put(res, key, value == "true")
 577         else
 578           res
 579         end
 580       end)
 581
 582     info_params =
 583       if value = params["default_scope"] do
 584         Map.put(info_params, "default_scope", value)
 585       else
 586         info_params
 587       end
 588
 589     User.Info.profile_update(user.info, info_params)
 590   end
 591
 592   defp parse_profile_bio(user, params) do
 593     if bio = params["description"] do
 594       Map.put(params, "bio", User.parse_bio(bio, user))
 595     else
 596       params
 597     end
 598   end
 599
 600   def update_profile(%{assigns: %{user: user}} = conn, params) do
 601     params = parse_profile_bio(user, params)
 602     info_cng = build_info_cng(user, params)
 603
 604     with changeset <- User.update_changeset(user, params),
 605          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 606          {:ok, user} <- User.update_and_set_cache(changeset) do
 607       CommonAPI.update(user)
 608
 609       conn
 610       |> put_view(UserView)
 611       |> render("user.json", %{user: user, for: user})
 612     else
 613       error ->
 614         Logger.debug("Can't update user: #{inspect(error)}")
 615         bad_request_reply(conn, "Can't update user")
 616     end
 617   end
 618
 619   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 620     activities = TwitterAPI.search(user, params)
 621
 622     conn
 623     |> put_view(ActivityView)
 624     |> render("index.json", %{activities: activities, for: user})
 625   end
 626
 627   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 628     users = User.search(query, true)
 629
 630     conn
 631     |> put_view(UserView)
 632     |> render("index.json", %{users: users, for: user})
 633   end
 634
 635   defp bad_request_reply(conn, error_message) do
 636     json = error_json(conn, error_message)
 637     json_reply(conn, 400, json)
 638   end
 639
 640   defp json_reply(conn, status, json) do
 641     conn
 642     |> put_resp_content_type("application/json")
 643     |> send_resp(status, json)
 644   end
 645
 646   defp forbidden_json_reply(conn, error_message) do
 647     json = error_json(conn, error_message)
 648     json_reply(conn, 403, json)
 649   end
 650
 651   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 652
 653   def only_if_public_instance(conn, _) do
 654     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 655       conn
 656     else
 657       conn
 658       |> forbidden_json_reply("Invalid credentials.")
 659       |> halt()
 660     end
 661   end
 662
 663   defp error_json(conn, error_message) do
 664     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 665   end
 666
 667   def errors(conn, {:param_cast, _}) do
 668     conn
 669     |> put_status(400)
 670     |> json("Invalid parameters")
 671   end
 672
 673   def errors(conn, _) do
 674     conn
 675     |> put_status(500)
 676     |> json("Something went wrong")
 677   end
 678 end