git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   action_fallback(:errors)
  17
  18   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  19     token = Phoenix.Token.sign(conn, "user socket", user.id)
  20
  21     conn
  22     |> put_view(UserView)
  23     |> render("show.json", %{user: user, token: token})
  24   end
  25
  26   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  27     with media_ids <- extract_media_ids(status_data),
  28          {:ok, activity} <-
  29            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  30       conn
  31       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  32     else
  33       _ -> empty_status_reply(conn)
  34     end
  35   end
  36
  37   def status_update(conn, _status_data) do
  38     empty_status_reply(conn)
  39   end
  40
  41   defp empty_status_reply(conn) do
  42     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  43   end
  44
  45   defp extract_media_ids(status_data) do
  46     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  47          split_ids <- String.split(media_ids, ","),
  48          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  49       clean_ids
  50     else
  51       _e -> []
  52     end
  53   end
  54
  55   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  56     params =
  57       params
  58       |> Map.put("type", ["Create", "Announce"])
  59       |> Map.put("blocking_user", user)
  60
  61     activities = ActivityPub.fetch_public_activities(params)
  62
  63     conn
  64     |> put_view(ActivityView)
  65     |> render("index.json", %{activities: activities, for: user})
  66   end
  67
  68   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  69     params =
  70       params
  71       |> Map.put("type", ["Create", "Announce"])
  72       |> Map.put("local_only", true)
  73       |> Map.put("blocking_user", user)
  74
  75     activities = ActivityPub.fetch_public_activities(params)
  76
  77     conn
  78     |> put_view(ActivityView)
  79     |> render("index.json", %{activities: activities, for: user})
  80   end
  81
  82   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  83     params =
  84       params
  85       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  86       |> Map.put("blocking_user", user)
  87       |> Map.put("user", user)
  88
  89     activities =
  90       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  91       |> ActivityPub.contain_timeline(user)
  92
  93     conn
  94     |> put_view(ActivityView)
  95     |> render("index.json", %{activities: activities, for: user})
  96   end
  97
  98   def show_user(conn, params) do
  99     for_user = conn.assigns.user
 100
 101     with {:ok, shown} <- TwitterAPI.get_user(params),
 102          true <-
 103            User.auth_active?(shown) ||
 104              (for_user && (for_user.id == shown.id || User.superuser?(for_user))) do
 105       params =
 106         if for_user do
 107           %{user: shown, for: for_user}
 108         else
 109           %{user: shown}
 110         end
 111
 112       conn
 113       |> put_view(UserView)
 114       |> render("show.json", params)
 115     else
 116       {:error, msg} ->
 117         bad_request_reply(conn, msg)
 118
 119       false ->
 120         conn
 121         |> put_status(404)
 122         |> json(%{error: "Unconfirmed user"})
 123     end
 124   end
 125
 126   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 127     case TwitterAPI.get_user(user, params) do
 128       {:ok, target_user} ->
 129         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 130
 131         conn
 132         |> put_view(ActivityView)
 133         |> render("index.json", %{activities: activities, for: user})
 134
 135       {:error, msg} ->
 136         bad_request_reply(conn, msg)
 137     end
 138   end
 139
 140   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 141     params =
 142       params
 143       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 144       |> Map.put("blocking_user", user)
 145
 146     activities = ActivityPub.fetch_activities([user.ap_id], params)
 147
 148     conn
 149     |> put_view(ActivityView)
 150     |> render("index.json", %{activities: activities, for: user})
 151   end
 152
 153   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 154     query =
 155       ActivityPub.fetch_activities_query(
 156         [user.ap_id],
 157         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 158       )
 159
 160     activities = Repo.all(query)
 161
 162     conn
 163     |> put_view(ActivityView)
 164     |> render("index.json", %{activities: activities, for: user})
 165   end
 166
 167   def notifications(%{assigns: %{user: user}} = conn, params) do
 168     notifications = Notification.for_user(user, params)
 169
 170     conn
 171     |> put_view(NotificationView)
 172     |> render("notification.json", %{notifications: notifications, for: user})
 173   end
 174
 175   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 176     Notification.set_read_up_to(user, latest_id)
 177
 178     notifications = Notification.for_user(user, params)
 179
 180     conn
 181     |> put_view(NotificationView)
 182     |> render("notification.json", %{notifications: notifications, for: user})
 183   end
 184
 185   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 186     bad_request_reply(conn, "You need to specify latest_id")
 187   end
 188
 189   def follow(%{assigns: %{user: user}} = conn, params) do
 190     case TwitterAPI.follow(user, params) do
 191       {:ok, user, followed, _activity} ->
 192         conn
 193         |> put_view(UserView)
 194         |> render("show.json", %{user: followed, for: user})
 195
 196       {:error, msg} ->
 197         forbidden_json_reply(conn, msg)
 198     end
 199   end
 200
 201   def block(%{assigns: %{user: user}} = conn, params) do
 202     case TwitterAPI.block(user, params) do
 203       {:ok, user, blocked} ->
 204         conn
 205         |> put_view(UserView)
 206         |> render("show.json", %{user: blocked, for: user})
 207
 208       {:error, msg} ->
 209         forbidden_json_reply(conn, msg)
 210     end
 211   end
 212
 213   def unblock(%{assigns: %{user: user}} = conn, params) do
 214     case TwitterAPI.unblock(user, params) do
 215       {:ok, user, blocked} ->
 216         conn
 217         |> put_view(UserView)
 218         |> render("show.json", %{user: blocked, for: user})
 219
 220       {:error, msg} ->
 221         forbidden_json_reply(conn, msg)
 222     end
 223   end
 224
 225   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 226     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 227       conn
 228       |> put_view(ActivityView)
 229       |> render("activity.json", %{activity: activity, for: user})
 230     end
 231   end
 232
 233   def unfollow(%{assigns: %{user: user}} = conn, params) do
 234     case TwitterAPI.unfollow(user, params) do
 235       {:ok, user, unfollowed} ->
 236         conn
 237         |> put_view(UserView)
 238         |> render("show.json", %{user: unfollowed, for: user})
 239
 240       {:error, msg} ->
 241         forbidden_json_reply(conn, msg)
 242     end
 243   end
 244
 245   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 246     with %Activity{} = activity <- Repo.get(Activity, id),
 247          true <- ActivityPub.visible_for_user?(activity, user) do
 248       conn
 249       |> put_view(ActivityView)
 250       |> render("activity.json", %{activity: activity, for: user})
 251     end
 252   end
 253
 254   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 255     id = String.to_integer(id)
 256
 257     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 258          activities <-
 259            ActivityPub.fetch_activities_for_context(context, %{
 260              "blocking_user" => user,
 261              "user" => user
 262            }) do
 263       conn
 264       |> put_view(ActivityView)
 265       |> render("index.json", %{activities: activities, for: user})
 266     end
 267   end
 268
 269   @doc """
 270   Updates metadata of uploaded media object.
 271   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 272   """
 273   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 274     object = Repo.get(Object, id)
 275     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 276
 277     {conn, status, response_body} =
 278       cond do
 279         !object ->
 280           {halt(conn), :not_found, ""}
 281
 282         !Object.authorize_mutation(object, user) ->
 283           {halt(conn), :forbidden, "You can only update your own uploads."}
 284
 285         !is_binary(description) ->
 286           {conn, :not_modified, ""}
 287
 288         true ->
 289           new_data = Map.put(object.data, "name", description)
 290
 291           {:ok, _} =
 292             object
 293             |> Object.change(%{data: new_data})
 294             |> Repo.update()
 295
 296           {conn, :no_content, ""}
 297       end
 298
 299     conn
 300     |> put_status(status)
 301     |> json(response_body)
 302   end
 303
 304   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 305     response = TwitterAPI.upload(media, user)
 306
 307     conn
 308     |> put_resp_content_type("application/atom+xml")
 309     |> send_resp(200, response)
 310   end
 311
 312   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 313     response = TwitterAPI.upload(media, user, "json")
 314
 315     conn
 316     |> json_reply(200, response)
 317   end
 318
 319   def get_by_id_or_ap_id(id) do
 320     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 321
 322     if activity.data["type"] == "Create" do
 323       activity
 324     else
 325       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 326     end
 327   end
 328
 329   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 330     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 331          {:ok, activity} <- TwitterAPI.fav(user, id) do
 332       conn
 333       |> put_view(ActivityView)
 334       |> render("activity.json", %{activity: activity, for: user})
 335     end
 336   end
 337
 338   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 339     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 340          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 341       conn
 342       |> put_view(ActivityView)
 343       |> render("activity.json", %{activity: activity, for: user})
 344     end
 345   end
 346
 347   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 348     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 349          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 350       conn
 351       |> put_view(ActivityView)
 352       |> render("activity.json", %{activity: activity, for: user})
 353     end
 354   end
 355
 356   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 357     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 358          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 359       conn
 360       |> put_view(ActivityView)
 361       |> render("activity.json", %{activity: activity, for: user})
 362     end
 363   end
 364
 365   def register(conn, params) do
 366     with {:ok, user} <- TwitterAPI.register_user(params) do
 367       conn
 368       |> put_view(UserView)
 369       |> render("show.json", %{user: user})
 370     else
 371       {:error, errors} ->
 372         conn
 373         |> json_reply(400, Jason.encode!(errors))
 374     end
 375   end
 376
 377   def password_reset(conn, params) do
 378     nickname_or_email = params["email"] || params["nickname"]
 379
 380     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 381       json_response(conn, :no_content, "")
 382     end
 383   end
 384
 385   def confirm_email(conn, %{"user_id" => uid, "token" => token}) do
 386     with %User{} = user <- Repo.get(User, uid),
 387          true <- user.local,
 388          true <- user.info.confirmation_pending,
 389          true <- user.info.confirmation_token == token,
 390          info_change <- User.Info.confirmation_changeset(user.info, :confirmed),
 391          changeset <- Changeset.change(user) |> Changeset.put_embed(:info, info_change),
 392          {:ok, _} <- User.update_and_set_cache(changeset) do
 393       conn
 394       |> redirect(to: "/")
 395     end
 396   end
 397
 398   def resend_confirmation_email(conn, params) do
 399     nickname_or_email = params["email"] || params["nickname"]
 400
 401     with %User{} = user <- User.get_by_nickname_or_email(nickname_or_email),
 402          {:ok, _} <- User.try_send_confirmation_email(user) do
 403       conn
 404       |> json_response(:no_content, "")
 405     end
 406   end
 407
 408   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 409     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 410     change = Changeset.change(user, %{avatar: object.data})
 411     {:ok, user} = User.update_and_set_cache(change)
 412     CommonAPI.update(user)
 413
 414     conn
 415     |> put_view(UserView)
 416     |> render("show.json", %{user: user, for: user})
 417   end
 418
 419   def update_banner(%{assigns: %{user: user}} = conn, params) do
 420     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 421          new_info <- %{"banner" => object.data},
 422          info_cng <- User.Info.profile_update(user.info, new_info),
 423          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 424          {:ok, user} <- User.update_and_set_cache(changeset) do
 425       CommonAPI.update(user)
 426       %{"url" => [%{"href" => href} | _]} = object.data
 427       response = %{url: href} |> Jason.encode!()
 428
 429       conn
 430       |> json_reply(200, response)
 431     end
 432   end
 433
 434   def update_background(%{assigns: %{user: user}} = conn, params) do
 435     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 436          new_info <- %{"background" => object.data},
 437          info_cng <- User.Info.profile_update(user.info, new_info),
 438          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 439          {:ok, _user} <- User.update_and_set_cache(changeset) do
 440       %{"url" => [%{"href" => href} | _]} = object.data
 441       response = %{url: href} |> Jason.encode!()
 442
 443       conn
 444       |> json_reply(200, response)
 445     end
 446   end
 447
 448   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 449     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 450          response <- Jason.encode!(user_map) do
 451       conn
 452       |> json_reply(200, response)
 453     else
 454       _e ->
 455         conn
 456         |> put_status(404)
 457         |> json(%{error: "Can't find user"})
 458     end
 459   end
 460
 461   def followers(%{assigns: %{user: for_user}} = conn, params) do
 462     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 463          {:ok, followers} <- User.get_followers(user) do
 464       followers =
 465         cond do
 466           for_user && user.id == for_user.id -> followers
 467           user.info.hide_network -> []
 468           true -> followers
 469         end
 470
 471       conn
 472       |> put_view(UserView)
 473       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 474     else
 475       _e -> bad_request_reply(conn, "Can't get followers")
 476     end
 477   end
 478
 479   def friends(%{assigns: %{user: for_user}} = conn, params) do
 480     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 481          {:ok, friends} <- User.get_friends(user) do
 482       friends =
 483         cond do
 484           for_user && user.id == for_user.id -> friends
 485           user.info.hide_network -> []
 486           true -> friends
 487         end
 488
 489       conn
 490       |> put_view(UserView)
 491       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 492     else
 493       _e -> bad_request_reply(conn, "Can't get friends")
 494     end
 495   end
 496
 497   def friend_requests(conn, params) do
 498     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 499          {:ok, friend_requests} <- User.get_follow_requests(user) do
 500       conn
 501       |> put_view(UserView)
 502       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 503     else
 504       _e -> bad_request_reply(conn, "Can't get friend requests")
 505     end
 506   end
 507
 508   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 509     with followed <- conn.assigns[:user],
 510          uid when is_number(uid) <- String.to_integer(uid),
 511          %User{} = follower <- Repo.get(User, uid),
 512          {:ok, follower} <- User.maybe_follow(follower, followed),
 513          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 514          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 515          {:ok, _activity} <-
 516            ActivityPub.accept(%{
 517              to: [follower.ap_id],
 518              actor: followed.ap_id,
 519              object: follow_activity.data["id"],
 520              type: "Accept"
 521            }) do
 522       conn
 523       |> put_view(UserView)
 524       |> render("show.json", %{user: follower, for: followed})
 525     else
 526       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 527     end
 528   end
 529
 530   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 531     with followed <- conn.assigns[:user],
 532          uid when is_number(uid) <- String.to_integer(uid),
 533          %User{} = follower <- Repo.get(User, uid),
 534          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 535          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 536          {:ok, _activity} <-
 537            ActivityPub.reject(%{
 538              to: [follower.ap_id],
 539              actor: followed.ap_id,
 540              object: follow_activity.data["id"],
 541              type: "Reject"
 542            }) do
 543       conn
 544       |> put_view(UserView)
 545       |> render("show.json", %{user: follower, for: followed})
 546     else
 547       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 548     end
 549   end
 550
 551   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 552     with {:ok, friends} <- User.get_friends(user) do
 553       ids =
 554         friends
 555         |> Enum.map(fn x -> x.id end)
 556         |> Jason.encode!()
 557
 558       json(conn, ids)
 559     else
 560       _e -> bad_request_reply(conn, "Can't get friends")
 561     end
 562   end
 563
 564   def empty_array(conn, _params) do
 565     json(conn, Jason.encode!([]))
 566   end
 567
 568   def raw_empty_array(conn, _params) do
 569     json(conn, [])
 570   end
 571
 572   defp build_info_cng(user, params) do
 573     info_params =
 574       ["no_rich_text", "locked", "hide_network"]
 575       |> Enum.reduce(%{}, fn key, res ->
 576         if value = params[key] do
 577           Map.put(res, key, value == "true")
 578         else
 579           res
 580         end
 581       end)
 582
 583     info_params =
 584       if value = params["default_scope"] do
 585         Map.put(info_params, "default_scope", value)
 586       else
 587         info_params
 588       end
 589
 590     User.Info.profile_update(user.info, info_params)
 591   end
 592
 593   defp parse_profile_bio(user, params) do
 594     if bio = params["description"] do
 595       Map.put(params, "bio", User.parse_bio(bio, user))
 596     else
 597       params
 598     end
 599   end
 600
 601   def update_profile(%{assigns: %{user: user}} = conn, params) do
 602     params = parse_profile_bio(user, params)
 603     info_cng = build_info_cng(user, params)
 604
 605     with changeset <- User.update_changeset(user, params),
 606          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 607          {:ok, user} <- User.update_and_set_cache(changeset) do
 608       CommonAPI.update(user)
 609
 610       conn
 611       |> put_view(UserView)
 612       |> render("user.json", %{user: user, for: user})
 613     else
 614       error ->
 615         Logger.debug("Can't update user: #{inspect(error)}")
 616         bad_request_reply(conn, "Can't update user")
 617     end
 618   end
 619
 620   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 621     activities = TwitterAPI.search(user, params)
 622
 623     conn
 624     |> put_view(ActivityView)
 625     |> render("index.json", %{activities: activities, for: user})
 626   end
 627
 628   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 629     users = User.search(query, true)
 630
 631     conn
 632     |> put_view(UserView)
 633     |> render("index.json", %{users: users, for: user})
 634   end
 635
 636   defp bad_request_reply(conn, error_message) do
 637     json = error_json(conn, error_message)
 638     json_reply(conn, 400, json)
 639   end
 640
 641   defp json_reply(conn, status, json) do
 642     conn
 643     |> put_resp_content_type("application/json")
 644     |> send_resp(status, json)
 645   end
 646
 647   defp forbidden_json_reply(conn, error_message) do
 648     json = error_json(conn, error_message)
 649     json_reply(conn, 403, json)
 650   end
 651
 652   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 653
 654   def only_if_public_instance(conn, _) do
 655     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 656       conn
 657     else
 658       conn
 659       |> forbidden_json_reply("Invalid credentials.")
 660       |> halt()
 661     end
 662   end
 663
 664   defp error_json(conn, error_message) do
 665     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 666   end
 667
 668   def errors(conn, {:param_cast, _}) do
 669     conn
 670     |> put_status(400)
 671     |> json("Invalid parameters")
 672   end
 673
 674   def errors(conn, _) do
 675     conn
 676     |> put_status(500)
 677     |> json("Something went wrong")
 678   end
 679 end