git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.Controller do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   9
  10   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.{Repo, Activity, Object, User, Notification}
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15   alias Ecto.Changeset
  16
  17   require Logger
  18
  19   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  20   action_fallback(:errors)
  21
  22   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  23     token = Phoenix.Token.sign(conn, "user socket", user.id)
  24
  25     conn
  26     |> put_view(UserView)
  27     |> render("show.json", %{user: user, token: token, for: user})
  28   end
  29
  30   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  31     with media_ids <- extract_media_ids(status_data),
  32          {:ok, activity} <-
  33            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  34       conn
  35       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  36     else
  37       _ -> empty_status_reply(conn)
  38     end
  39   end
  40
  41   def status_update(conn, _status_data) do
  42     empty_status_reply(conn)
  43   end
  44
  45   defp empty_status_reply(conn) do
  46     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  47   end
  48
  49   defp extract_media_ids(status_data) do
  50     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  51          split_ids <- String.split(media_ids, ","),
  52          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  53       clean_ids
  54     else
  55       _e -> []
  56     end
  57   end
  58
  59   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  60     params =
  61       params
  62       |> Map.put("type", ["Create", "Announce"])
  63       |> Map.put("blocking_user", user)
  64
  65     activities = ActivityPub.fetch_public_activities(params)
  66
  67     conn
  68     |> put_view(ActivityView)
  69     |> render("index.json", %{activities: activities, for: user})
  70   end
  71
  72   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  73     params =
  74       params
  75       |> Map.put("type", ["Create", "Announce"])
  76       |> Map.put("local_only", true)
  77       |> Map.put("blocking_user", user)
  78
  79     activities = ActivityPub.fetch_public_activities(params)
  80
  81     conn
  82     |> put_view(ActivityView)
  83     |> render("index.json", %{activities: activities, for: user})
  84   end
  85
  86   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  87     params =
  88       params
  89       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  90       |> Map.put("blocking_user", user)
  91       |> Map.put("user", user)
  92
  93     activities =
  94       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  95       |> ActivityPub.contain_timeline(user)
  96
  97     conn
  98     |> put_view(ActivityView)
  99     |> render("index.json", %{activities: activities, for: user})
 100   end
 101
 102   def show_user(conn, params) do
 103     for_user = conn.assigns.user
 104
 105     with {:ok, shown} <- TwitterAPI.get_user(params),
 106          true <-
 107            User.auth_active?(shown) ||
 108              (for_user && (for_user.id == shown.id || User.superuser?(for_user))) do
 109       params =
 110         if for_user do
 111           %{user: shown, for: for_user}
 112         else
 113           %{user: shown}
 114         end
 115
 116       conn
 117       |> put_view(UserView)
 118       |> render("show.json", params)
 119     else
 120       {:error, msg} ->
 121         bad_request_reply(conn, msg)
 122
 123       false ->
 124         conn
 125         |> put_status(404)
 126         |> json(%{error: "Unconfirmed user"})
 127     end
 128   end
 129
 130   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 131     case TwitterAPI.get_user(user, params) do
 132       {:ok, target_user} ->
 133         # Twitter and ActivityPub use a different name and sense for this parameter.
 134         {include_rts, params} = Map.pop(params, "include_rts")
 135
 136         params =
 137           case include_rts do
 138             x when x == "false" or x == "0" -> Map.put(params, "exclude_reblogs", "true")
 139             _ -> params
 140           end
 141
 142         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 143
 144         conn
 145         |> put_view(ActivityView)
 146         |> render("index.json", %{activities: activities, for: user})
 147
 148       {:error, msg} ->
 149         bad_request_reply(conn, msg)
 150     end
 151   end
 152
 153   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 154     params =
 155       params
 156       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 157       |> Map.put("blocking_user", user)
 158
 159     activities = ActivityPub.fetch_activities([user.ap_id], params)
 160
 161     conn
 162     |> put_view(ActivityView)
 163     |> render("index.json", %{activities: activities, for: user})
 164   end
 165
 166   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 167     query =
 168       ActivityPub.fetch_activities_query(
 169         [user.ap_id],
 170         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 171       )
 172
 173     activities = Repo.all(query)
 174
 175     conn
 176     |> put_view(ActivityView)
 177     |> render("index.json", %{activities: activities, for: user})
 178   end
 179
 180   def notifications(%{assigns: %{user: user}} = conn, params) do
 181     notifications = Notification.for_user(user, params)
 182
 183     conn
 184     |> put_view(NotificationView)
 185     |> render("notification.json", %{notifications: notifications, for: user})
 186   end
 187
 188   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 189     Notification.set_read_up_to(user, latest_id)
 190
 191     notifications = Notification.for_user(user, params)
 192
 193     conn
 194     |> put_view(NotificationView)
 195     |> render("notification.json", %{notifications: notifications, for: user})
 196   end
 197
 198   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 199     bad_request_reply(conn, "You need to specify latest_id")
 200   end
 201
 202   def follow(%{assigns: %{user: user}} = conn, params) do
 203     case TwitterAPI.follow(user, params) do
 204       {:ok, user, followed, _activity} ->
 205         conn
 206         |> put_view(UserView)
 207         |> render("show.json", %{user: followed, for: user})
 208
 209       {:error, msg} ->
 210         forbidden_json_reply(conn, msg)
 211     end
 212   end
 213
 214   def block(%{assigns: %{user: user}} = conn, params) do
 215     case TwitterAPI.block(user, params) do
 216       {:ok, user, blocked} ->
 217         conn
 218         |> put_view(UserView)
 219         |> render("show.json", %{user: blocked, for: user})
 220
 221       {:error, msg} ->
 222         forbidden_json_reply(conn, msg)
 223     end
 224   end
 225
 226   def unblock(%{assigns: %{user: user}} = conn, params) do
 227     case TwitterAPI.unblock(user, params) do
 228       {:ok, user, blocked} ->
 229         conn
 230         |> put_view(UserView)
 231         |> render("show.json", %{user: blocked, for: user})
 232
 233       {:error, msg} ->
 234         forbidden_json_reply(conn, msg)
 235     end
 236   end
 237
 238   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 239     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 240       conn
 241       |> put_view(ActivityView)
 242       |> render("activity.json", %{activity: activity, for: user})
 243     end
 244   end
 245
 246   def unfollow(%{assigns: %{user: user}} = conn, params) do
 247     case TwitterAPI.unfollow(user, params) do
 248       {:ok, user, unfollowed} ->
 249         conn
 250         |> put_view(UserView)
 251         |> render("show.json", %{user: unfollowed, for: user})
 252
 253       {:error, msg} ->
 254         forbidden_json_reply(conn, msg)
 255     end
 256   end
 257
 258   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 259     with %Activity{} = activity <- Repo.get(Activity, id),
 260          true <- ActivityPub.visible_for_user?(activity, user) do
 261       conn
 262       |> put_view(ActivityView)
 263       |> render("activity.json", %{activity: activity, for: user})
 264     end
 265   end
 266
 267   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 268     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 269          activities <-
 270            ActivityPub.fetch_activities_for_context(context, %{
 271              "blocking_user" => user,
 272              "user" => user
 273            }) do
 274       conn
 275       |> put_view(ActivityView)
 276       |> render("index.json", %{activities: activities, for: user})
 277     end
 278   end
 279
 280   @doc """
 281   Updates metadata of uploaded media object.
 282   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 283   """
 284   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 285     object = Repo.get(Object, id)
 286     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 287
 288     {conn, status, response_body} =
 289       cond do
 290         !object ->
 291           {halt(conn), :not_found, ""}
 292
 293         !Object.authorize_mutation(object, user) ->
 294           {halt(conn), :forbidden, "You can only update your own uploads."}
 295
 296         !is_binary(description) ->
 297           {conn, :not_modified, ""}
 298
 299         true ->
 300           new_data = Map.put(object.data, "name", description)
 301
 302           {:ok, _} =
 303             object
 304             |> Object.change(%{data: new_data})
 305             |> Repo.update()
 306
 307           {conn, :no_content, ""}
 308       end
 309
 310     conn
 311     |> put_status(status)
 312     |> json(response_body)
 313   end
 314
 315   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 316     response = TwitterAPI.upload(media, user)
 317
 318     conn
 319     |> put_resp_content_type("application/atom+xml")
 320     |> send_resp(200, response)
 321   end
 322
 323   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 324     response = TwitterAPI.upload(media, user, "json")
 325
 326     conn
 327     |> json_reply(200, response)
 328   end
 329
 330   def get_by_id_or_ap_id(id) do
 331     activity = Repo.get(Activity, id) || Activity.get_create_by_object_ap_id(id)
 332
 333     if activity.data["type"] == "Create" do
 334       activity
 335     else
 336       Activity.get_create_by_object_ap_id(activity.data["object"])
 337     end
 338   end
 339
 340   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 341     with {:ok, activity} <- TwitterAPI.fav(user, id) do
 342       conn
 343       |> put_view(ActivityView)
 344       |> render("activity.json", %{activity: activity, for: user})
 345     else
 346       _ -> json_reply(conn, 400, Jason.encode!(%{}))
 347     end
 348   end
 349
 350   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 351     with {:ok, activity} <- TwitterAPI.unfav(user, id) do
 352       conn
 353       |> put_view(ActivityView)
 354       |> render("activity.json", %{activity: activity, for: user})
 355     else
 356       _ -> json_reply(conn, 400, Jason.encode!(%{}))
 357     end
 358   end
 359
 360   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 361     with {:ok, activity} <- TwitterAPI.repeat(user, id) do
 362       conn
 363       |> put_view(ActivityView)
 364       |> render("activity.json", %{activity: activity, for: user})
 365     else
 366       _ -> json_reply(conn, 400, Jason.encode!(%{}))
 367     end
 368   end
 369
 370   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 371     with {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 372       conn
 373       |> put_view(ActivityView)
 374       |> render("activity.json", %{activity: activity, for: user})
 375     else
 376       _ -> json_reply(conn, 400, Jason.encode!(%{}))
 377     end
 378   end
 379
 380   def pin(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 381     with {:ok, activity} <- TwitterAPI.pin(user, id) do
 382       conn
 383       |> put_view(ActivityView)
 384       |> render("activity.json", %{activity: activity, for: user})
 385     else
 386       {:error, message} -> bad_request_reply(conn, message)
 387       err -> err
 388     end
 389   end
 390
 391   def unpin(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 392     with {:ok, activity} <- TwitterAPI.unpin(user, id) do
 393       conn
 394       |> put_view(ActivityView)
 395       |> render("activity.json", %{activity: activity, for: user})
 396     else
 397       {:error, message} -> bad_request_reply(conn, message)
 398       err -> err
 399     end
 400   end
 401
 402   def register(conn, params) do
 403     with {:ok, user} <- TwitterAPI.register_user(params) do
 404       conn
 405       |> put_view(UserView)
 406       |> render("show.json", %{user: user})
 407     else
 408       {:error, errors} ->
 409         conn
 410         |> json_reply(400, Jason.encode!(errors))
 411     end
 412   end
 413
 414   def password_reset(conn, params) do
 415     nickname_or_email = params["email"] || params["nickname"]
 416
 417     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 418       json_response(conn, :no_content, "")
 419     end
 420   end
 421
 422   def confirm_email(conn, %{"user_id" => uid, "token" => token}) do
 423     with %User{} = user <- Repo.get(User, uid),
 424          true <- user.local,
 425          true <- user.info.confirmation_pending,
 426          true <- user.info.confirmation_token == token,
 427          info_change <- User.Info.confirmation_changeset(user.info, :confirmed),
 428          changeset <- Changeset.change(user) |> Changeset.put_embed(:info, info_change),
 429          {:ok, _} <- User.update_and_set_cache(changeset) do
 430       conn
 431       |> redirect(to: "/")
 432     end
 433   end
 434
 435   def resend_confirmation_email(conn, params) do
 436     nickname_or_email = params["email"] || params["nickname"]
 437
 438     with %User{} = user <- User.get_by_nickname_or_email(nickname_or_email),
 439          {:ok, _} <- User.try_send_confirmation_email(user) do
 440       conn
 441       |> json_response(:no_content, "")
 442     end
 443   end
 444
 445   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 446     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 447     change = Changeset.change(user, %{avatar: object.data})
 448     {:ok, user} = User.update_and_set_cache(change)
 449     CommonAPI.update(user)
 450
 451     conn
 452     |> put_view(UserView)
 453     |> render("show.json", %{user: user, for: user})
 454   end
 455
 456   def update_banner(%{assigns: %{user: user}} = conn, params) do
 457     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 458          new_info <- %{"banner" => object.data},
 459          info_cng <- User.Info.profile_update(user.info, new_info),
 460          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 461          {:ok, user} <- User.update_and_set_cache(changeset) do
 462       CommonAPI.update(user)
 463       %{"url" => [%{"href" => href} | _]} = object.data
 464       response = %{url: href} |> Jason.encode!()
 465
 466       conn
 467       |> json_reply(200, response)
 468     end
 469   end
 470
 471   def update_background(%{assigns: %{user: user}} = conn, params) do
 472     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 473          new_info <- %{"background" => object.data},
 474          info_cng <- User.Info.profile_update(user.info, new_info),
 475          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 476          {:ok, _user} <- User.update_and_set_cache(changeset) do
 477       %{"url" => [%{"href" => href} | _]} = object.data
 478       response = %{url: href} |> Jason.encode!()
 479
 480       conn
 481       |> json_reply(200, response)
 482     end
 483   end
 484
 485   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 486     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 487          response <- Jason.encode!(user_map) do
 488       conn
 489       |> json_reply(200, response)
 490     else
 491       _e ->
 492         conn
 493         |> put_status(404)
 494         |> json(%{error: "Can't find user"})
 495     end
 496   end
 497
 498   def followers(%{assigns: %{user: for_user}} = conn, params) do
 499     {:ok, page} = Ecto.Type.cast(:integer, params["page"] || 1)
 500
 501     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 502          {:ok, followers} <- User.get_followers(user, page) do
 503       followers =
 504         cond do
 505           for_user && user.id == for_user.id -> followers
 506           user.info.hide_followers -> []
 507           true -> followers
 508         end
 509
 510       conn
 511       |> put_view(UserView)
 512       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 513     else
 514       _e -> bad_request_reply(conn, "Can't get followers")
 515     end
 516   end
 517
 518   def friends(%{assigns: %{user: for_user}} = conn, params) do
 519     {:ok, page} = Ecto.Type.cast(:integer, params["page"] || 1)
 520
 521     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 522          {:ok, friends} <- User.get_friends(user, page) do
 523       friends =
 524         cond do
 525           for_user && user.id == for_user.id -> friends
 526           user.info.hide_follows -> []
 527           true -> friends
 528         end
 529
 530       conn
 531       |> put_view(UserView)
 532       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 533     else
 534       _e -> bad_request_reply(conn, "Can't get friends")
 535     end
 536   end
 537
 538   def blocks(%{assigns: %{user: user}} = conn, _params) do
 539     with blocked_users <- User.blocked_users(user) do
 540       conn
 541       |> put_view(UserView)
 542       |> render("index.json", %{users: blocked_users, for: user})
 543     end
 544   end
 545
 546   def friend_requests(conn, params) do
 547     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 548          {:ok, friend_requests} <- User.get_follow_requests(user) do
 549       conn
 550       |> put_view(UserView)
 551       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 552     else
 553       _e -> bad_request_reply(conn, "Can't get friend requests")
 554     end
 555   end
 556
 557   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 558     with followed <- conn.assigns[:user],
 559          %User{} = follower <- Repo.get(User, uid),
 560          {:ok, follower} <- User.maybe_follow(follower, followed),
 561          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 562          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 563          {:ok, _activity} <-
 564            ActivityPub.accept(%{
 565              to: [follower.ap_id],
 566              actor: followed.ap_id,
 567              object: follow_activity.data["id"],
 568              type: "Accept"
 569            }) do
 570       conn
 571       |> put_view(UserView)
 572       |> render("show.json", %{user: follower, for: followed})
 573     else
 574       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 575     end
 576   end
 577
 578   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 579     with followed <- conn.assigns[:user],
 580          %User{} = follower <- Repo.get(User, uid),
 581          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 582          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 583          {:ok, _activity} <-
 584            ActivityPub.reject(%{
 585              to: [follower.ap_id],
 586              actor: followed.ap_id,
 587              object: follow_activity.data["id"],
 588              type: "Reject"
 589            }) do
 590       conn
 591       |> put_view(UserView)
 592       |> render("show.json", %{user: follower, for: followed})
 593     else
 594       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 595     end
 596   end
 597
 598   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 599     with {:ok, friends} <- User.get_friends(user) do
 600       ids =
 601         friends
 602         |> Enum.map(fn x -> x.id end)
 603         |> Jason.encode!()
 604
 605       json(conn, ids)
 606     else
 607       _e -> bad_request_reply(conn, "Can't get friends")
 608     end
 609   end
 610
 611   def empty_array(conn, _params) do
 612     json(conn, Jason.encode!([]))
 613   end
 614
 615   def raw_empty_array(conn, _params) do
 616     json(conn, [])
 617   end
 618
 619   defp build_info_cng(user, params) do
 620     info_params =
 621       ["no_rich_text", "locked", "hide_followers", "hide_follows", "show_role"]
 622       |> Enum.reduce(%{}, fn key, res ->
 623         if value = params[key] do
 624           Map.put(res, key, value == "true")
 625         else
 626           res
 627         end
 628       end)
 629
 630     info_params =
 631       if value = params["default_scope"] do
 632         Map.put(info_params, "default_scope", value)
 633       else
 634         info_params
 635       end
 636
 637     User.Info.profile_update(user.info, info_params)
 638   end
 639
 640   defp parse_profile_bio(user, params) do
 641     if bio = params["description"] do
 642       Map.put(params, "bio", User.parse_bio(bio, user))
 643     else
 644       params
 645     end
 646   end
 647
 648   def update_profile(%{assigns: %{user: user}} = conn, params) do
 649     params = parse_profile_bio(user, params)
 650     info_cng = build_info_cng(user, params)
 651
 652     with changeset <- User.update_changeset(user, params),
 653          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 654          {:ok, user} <- User.update_and_set_cache(changeset) do
 655       CommonAPI.update(user)
 656
 657       conn
 658       |> put_view(UserView)
 659       |> render("user.json", %{user: user, for: user})
 660     else
 661       error ->
 662         Logger.debug("Can't update user: #{inspect(error)}")
 663         bad_request_reply(conn, "Can't update user")
 664     end
 665   end
 666
 667   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 668     activities = TwitterAPI.search(user, params)
 669
 670     conn
 671     |> put_view(ActivityView)
 672     |> render("index.json", %{activities: activities, for: user})
 673   end
 674
 675   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 676     users = User.search(query, true, user)
 677
 678     conn
 679     |> put_view(UserView)
 680     |> render("index.json", %{users: users, for: user})
 681   end
 682
 683   defp bad_request_reply(conn, error_message) do
 684     json = error_json(conn, error_message)
 685     json_reply(conn, 400, json)
 686   end
 687
 688   defp json_reply(conn, status, json) do
 689     conn
 690     |> put_resp_content_type("application/json")
 691     |> send_resp(status, json)
 692   end
 693
 694   defp forbidden_json_reply(conn, error_message) do
 695     json = error_json(conn, error_message)
 696     json_reply(conn, 403, json)
 697   end
 698
 699   def only_if_public_instance(%{assigns: %{user: %User{}}} = conn, _), do: conn
 700
 701   def only_if_public_instance(conn, _) do
 702     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 703       conn
 704     else
 705       conn
 706       |> forbidden_json_reply("Invalid credentials.")
 707       |> halt()
 708     end
 709   end
 710
 711   defp error_json(conn, error_message) do
 712     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 713   end
 714
 715   def errors(conn, {:param_cast, _}) do
 716     conn
 717     |> put_status(400)
 718     |> json("Invalid parameters")
 719   end
 720
 721   def errors(conn, _) do
 722     conn
 723     |> put_status(500)
 724     |> json("Something went wrong")
 725   end
 726 end