git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   plug(:fetch_flash when action in [:confirm_email, :resend_confirmation_email])
  17   action_fallback(:errors)
  18
  19   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  20     token = Phoenix.Token.sign(conn, "user socket", user.id)
  21
  22     conn
  23     |> put_view(UserView)
  24     |> render("show.json", %{user: user, token: token})
  25   end
  26
  27   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  28     with media_ids <- extract_media_ids(status_data),
  29          {:ok, activity} <-
  30            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  31       conn
  32       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  33     else
  34       _ -> empty_status_reply(conn)
  35     end
  36   end
  37
  38   def status_update(conn, _status_data) do
  39     empty_status_reply(conn)
  40   end
  41
  42   defp empty_status_reply(conn) do
  43     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  44   end
  45
  46   defp extract_media_ids(status_data) do
  47     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  48          split_ids <- String.split(media_ids, ","),
  49          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  50       clean_ids
  51     else
  52       _e -> []
  53     end
  54   end
  55
  56   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  57     params =
  58       params
  59       |> Map.put("type", ["Create", "Announce"])
  60       |> Map.put("blocking_user", user)
  61
  62     activities = ActivityPub.fetch_public_activities(params)
  63
  64     conn
  65     |> put_view(ActivityView)
  66     |> render("index.json", %{activities: activities, for: user})
  67   end
  68
  69   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  70     params =
  71       params
  72       |> Map.put("type", ["Create", "Announce"])
  73       |> Map.put("local_only", true)
  74       |> Map.put("blocking_user", user)
  75
  76     activities = ActivityPub.fetch_public_activities(params)
  77
  78     conn
  79     |> put_view(ActivityView)
  80     |> render("index.json", %{activities: activities, for: user})
  81   end
  82
  83   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  84     params =
  85       params
  86       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  87       |> Map.put("blocking_user", user)
  88       |> Map.put("user", user)
  89
  90     activities =
  91       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  92       |> ActivityPub.contain_timeline(user)
  93
  94     conn
  95     |> put_view(ActivityView)
  96     |> render("index.json", %{activities: activities, for: user})
  97   end
  98
  99   def show_user(conn, params) do
 100     with {:ok, shown} <- TwitterAPI.get_user(params) do
 101       params =
 102         if user = conn.assigns.user do
 103           %{user: shown, for: user}
 104         else
 105           %{user: shown}
 106         end
 107
 108       conn
 109       |> put_view(UserView)
 110       |> render("show.json", params)
 111     else
 112       {:error, msg} ->
 113         bad_request_reply(conn, msg)
 114     end
 115   end
 116
 117   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 118     case TwitterAPI.get_user(user, params) do
 119       {:ok, target_user} ->
 120         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 121
 122         conn
 123         |> put_view(ActivityView)
 124         |> render("index.json", %{activities: activities, for: user})
 125
 126       {:error, msg} ->
 127         bad_request_reply(conn, msg)
 128     end
 129   end
 130
 131   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 132     params =
 133       params
 134       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 135       |> Map.put("blocking_user", user)
 136
 137     activities = ActivityPub.fetch_activities([user.ap_id], params)
 138
 139     conn
 140     |> put_view(ActivityView)
 141     |> render("index.json", %{activities: activities, for: user})
 142   end
 143
 144   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 145     query =
 146       ActivityPub.fetch_activities_query(
 147         [user.ap_id],
 148         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 149       )
 150
 151     activities = Repo.all(query)
 152
 153     conn
 154     |> put_view(ActivityView)
 155     |> render("index.json", %{activities: activities, for: user})
 156   end
 157
 158   def notifications(%{assigns: %{user: user}} = conn, params) do
 159     notifications = Notification.for_user(user, params)
 160
 161     conn
 162     |> put_view(NotificationView)
 163     |> render("notification.json", %{notifications: notifications, for: user})
 164   end
 165
 166   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 167     Notification.set_read_up_to(user, latest_id)
 168
 169     notifications = Notification.for_user(user, params)
 170
 171     conn
 172     |> put_view(NotificationView)
 173     |> render("notification.json", %{notifications: notifications, for: user})
 174   end
 175
 176   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 177     bad_request_reply(conn, "You need to specify latest_id")
 178   end
 179
 180   def follow(%{assigns: %{user: user}} = conn, params) do
 181     case TwitterAPI.follow(user, params) do
 182       {:ok, user, followed, _activity} ->
 183         conn
 184         |> put_view(UserView)
 185         |> render("show.json", %{user: followed, for: user})
 186
 187       {:error, msg} ->
 188         forbidden_json_reply(conn, msg)
 189     end
 190   end
 191
 192   def block(%{assigns: %{user: user}} = conn, params) do
 193     case TwitterAPI.block(user, params) do
 194       {:ok, user, blocked} ->
 195         conn
 196         |> put_view(UserView)
 197         |> render("show.json", %{user: blocked, for: user})
 198
 199       {:error, msg} ->
 200         forbidden_json_reply(conn, msg)
 201     end
 202   end
 203
 204   def unblock(%{assigns: %{user: user}} = conn, params) do
 205     case TwitterAPI.unblock(user, params) do
 206       {:ok, user, blocked} ->
 207         conn
 208         |> put_view(UserView)
 209         |> render("show.json", %{user: blocked, for: user})
 210
 211       {:error, msg} ->
 212         forbidden_json_reply(conn, msg)
 213     end
 214   end
 215
 216   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 217     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 218       conn
 219       |> put_view(ActivityView)
 220       |> render("activity.json", %{activity: activity, for: user})
 221     end
 222   end
 223
 224   def unfollow(%{assigns: %{user: user}} = conn, params) do
 225     case TwitterAPI.unfollow(user, params) do
 226       {:ok, user, unfollowed} ->
 227         conn
 228         |> put_view(UserView)
 229         |> render("show.json", %{user: unfollowed, for: user})
 230
 231       {:error, msg} ->
 232         forbidden_json_reply(conn, msg)
 233     end
 234   end
 235
 236   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 237     with %Activity{} = activity <- Repo.get(Activity, id),
 238          true <- ActivityPub.visible_for_user?(activity, user) do
 239       conn
 240       |> put_view(ActivityView)
 241       |> render("activity.json", %{activity: activity, for: user})
 242     end
 243   end
 244
 245   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 246     id = String.to_integer(id)
 247
 248     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 249          activities <-
 250            ActivityPub.fetch_activities_for_context(context, %{
 251              "blocking_user" => user,
 252              "user" => user
 253            }) do
 254       conn
 255       |> put_view(ActivityView)
 256       |> render("index.json", %{activities: activities, for: user})
 257     end
 258   end
 259
 260   @doc """
 261   Updates metadata of uploaded media object.
 262   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 263   """
 264   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 265     object = Repo.get(Object, id)
 266     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 267
 268     {conn, status, response_body} =
 269       cond do
 270         !object ->
 271           {halt(conn), :not_found, ""}
 272
 273         !Object.authorize_mutation(object, user) ->
 274           {halt(conn), :forbidden, "You can only update your own uploads."}
 275
 276         !is_binary(description) ->
 277           {conn, :not_modified, ""}
 278
 279         true ->
 280           new_data = Map.put(object.data, "name", description)
 281
 282           {:ok, _} =
 283             object
 284             |> Object.change(%{data: new_data})
 285             |> Repo.update()
 286
 287           {conn, :no_content, ""}
 288       end
 289
 290     conn
 291     |> put_status(status)
 292     |> json(response_body)
 293   end
 294
 295   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 296     response = TwitterAPI.upload(media, user)
 297
 298     conn
 299     |> put_resp_content_type("application/atom+xml")
 300     |> send_resp(200, response)
 301   end
 302
 303   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 304     response = TwitterAPI.upload(media, user, "json")
 305
 306     conn
 307     |> json_reply(200, response)
 308   end
 309
 310   def get_by_id_or_ap_id(id) do
 311     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 312
 313     if activity.data["type"] == "Create" do
 314       activity
 315     else
 316       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 317     end
 318   end
 319
 320   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 321     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 322          {:ok, activity} <- TwitterAPI.fav(user, id) do
 323       conn
 324       |> put_view(ActivityView)
 325       |> render("activity.json", %{activity: activity, for: user})
 326     end
 327   end
 328
 329   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 330     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 331          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 332       conn
 333       |> put_view(ActivityView)
 334       |> render("activity.json", %{activity: activity, for: user})
 335     end
 336   end
 337
 338   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 339     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 340          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 341       conn
 342       |> put_view(ActivityView)
 343       |> render("activity.json", %{activity: activity, for: user})
 344     end
 345   end
 346
 347   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 348     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 349          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 350       conn
 351       |> put_view(ActivityView)
 352       |> render("activity.json", %{activity: activity, for: user})
 353     end
 354   end
 355
 356   def register(conn, params) do
 357     with {:ok, user} <- TwitterAPI.register_user(params) do
 358       conn
 359       |> put_view(UserView)
 360       |> render("show.json", %{user: user})
 361     else
 362       {:error, errors} ->
 363         conn
 364         |> json_reply(400, Jason.encode!(errors))
 365     end
 366   end
 367
 368   def password_reset(conn, params) do
 369     nickname_or_email = params["email"] || params["nickname"]
 370
 371     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 372       json_response(conn, :no_content, "")
 373     end
 374   end
 375
 376   def confirm_email(conn, %{"token" => token}) do
 377     with %User{} = user <- User.get_by_confirmation_token(token),
 378          true <- user.local,
 379          info_change <- User.Info.confirmation_changeset(user.info, :confirmed),
 380          changeset <- Changeset.change(user) |> Changeset.put_embed(:info, info_change),
 381          {:ok, _} <- User.update_and_set_cache(changeset) do
 382       conn
 383       |> put_flash(:info, "Email confirmed. Please sign in.")
 384       |> redirect(to: "/")
 385     end
 386   end
 387
 388   def resend_confirmation_email(conn, params) do
 389     nickname_or_email = params["email"] || params["nickname"]
 390
 391     with %User{} = user <- User.get_by_nickname_or_email(nickname_or_email),
 392          {:ok, _} <- User.try_send_confirmation_email(user) do
 393       conn
 394       |> put_flash(:info, "Email confirmation has been sent.")
 395       |> json_response(:no_content, "")
 396     end
 397   end
 398
 399   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 400     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 401     change = Changeset.change(user, %{avatar: object.data})
 402     {:ok, user} = User.update_and_set_cache(change)
 403     CommonAPI.update(user)
 404
 405     conn
 406     |> put_view(UserView)
 407     |> render("show.json", %{user: user, for: user})
 408   end
 409
 410   def update_banner(%{assigns: %{user: user}} = conn, params) do
 411     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 412          new_info <- %{"banner" => object.data},
 413          info_cng <- User.Info.profile_update(user.info, new_info),
 414          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 415          {:ok, user} <- User.update_and_set_cache(changeset) do
 416       CommonAPI.update(user)
 417       %{"url" => [%{"href" => href} | _]} = object.data
 418       response = %{url: href} |> Jason.encode!()
 419
 420       conn
 421       |> json_reply(200, response)
 422     end
 423   end
 424
 425   def update_background(%{assigns: %{user: user}} = conn, params) do
 426     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 427          new_info <- %{"background" => object.data},
 428          info_cng <- User.Info.profile_update(user.info, new_info),
 429          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 430          {:ok, _user} <- User.update_and_set_cache(changeset) do
 431       %{"url" => [%{"href" => href} | _]} = object.data
 432       response = %{url: href} |> Jason.encode!()
 433
 434       conn
 435       |> json_reply(200, response)
 436     end
 437   end
 438
 439   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 440     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 441          response <- Jason.encode!(user_map) do
 442       conn
 443       |> json_reply(200, response)
 444     else
 445       _e ->
 446         conn
 447         |> put_status(404)
 448         |> json(%{error: "Can't find user"})
 449     end
 450   end
 451
 452   def followers(%{assigns: %{user: for_user}} = conn, params) do
 453     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 454          {:ok, followers} <- User.get_followers(user) do
 455       followers =
 456         cond do
 457           for_user && user.id == for_user.id -> followers
 458           user.info.hide_network -> []
 459           true -> followers
 460         end
 461
 462       conn
 463       |> put_view(UserView)
 464       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 465     else
 466       _e -> bad_request_reply(conn, "Can't get followers")
 467     end
 468   end
 469
 470   def friends(%{assigns: %{user: for_user}} = conn, params) do
 471     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 472          {:ok, friends} <- User.get_friends(user) do
 473       friends =
 474         cond do
 475           for_user && user.id == for_user.id -> friends
 476           user.info.hide_network -> []
 477           true -> friends
 478         end
 479
 480       conn
 481       |> put_view(UserView)
 482       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 483     else
 484       _e -> bad_request_reply(conn, "Can't get friends")
 485     end
 486   end
 487
 488   def friend_requests(conn, params) do
 489     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 490          {:ok, friend_requests} <- User.get_follow_requests(user) do
 491       conn
 492       |> put_view(UserView)
 493       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 494     else
 495       _e -> bad_request_reply(conn, "Can't get friend requests")
 496     end
 497   end
 498
 499   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 500     with followed <- conn.assigns[:user],
 501          uid when is_number(uid) <- String.to_integer(uid),
 502          %User{} = follower <- Repo.get(User, uid),
 503          {:ok, follower} <- User.maybe_follow(follower, followed),
 504          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 505          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 506          {:ok, _activity} <-
 507            ActivityPub.accept(%{
 508              to: [follower.ap_id],
 509              actor: followed.ap_id,
 510              object: follow_activity.data["id"],
 511              type: "Accept"
 512            }) do
 513       conn
 514       |> put_view(UserView)
 515       |> render("show.json", %{user: follower, for: followed})
 516     else
 517       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 518     end
 519   end
 520
 521   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 522     with followed <- conn.assigns[:user],
 523          uid when is_number(uid) <- String.to_integer(uid),
 524          %User{} = follower <- Repo.get(User, uid),
 525          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 526          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 527          {:ok, _activity} <-
 528            ActivityPub.reject(%{
 529              to: [follower.ap_id],
 530              actor: followed.ap_id,
 531              object: follow_activity.data["id"],
 532              type: "Reject"
 533            }) do
 534       conn
 535       |> put_view(UserView)
 536       |> render("show.json", %{user: follower, for: followed})
 537     else
 538       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 539     end
 540   end
 541
 542   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 543     with {:ok, friends} <- User.get_friends(user) do
 544       ids =
 545         friends
 546         |> Enum.map(fn x -> x.id end)
 547         |> Jason.encode!()
 548
 549       json(conn, ids)
 550     else
 551       _e -> bad_request_reply(conn, "Can't get friends")
 552     end
 553   end
 554
 555   def empty_array(conn, _params) do
 556     json(conn, Jason.encode!([]))
 557   end
 558
 559   def raw_empty_array(conn, _params) do
 560     json(conn, [])
 561   end
 562
 563   defp build_info_cng(user, params) do
 564     info_params =
 565       ["no_rich_text", "locked", "hide_network"]
 566       |> Enum.reduce(%{}, fn key, res ->
 567         if value = params[key] do
 568           Map.put(res, key, value == "true")
 569         else
 570           res
 571         end
 572       end)
 573
 574     info_params =
 575       if value = params["default_scope"] do
 576         Map.put(info_params, "default_scope", value)
 577       else
 578         info_params
 579       end
 580
 581     User.Info.profile_update(user.info, info_params)
 582   end
 583
 584   defp parse_profile_bio(user, params) do
 585     if bio = params["description"] do
 586       Map.put(params, "bio", User.parse_bio(bio, user))
 587     else
 588       params
 589     end
 590   end
 591
 592   def update_profile(%{assigns: %{user: user}} = conn, params) do
 593     params = parse_profile_bio(user, params)
 594     info_cng = build_info_cng(user, params)
 595
 596     with changeset <- User.update_changeset(user, params),
 597          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 598          {:ok, user} <- User.update_and_set_cache(changeset) do
 599       CommonAPI.update(user)
 600
 601       conn
 602       |> put_view(UserView)
 603       |> render("user.json", %{user: user, for: user})
 604     else
 605       error ->
 606         Logger.debug("Can't update user: #{inspect(error)}")
 607         bad_request_reply(conn, "Can't update user")
 608     end
 609   end
 610
 611   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 612     activities = TwitterAPI.search(user, params)
 613
 614     conn
 615     |> put_view(ActivityView)
 616     |> render("index.json", %{activities: activities, for: user})
 617   end
 618
 619   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 620     users = User.search(query, true)
 621
 622     conn
 623     |> put_view(UserView)
 624     |> render("index.json", %{users: users, for: user})
 625   end
 626
 627   defp bad_request_reply(conn, error_message) do
 628     json = error_json(conn, error_message)
 629     json_reply(conn, 400, json)
 630   end
 631
 632   defp json_reply(conn, status, json) do
 633     conn
 634     |> put_resp_content_type("application/json")
 635     |> send_resp(status, json)
 636   end
 637
 638   defp forbidden_json_reply(conn, error_message) do
 639     json = error_json(conn, error_message)
 640     json_reply(conn, 403, json)
 641   end
 642
 643   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 644
 645   def only_if_public_instance(conn, _) do
 646     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 647       conn
 648     else
 649       conn
 650       |> forbidden_json_reply("Invalid credentials.")
 651       |> halt()
 652     end
 653   end
 654
 655   defp error_json(conn, error_message) do
 656     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 657   end
 658
 659   def errors(conn, {:param_cast, _}) do
 660     conn
 661     |> put_status(400)
 662     |> json("Invalid parameters")
 663   end
 664
 665   def errors(conn, _) do
 666     conn
 667     |> put_status(500)
 668     |> json("Something went wrong")
 669   end
 670 end