git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   4   alias Pleroma.Web.CommonAPI
   5   alias Pleroma.{Repo, Activity, Object, User, Notification}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.ActivityPub.Utils
   8   alias Ecto.Changeset
   9
  10   require Logger
  11
  12   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  13   action_fallback(:errors)
  14
  15   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  16     token = Phoenix.Token.sign(conn, "user socket", user.id)
  17     render(conn, UserView, "show.json", %{user: user, token: token})
  18   end
  19
  20   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  21     with media_ids <- extract_media_ids(status_data),
  22          {:ok, activity} <-
  23            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  24       conn
  25       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  26     else
  27       _ -> empty_status_reply(conn)
  28     end
  29   end
  30
  31   def status_update(conn, _status_data) do
  32     empty_status_reply(conn)
  33   end
  34
  35   defp empty_status_reply(conn) do
  36     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  37   end
  38
  39   defp extract_media_ids(status_data) do
  40     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  41          split_ids <- String.split(media_ids, ","),
  42          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  43       clean_ids
  44     else
  45       _e -> []
  46     end
  47   end
  48
  49   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  50     params =
  51       params
  52       |> Map.put("type", ["Create", "Announce"])
  53       |> Map.put("blocking_user", user)
  54
  55     activities = ActivityPub.fetch_public_activities(params)
  56
  57     conn
  58     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  59   end
  60
  61   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  62     params =
  63       params
  64       |> Map.put("type", ["Create", "Announce"])
  65       |> Map.put("local_only", true)
  66       |> Map.put("blocking_user", user)
  67
  68     activities = ActivityPub.fetch_public_activities(params)
  69
  70     conn
  71     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  72   end
  73
  74   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  75     params =
  76       params
  77       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  78       |> Map.put("blocking_user", user)
  79       |> Map.put("user", user)
  80
  81     activities =
  82       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  83       |> ActivityPub.contain_timeline(user)
  84
  85     conn
  86     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  87   end
  88
  89   def show_user(conn, params) do
  90     with {:ok, shown} <- TwitterAPI.get_user(params) do
  91       if user = conn.assigns.user do
  92         render(conn, UserView, "show.json", %{user: shown, for: user})
  93       else
  94         render(conn, UserView, "show.json", %{user: shown})
  95       end
  96     else
  97       {:error, msg} ->
  98         bad_request_reply(conn, msg)
  99     end
 100   end
 101
 102   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 103     case TwitterAPI.get_user(user, params) do
 104       {:ok, target_user} ->
 105         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 106
 107         conn
 108         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 109
 110       {:error, msg} ->
 111         bad_request_reply(conn, msg)
 112     end
 113   end
 114
 115   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 116     params =
 117       params
 118       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 119       |> Map.put("blocking_user", user)
 120
 121     activities = ActivityPub.fetch_activities([user.ap_id], params)
 122
 123     conn
 124     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 125   end
 126
 127   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 128     query =
 129       ActivityPub.fetch_activities_query(
 130         [user.ap_id],
 131         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 132       )
 133
 134     activities = Repo.all(query)
 135
 136     conn
 137     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 138   end
 139
 140   def notifications(%{assigns: %{user: user}} = conn, params) do
 141     notifications = Notification.for_user(user, params)
 142
 143     conn
 144     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 145   end
 146
 147   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 148     Notification.set_read_up_to(user, latest_id)
 149
 150     notifications = Notification.for_user(user, params)
 151
 152     conn
 153     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 154   end
 155
 156   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 157     bad_request_reply(conn, "You need to specify latest_id")
 158   end
 159
 160   def follow(%{assigns: %{user: user}} = conn, params) do
 161     case TwitterAPI.follow(user, params) do
 162       {:ok, user, followed, _activity} ->
 163         render(conn, UserView, "show.json", %{user: followed, for: user})
 164
 165       {:error, msg} ->
 166         forbidden_json_reply(conn, msg)
 167     end
 168   end
 169
 170   def block(%{assigns: %{user: user}} = conn, params) do
 171     case TwitterAPI.block(user, params) do
 172       {:ok, user, blocked} ->
 173         render(conn, UserView, "show.json", %{user: blocked, for: user})
 174
 175       {:error, msg} ->
 176         forbidden_json_reply(conn, msg)
 177     end
 178   end
 179
 180   def unblock(%{assigns: %{user: user}} = conn, params) do
 181     case TwitterAPI.unblock(user, params) do
 182       {:ok, user, blocked} ->
 183         render(conn, UserView, "show.json", %{user: blocked, for: user})
 184
 185       {:error, msg} ->
 186         forbidden_json_reply(conn, msg)
 187     end
 188   end
 189
 190   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 191     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 192       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 193     end
 194   end
 195
 196   def unfollow(%{assigns: %{user: user}} = conn, params) do
 197     case TwitterAPI.unfollow(user, params) do
 198       {:ok, user, unfollowed} ->
 199         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 200
 201       {:error, msg} ->
 202         forbidden_json_reply(conn, msg)
 203     end
 204   end
 205
 206   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 207     with %Activity{} = activity <- Repo.get(Activity, id),
 208          true <- ActivityPub.visible_for_user?(activity, user) do
 209       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 210     end
 211   end
 212
 213   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 214     id = String.to_integer(id)
 215
 216     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 217          activities <-
 218            ActivityPub.fetch_activities_for_context(context, %{
 219              "blocking_user" => user,
 220              "user" => user
 221            }) do
 222       conn
 223       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 224     end
 225   end
 226
 227   @doc """
 228   Updates metadata of uploaded media object.
 229   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 230   """
 231   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 232     object = Repo.get(Object, id)
 233     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 234
 235     {conn, status, response_body} =
 236       cond do
 237         !object ->
 238           {halt(conn), :not_found, ""}
 239
 240         !Object.authorize_mutation(object, user) ->
 241           {halt(conn), :forbidden, "You can only update your own uploads."}
 242
 243         !is_binary(description) ->
 244           {conn, :not_modified, ""}
 245
 246         true ->
 247           new_data = Map.put(object.data, "name", description)
 248
 249           {:ok, _} =
 250             object
 251             |> Object.change(%{data: new_data})
 252             |> Repo.update()
 253
 254           {conn, :no_content, ""}
 255       end
 256
 257     conn
 258     |> put_status(status)
 259     |> json(response_body)
 260   end
 261
 262   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 263     response = TwitterAPI.upload(media, user)
 264
 265     conn
 266     |> put_resp_content_type("application/atom+xml")
 267     |> send_resp(200, response)
 268   end
 269
 270   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 271     response = TwitterAPI.upload(media, user, "json")
 272
 273     conn
 274     |> json_reply(200, response)
 275   end
 276
 277   def get_by_id_or_ap_id(id) do
 278     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 279
 280     if activity.data["type"] == "Create" do
 281       activity
 282     else
 283       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 284     end
 285   end
 286
 287   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 288     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 289          {:ok, activity} <- TwitterAPI.fav(user, id) do
 290       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 291     end
 292   end
 293
 294   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 295     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 296          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 297       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 298     end
 299   end
 300
 301   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 302     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 303          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 304       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 305     end
 306   end
 307
 308   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 309     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 310          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 311       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 312     end
 313   end
 314
 315   def register(conn, params) do
 316     with {:ok, user} <- TwitterAPI.register_user(params) do
 317       render(conn, UserView, "show.json", %{user: user})
 318     else
 319       {:error, errors} ->
 320         conn
 321         |> json_reply(400, Jason.encode!(errors))
 322     end
 323   end
 324
 325   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 326     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 327     change = Changeset.change(user, %{avatar: object.data})
 328     {:ok, user} = User.update_and_set_cache(change)
 329     CommonAPI.update(user)
 330
 331     render(conn, UserView, "show.json", %{user: user, for: user})
 332   end
 333
 334   def update_banner(%{assigns: %{user: user}} = conn, params) do
 335     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 336          new_info <- %{"banner" => object.data},
 337          info_cng <- User.Info.profile_update(user.info, new_info),
 338          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 339          {:ok, user} <- User.update_and_set_cache(changeset) do
 340       CommonAPI.update(user)
 341       %{"url" => [%{"href" => href} | _]} = object.data
 342       response = %{url: href} |> Jason.encode!()
 343
 344       conn
 345       |> json_reply(200, response)
 346     end
 347   end
 348
 349   def update_background(%{assigns: %{user: user}} = conn, params) do
 350     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 351          new_info <- %{"background" => object.data},
 352          info_cng <- User.Info.profile_update(user.info, new_info),
 353          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 354          {:ok, _user} <- User.update_and_set_cache(changeset) do
 355       %{"url" => [%{"href" => href} | _]} = object.data
 356       response = %{url: href} |> Jason.encode!()
 357
 358       conn
 359       |> json_reply(200, response)
 360     end
 361   end
 362
 363   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 364     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 365          response <- Jason.encode!(user_map) do
 366       conn
 367       |> json_reply(200, response)
 368     else
 369       _e ->
 370         conn
 371         |> put_status(404)
 372         |> json(%{error: "Can't find user"})
 373     end
 374   end
 375
 376   def followers(%{assigns: %{user: for_user}} = conn, params) do
 377     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 378          {:ok, followers} <- User.get_followers(user) do
 379       followers =
 380         cond do
 381           for_user && user.id == for_user.id -> followers
 382           user.info.hide_network -> []
 383           true -> followers
 384         end
 385
 386       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 387     else
 388       _e -> bad_request_reply(conn, "Can't get followers")
 389     end
 390   end
 391
 392   def friends(%{assigns: %{user: for_user}} = conn, params) do
 393     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 394          {:ok, friends} <- User.get_friends(user) do
 395       friends =
 396         cond do
 397           for_user && user.id == for_user.id -> friends
 398           user.info.hide_network -> []
 399           true -> friends
 400         end
 401
 402       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 403     else
 404       _e -> bad_request_reply(conn, "Can't get friends")
 405     end
 406   end
 407
 408   def friend_requests(conn, params) do
 409     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 410          {:ok, friend_requests} <- User.get_follow_requests(user) do
 411       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 412     else
 413       _e -> bad_request_reply(conn, "Can't get friend requests")
 414     end
 415   end
 416
 417   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 418     with followed <- conn.assigns[:user],
 419          uid when is_number(uid) <- String.to_integer(uid),
 420          %User{} = follower <- Repo.get(User, uid),
 421          {:ok, follower} <- User.maybe_follow(follower, followed),
 422          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 423          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 424          {:ok, _activity} <-
 425            ActivityPub.accept(%{
 426              to: [follower.ap_id],
 427              actor: followed.ap_id,
 428              object: follow_activity.data["id"],
 429              type: "Accept"
 430            }) do
 431       render(conn, UserView, "show.json", %{user: follower, for: followed})
 432     else
 433       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 434     end
 435   end
 436
 437   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 438     with followed <- conn.assigns[:user],
 439          uid when is_number(uid) <- String.to_integer(uid),
 440          %User{} = follower <- Repo.get(User, uid),
 441          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 442          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 443          {:ok, _activity} <-
 444            ActivityPub.reject(%{
 445              to: [follower.ap_id],
 446              actor: followed.ap_id,
 447              object: follow_activity.data["id"],
 448              type: "Reject"
 449            }) do
 450       render(conn, UserView, "show.json", %{user: follower, for: followed})
 451     else
 452       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 453     end
 454   end
 455
 456   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 457     with {:ok, friends} <- User.get_friends(user) do
 458       ids =
 459         friends
 460         |> Enum.map(fn x -> x.id end)
 461         |> Jason.encode!()
 462
 463       json(conn, ids)
 464     else
 465       _e -> bad_request_reply(conn, "Can't get friends")
 466     end
 467   end
 468
 469   def empty_array(conn, _params) do
 470     json(conn, Jason.encode!([]))
 471   end
 472
 473   def raw_empty_array(conn, _params) do
 474     json(conn, [])
 475   end
 476
 477   defp build_info_cng(user, params) do
 478     info_params =
 479       ["no_rich_text", "locked", "hide_network"]
 480       |> Enum.reduce(%{}, fn key, res ->
 481         if value = params[key] do
 482           Map.put(res, key, value == "true")
 483         else
 484           res
 485         end
 486       end)
 487
 488     info_params =
 489       if value = params["default_scope"] do
 490         Map.put(info_params, "default_scope", value)
 491       else
 492         info_params
 493       end
 494
 495     User.Info.profile_update(user.info, info_params)
 496   end
 497
 498   defp parse_profile_bio(user, params) do
 499     if bio = params["description"] do
 500       Map.put(params, "bio", User.parse_bio(bio, user))
 501     else
 502       params
 503     end
 504   end
 505
 506   def update_profile(%{assigns: %{user: user}} = conn, params) do
 507     params = parse_profile_bio(user, params)
 508     info_cng = build_info_cng(user, params)
 509
 510     with changeset <- User.update_changeset(user, params),
 511          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 512          {:ok, user} <- User.update_and_set_cache(changeset) do
 513       CommonAPI.update(user)
 514       render(conn, UserView, "user.json", %{user: user, for: user})
 515     else
 516       error ->
 517         Logger.debug("Can't update user: #{inspect(error)}")
 518         bad_request_reply(conn, "Can't update user")
 519     end
 520   end
 521
 522   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 523     activities = TwitterAPI.search(user, params)
 524
 525     conn
 526     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 527   end
 528
 529   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 530     users = User.search(query, true)
 531
 532     conn
 533     |> render(UserView, "index.json", %{users: users, for: user})
 534   end
 535
 536   defp bad_request_reply(conn, error_message) do
 537     json = error_json(conn, error_message)
 538     json_reply(conn, 400, json)
 539   end
 540
 541   defp json_reply(conn, status, json) do
 542     conn
 543     |> put_resp_content_type("application/json")
 544     |> send_resp(status, json)
 545   end
 546
 547   defp forbidden_json_reply(conn, error_message) do
 548     json = error_json(conn, error_message)
 549     json_reply(conn, 403, json)
 550   end
 551
 552   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 553
 554   def only_if_public_instance(conn, _) do
 555     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 556       conn
 557     else
 558       conn
 559       |> forbidden_json_reply("Invalid credentials.")
 560       |> halt()
 561     end
 562   end
 563
 564   defp error_json(conn, error_message) do
 565     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 566   end
 567
 568   def errors(conn, {:param_cast, _}) do
 569     conn
 570     |> put_status(400)
 571     |> json("Invalid parameters")
 572   end
 573
 574   def errors(conn, _) do
 575     conn
 576     |> put_status(500)
 577     |> json("Something went wrong")
 578   end
 579 end