git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   7   alias Pleroma.{UserEmail, Mailer}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.TwitterAPI.UserView
  10   alias Pleroma.Web.CommonAPI
  11
  12   import Ecto.Query
  13
  14   def create_status(%User{} = user, %{"status" => _} = data) do
  15     CommonAPI.post(user, data)
  16   end
  17
  18   def delete(%User{} = user, id) do
  19     with %Activity{data: %{"type" => _type}} <- Repo.get(Activity, id),
  20          {:ok, activity} <- CommonAPI.delete(id, user) do
  21       {:ok, activity}
  22     end
  23   end
  24
  25   def follow(%User{} = follower, params) do
  26     with {:ok, %User{} = followed} <- get_user(params),
  27          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  28          {:ok, activity} <- ActivityPub.follow(follower, followed),
  29          {:ok, follower, followed} <-
  30            User.wait_and_refresh(
  31              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  32              follower,
  33              followed
  34            ) do
  35       {:ok, follower, followed, activity}
  36     else
  37       err -> err
  38     end
  39   end
  40
  41   def unfollow(%User{} = follower, params) do
  42     with {:ok, %User{} = unfollowed} <- get_user(params),
  43          {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  44          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  45       {:ok, follower, unfollowed}
  46     else
  47       err -> err
  48     end
  49   end
  50
  51   def block(%User{} = blocker, params) do
  52     with {:ok, %User{} = blocked} <- get_user(params),
  53          {:ok, blocker} <- User.block(blocker, blocked),
  54          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  55       {:ok, blocker, blocked}
  56     else
  57       err -> err
  58     end
  59   end
  60
  61   def unblock(%User{} = blocker, params) do
  62     with {:ok, %User{} = blocked} <- get_user(params),
  63          {:ok, blocker} <- User.unblock(blocker, blocked),
  64          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  65       {:ok, blocker, blocked}
  66     else
  67       err -> err
  68     end
  69   end
  70
  71   def repeat(%User{} = user, ap_id_or_id) do
  72     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  73          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  74       {:ok, activity}
  75     end
  76   end
  77
  78   def unrepeat(%User{} = user, ap_id_or_id) do
  79     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  80          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  81       {:ok, activity}
  82     end
  83   end
  84
  85   def fav(%User{} = user, ap_id_or_id) do
  86     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  87          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  88       {:ok, activity}
  89     end
  90   end
  91
  92   def unfav(%User{} = user, ap_id_or_id) do
  93     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  94          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  95       {:ok, activity}
  96     end
  97   end
  98
  99   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
 100     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
 101
 102     url = List.first(object.data["url"])
 103     href = url["href"]
 104     type = url["mediaType"]
 105
 106     case format do
 107       "xml" ->
 108         # Fake this as good as possible...
 109         """
 110         <?xml version="1.0" encoding="UTF-8"?>
 111         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 112         <mediaid>#{object.id}</mediaid>
 113         <media_id>#{object.id}</media_id>
 114         <media_id_string>#{object.id}</media_id_string>
 115         <media_url>#{href}</media_url>
 116         <mediaurl>#{href}</mediaurl>
 117         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 118         </rsp>
 119         """
 120
 121       "json" ->
 122         %{
 123           media_id: object.id,
 124           media_id_string: "#{object.id}}",
 125           media_url: href,
 126           size: 0
 127         }
 128         |> Jason.encode!()
 129     end
 130   end
 131
 132   def register_user(params) do
 133     tokenString = params["token"]
 134
 135     params = %{
 136       nickname: params["nickname"],
 137       name: params["fullname"],
 138       bio: User.parse_bio(params["bio"]),
 139       email: params["email"],
 140       password: params["password"],
 141       password_confirmation: params["confirm"],
 142       captcha_solution: params["captcha_solution"],
 143       captcha_token: params["captcha_token"],
 144       captcha_answer_data: params["captcha_answer_data"]
 145     }
 146
 147     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 148     # true if captcha is disabled or enabled and valid, false otherwise
 149     captcha_ok =
 150       if !captcha_enabled do
 151         :ok
 152       else
 153         Pleroma.Captcha.validate(
 154           params[:captcha_token],
 155           params[:captcha_solution],
 156           params[:captcha_answer_data]
 157         )
 158       end
 159
 160     # Captcha invalid
 161     if captcha_ok != :ok do
 162       {:error, error} = captcha_ok
 163       # I have no idea how this error handling works
 164       {:error, %{error: Jason.encode!(%{captcha: [error]})}}
 165     else
 166       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 167
 168       # no need to query DB if registration is open
 169       token =
 170         unless registrations_open || is_nil(tokenString) do
 171           Repo.get_by(UserInviteToken, %{token: tokenString})
 172         end
 173
 174       cond do
 175         registrations_open || (!is_nil(token) && !token.used) ->
 176           changeset = User.register_changeset(%User{}, params)
 177
 178           with {:ok, user} <- User.register(changeset) do
 179             !registrations_open && UserInviteToken.mark_as_used(token.token)
 180
 181             {:ok, user}
 182           else
 183             {:error, changeset} ->
 184               errors =
 185                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 186                 |> Jason.encode!()
 187
 188               {:error, %{error: errors}}
 189           end
 190
 191         !registrations_open && is_nil(token) ->
 192           {:error, "Invalid token"}
 193
 194         !registrations_open && token.used ->
 195           {:error, "Expired token"}
 196       end
 197     end
 198   end
 199
 200   def password_reset(nickname_or_email) do
 201     with true <- is_binary(nickname_or_email),
 202          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 203          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 204       user
 205       |> UserEmail.password_reset_email(token_record.token)
 206       |> Mailer.deliver()
 207     else
 208       false ->
 209         {:error, "bad user identifier"}
 210
 211       %User{local: false} ->
 212         {:error, "remote user"}
 213
 214       nil ->
 215         {:error, "unknown user"}
 216     end
 217   end
 218
 219   def get_by_id_or_nickname(id_or_nickname) do
 220     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 221       Repo.get_by(User, nickname: id_or_nickname)
 222     else
 223       Repo.get(User, id_or_nickname)
 224     end
 225   end
 226
 227   def get_user(user \\ nil, params) do
 228     case params do
 229       %{"user_id" => user_id} ->
 230         case target = get_by_id_or_nickname(user_id) do
 231           nil ->
 232             {:error, "No user with such user_id"}
 233
 234           _ ->
 235             {:ok, target}
 236         end
 237
 238       %{"screen_name" => nickname} ->
 239         case target = Repo.get_by(User, nickname: nickname) do
 240           nil ->
 241             {:error, "No user with such screen_name"}
 242
 243           _ ->
 244             {:ok, target}
 245         end
 246
 247       _ ->
 248         if user do
 249           {:ok, user}
 250         else
 251           {:error, "You need to specify screen_name or user_id"}
 252         end
 253     end
 254   end
 255
 256   defp parse_int(string, default)
 257
 258   defp parse_int(string, default) when is_binary(string) do
 259     with {n, _} <- Integer.parse(string) do
 260       n
 261     else
 262       _e -> default
 263     end
 264   end
 265
 266   defp parse_int(_, default), do: default
 267
 268   def search(_user, %{"q" => query} = params) do
 269     limit = parse_int(params["rpp"], 20)
 270     page = parse_int(params["page"], 1)
 271     offset = (page - 1) * limit
 272
 273     q =
 274       from(
 275         a in Activity,
 276         where: fragment("?->>'type' = 'Create'", a.data),
 277         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 278         where:
 279           fragment(
 280             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 281             a.data,
 282             ^query
 283           ),
 284         limit: ^limit,
 285         offset: ^offset,
 286         # this one isn't indexed so psql won't take the wrong index.
 287         order_by: [desc: :inserted_at]
 288       )
 289
 290     _activities = Repo.all(q)
 291   end
 292
 293   # DEPRECATED mostly, context objects are now created at insertion time.
 294   def context_to_conversation_id(context) do
 295     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 296       id
 297     else
 298       _e ->
 299         changeset = Object.context_mapping(context)
 300
 301         case Repo.insert(changeset) do
 302           {:ok, %{id: id}} ->
 303             id
 304
 305           # This should be solved by an upsert, but it seems ecto
 306           # has problems accessing the constraint inside the jsonb.
 307           {:error, _} ->
 308             Object.get_cached_by_ap_id(context).id
 309         end
 310     end
 311   end
 312
 313   def conversation_id_to_context(id) do
 314     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 315       context
 316     else
 317       _e ->
 318         {:error, "No such conversation"}
 319     end
 320   end
 321
 322   def get_external_profile(for_user, uri) do
 323     with %User{} = user <- User.get_or_fetch(uri) do
 324       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 325     else
 326       _e ->
 327         {:error, "Couldn't find user"}
 328     end
 329   end
 330 end