git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.{OStatus, CommonAPI}
   7   alias Pleroma.Formatter
   8   import Ecto.Query
   9
  10   @httpoison Application.get_env(:pleroma, :httpoison)
  11
  12   def create_status(%User{} = user, %{"status" => status} = data) do
  13     CommonAPI.post(user, data)
  14   end
  15
  16   def fetch_friend_statuses(user, opts \\ %{}) do
  17     opts = Map.put(opts, "blocking_user", user)
  18     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  19     |> activities_to_statuses(%{for: user})
  20   end
  21
  22   def fetch_public_statuses(user, opts \\ %{}) do
  23     opts = Map.put(opts, "local_only", true)
  24     opts = Map.put(opts, "blocking_user", user)
  25     ActivityPub.fetch_public_activities(opts)
  26     |> activities_to_statuses(%{for: user})
  27   end
  28
  29   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  30     opts = Map.put(opts, "blocking_user", user)
  31     ActivityPub.fetch_public_activities(opts)
  32     |> activities_to_statuses(%{for: user})
  33   end
  34
  35   def fetch_user_statuses(user, opts \\ %{}) do
  36     ActivityPub.fetch_activities([], opts)
  37     |> activities_to_statuses(%{for: user})
  38   end
  39
  40   def fetch_mentions(user, opts \\ %{}) do
  41     ActivityPub.fetch_activities([user.ap_id], opts)
  42     |> activities_to_statuses(%{for: user})
  43   end
  44
  45   def fetch_conversation(user, id) do
  46     with context when is_binary(context) <- conversation_id_to_context(id),
  47          activities <- ActivityPub.fetch_activities_for_context(context, %{"blocking_user" => user}),
  48          statuses <- activities |> activities_to_statuses(%{for: user})
  49     do
  50       statuses
  51     else _e ->
  52       []
  53     end
  54   end
  55
  56   def fetch_status(user, id) do
  57     with %Activity{} = activity <- Repo.get(Activity, id) do
  58       activity_to_status(activity, %{for: user})
  59     end
  60   end
  61
  62   def follow(%User{} = follower, params) do
  63     with {:ok, %User{} = followed} <- get_user(params),
  64          {:ok, follower} <- User.follow(follower, followed),
  65          {:ok, activity} <- ActivityPub.follow(follower, followed)
  66     do
  67       {:ok, follower, followed, activity}
  68     else
  69       err -> err
  70     end
  71   end
  72
  73   def unfollow(%User{} = follower, params) do
  74     with { :ok, %User{} = unfollowed } <- get_user(params),
  75          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
  76          { :ok, _activity } <- ActivityPub.insert(%{
  77            "type" => "Undo",
  78            "actor" => follower.ap_id,
  79            "object" => follow_activity.data["id"], # get latest Follow for these users
  80            "published" => make_date()
  81          })
  82     do
  83       { :ok, follower, unfollowed }
  84     else
  85       err -> err
  86     end
  87   end
  88
  89   def repeat(%User{} = user, ap_id_or_id) do
  90     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  91          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  92          status <- activity_to_status(activity, %{for: user}) do
  93       {:ok, status}
  94     end
  95   end
  96
  97   def fav(%User{} = user, ap_id_or_id) do
  98     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  99          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 100          status <- activity_to_status(activity, %{for: user}) do
 101       {:ok, status}
 102     end
 103   end
 104
 105   def unfav(%User{} = user, ap_id_or_id) do
 106     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 107          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 108          status <- activity_to_status(activity, %{for: user}) do
 109       {:ok, status}
 110     end
 111   end
 112
 113   def upload(%Plug.Upload{} = file, format \\ "xml") do
 114     {:ok, object} = ActivityPub.upload(file)
 115
 116     url = List.first(object.data["url"])
 117     href = url["href"]
 118     type = url["mediaType"]
 119
 120     case format do
 121       "xml" ->
 122         # Fake this as good as possible...
 123         """
 124         <?xml version="1.0" encoding="UTF-8"?>
 125         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 126         <mediaid>#{object.id}</mediaid>
 127         <media_id>#{object.id}</media_id>
 128         <media_id_string>#{object.id}</media_id_string>
 129         <media_url>#{href}</media_url>
 130         <mediaurl>#{href}</mediaurl>
 131         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 132         </rsp>
 133         """
 134       "json" ->
 135         %{
 136           media_id: object.id,
 137           media_id_string: "#{object.id}}",
 138           media_url: href,
 139           size: 0
 140         } |> Poison.encode!
 141     end
 142   end
 143
 144   def register_user(params) do
 145     params = %{
 146       nickname: params["nickname"],
 147       name: params["fullname"],
 148       bio: params["bio"],
 149       email: params["email"],
 150       password: params["password"],
 151       password_confirmation: params["confirm"]
 152     }
 153
 154     changeset = User.register_changeset(%User{}, params)
 155
 156     with {:ok, user} <- Repo.insert(changeset) do
 157       {:ok, user}
 158     else
 159       {:error, changeset} ->
 160         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 161       |> Poison.encode!
 162       {:error, %{error: errors}}
 163     end
 164   end
 165
 166   def get_by_id_or_nickname(id_or_nickname) do
 167     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 168       Repo.get_by(User, nickname: id_or_nickname)
 169     else
 170       Repo.get(User, id_or_nickname)
 171     end
 172   end
 173
 174   def get_user(user \\ nil, params) do
 175     case params do
 176       %{"user_id" => user_id} ->
 177         case target = get_by_id_or_nickname(user_id) do
 178           nil ->
 179             {:error, "No user with such user_id"}
 180           _ ->
 181             {:ok, target}
 182         end
 183       %{"screen_name" => nickname} ->
 184         case target = Repo.get_by(User, nickname: nickname) do
 185           nil ->
 186             {:error, "No user with such screen_name"}
 187           _ ->
 188             {:ok, target}
 189         end
 190       _ ->
 191         if user do
 192           {:ok, user}
 193         else
 194           {:error, "You need to specify screen_name or user_id"}
 195         end
 196     end
 197   end
 198
 199   defp parse_int(string, default \\ nil)
 200   defp parse_int(string, default) when is_binary(string) do
 201     with {n, _} <- Integer.parse(string) do
 202       n
 203     else
 204       _e -> default
 205     end
 206   end
 207   defp parse_int(_, default), do: default
 208
 209   def search(user, %{"q" => query} = params) do
 210     limit = parse_int(params["rpp"], 20)
 211     page = parse_int(params["page"], 1)
 212     offset = (page - 1) * limit
 213
 214     q = from a in Activity,
 215       where: fragment("?->>'type' = 'Create'", a.data),
 216       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 217       limit: ^limit,
 218       offset: ^offset,
 219       order_by: [desc: :inserted_at] # this one isn't indexed so psql won't take the wrong index.
 220
 221     activities = Repo.all(q)
 222     activities_to_statuses(activities, %{for: user})
 223   end
 224
 225   defp activities_to_statuses(activities, opts) do
 226     Enum.map(activities, fn(activity) ->
 227       activity_to_status(activity, opts)
 228     end)
 229   end
 230
 231   # For likes, fetch the liked activity, too.
 232   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 233     actor = get_in(activity.data, ["actor"])
 234     user = User.get_cached_by_ap_id(actor)
 235     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 236
 237     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 238   end
 239
 240   # For announces, fetch the announced activity and the user.
 241   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 242     actor = get_in(activity.data, ["actor"])
 243     user = User.get_cached_by_ap_id(actor)
 244     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 245     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 246
 247     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 248   end
 249
 250   defp activity_to_status(%Activity{data: %{"type" => "Delete"}} = activity, opts) do
 251     actor = get_in(activity.data, ["actor"])
 252     user = User.get_cached_by_ap_id(actor)
 253     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user}))
 254   end
 255
 256   defp activity_to_status(activity, opts) do
 257     actor = get_in(activity.data, ["actor"])
 258     user = User.get_cached_by_ap_id(actor)
 259     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 260     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 261       if ap_id do
 262         User.get_cached_by_ap_id(ap_id)
 263       else
 264         nil
 265       end
 266     end)
 267     |> Enum.filter(&(&1))
 268
 269     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 270   end
 271
 272   defp make_date do
 273     DateTime.utc_now() |> DateTime.to_iso8601
 274   end
 275
 276   def context_to_conversation_id(context) do
 277     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 278       id
 279       else _e ->
 280         changeset = Object.context_mapping(context)
 281         case Repo.insert(changeset) do
 282           {:ok, %{id: id}} -> id
 283           # This should be solved by an upsert, but it seems ecto
 284           # has problems accessing the constraint inside the jsonb.
 285           {:error, _} -> Object.get_cached_by_ap_id(context).id
 286         end
 287     end
 288   end
 289
 290   def conversation_id_to_context(id) do
 291     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 292       context
 293     else _e ->
 294       {:error, "No such conversation"}
 295     end
 296   end
 297
 298   def get_external_profile(for_user, uri) do
 299     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 300       with url <- user.info["topic"],
 301            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 302         OStatus.handle_incoming(body)
 303       end
 304       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 305     else _e ->
 306         {:error, "Couldn't find user"}
 307     end
 308   end
 309 end