git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.{OStatus, CommonAPI}
   7   alias Pleroma.Formatter
   8   import Ecto.Query
   9
  10   @httpoison Application.get_env(:pleroma, :httpoison)
  11
  12   def create_status(%User{} = user, %{"status" => status} = data) do
  13     CommonAPI.post(user, data)
  14   end
  15
  16   def fetch_friend_statuses(user, opts \\ %{}) do
  17     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  18     |> activities_to_statuses(%{for: user})
  19   end
  20
  21   def fetch_public_statuses(user, opts \\ %{}) do
  22     opts = Map.put(opts, "local_only", true)
  23     ActivityPub.fetch_public_activities(opts)
  24     |> activities_to_statuses(%{for: user})
  25   end
  26
  27   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  28     ActivityPub.fetch_public_activities(opts)
  29     |> activities_to_statuses(%{for: user})
  30   end
  31
  32   def fetch_user_statuses(user, opts \\ %{}) do
  33     ActivityPub.fetch_activities([], opts)
  34     |> activities_to_statuses(%{for: user})
  35   end
  36
  37   def fetch_mentions(user, opts \\ %{}) do
  38     ActivityPub.fetch_activities([user.ap_id], opts)
  39     |> activities_to_statuses(%{for: user})
  40   end
  41
  42   def fetch_conversation(user, id) do
  43     with context when is_binary(context) <- conversation_id_to_context(id),
  44          activities <- ActivityPub.fetch_activities_for_context(context),
  45          statuses <- activities |> activities_to_statuses(%{for: user})
  46     do
  47       statuses
  48     else _e ->
  49       []
  50     end
  51   end
  52
  53   def fetch_status(user, id) do
  54     with %Activity{} = activity <- Repo.get(Activity, id) do
  55       activity_to_status(activity, %{for: user})
  56     end
  57   end
  58
  59   def follow(%User{} = follower, params) do
  60     with {:ok, %User{} = followed} <- get_user(params),
  61          {:ok, follower} <- User.follow(follower, followed),
  62          {:ok, activity} <- ActivityPub.follow(follower, followed)
  63     do
  64       {:ok, follower, followed, activity}
  65     else
  66       err -> err
  67     end
  68   end
  69
  70   def unfollow(%User{} = follower, params) do
  71     with { :ok, %User{} = unfollowed } <- get_user(params),
  72          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
  73          { :ok, _activity } <- ActivityPub.insert(%{
  74            "type" => "Undo",
  75            "actor" => follower.ap_id,
  76            "object" => follow_activity.data["id"], # get latest Follow for these users
  77            "published" => make_date()
  78          })
  79     do
  80       { :ok, follower, unfollowed }
  81     else
  82       err -> err
  83     end
  84   end
  85
  86   def repeat(%User{} = user, ap_id_or_id) do
  87     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  88          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  89          status <- activity_to_status(activity, %{for: user}) do
  90       {:ok, status}
  91     end
  92   end
  93
  94   def fav(%User{} = user, ap_id_or_id) do
  95     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  96          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
  97          status <- activity_to_status(activity, %{for: user}) do
  98       {:ok, status}
  99     end
 100   end
 101
 102   def unfav(%User{} = user, ap_id_or_id) do
 103     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 104          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 105          status <- activity_to_status(activity, %{for: user}) do
 106       {:ok, status}
 107     end
 108   end
 109
 110   def upload(%Plug.Upload{} = file, format \\ "xml") do
 111     {:ok, object} = ActivityPub.upload(file)
 112
 113     url = List.first(object.data["url"])
 114     href = url["href"]
 115     type = url["mediaType"]
 116
 117     case format do
 118       "xml" ->
 119         # Fake this as good as possible...
 120         """
 121         <?xml version="1.0" encoding="UTF-8"?>
 122         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 123         <mediaid>#{object.id}</mediaid>
 124         <media_id>#{object.id}</media_id>
 125         <media_id_string>#{object.id}</media_id_string>
 126         <media_url>#{href}</media_url>
 127         <mediaurl>#{href}</mediaurl>
 128         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 129         </rsp>
 130         """
 131       "json" ->
 132         %{
 133           media_id: object.id,
 134           media_id_string: "#{object.id}}",
 135           media_url: href,
 136           size: 0
 137         } |> Poison.encode!
 138     end
 139   end
 140
 141   def register_user(params) do
 142     params = %{
 143       nickname: params["nickname"],
 144       name: params["fullname"],
 145       bio: params["bio"],
 146       email: params["email"],
 147       password: params["password"],
 148       password_confirmation: params["confirm"]
 149     }
 150
 151     changeset = User.register_changeset(%User{}, params)
 152
 153     with {:ok, user} <- Repo.insert(changeset) do
 154       {:ok, user}
 155     else
 156       {:error, changeset} ->
 157         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 158       |> Poison.encode!
 159       {:error, %{error: errors}}
 160     end
 161   end
 162
 163   def get_by_id_or_nickname(id_or_nickname) do
 164     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 165       Repo.get_by(User, nickname: id_or_nickname)
 166     else
 167       Repo.get(User, id_or_nickname)
 168     end
 169   end
 170
 171   def get_user(user \\ nil, params) do
 172     case params do
 173       %{"user_id" => user_id} ->
 174         case target = get_by_id_or_nickname(user_id) do
 175           nil ->
 176             {:error, "No user with such user_id"}
 177           _ ->
 178             {:ok, target}
 179         end
 180       %{"screen_name" => nickname} ->
 181         case target = Repo.get_by(User, nickname: nickname) do
 182           nil ->
 183             {:error, "No user with such screen_name"}
 184           _ ->
 185             {:ok, target}
 186         end
 187       _ ->
 188         if user do
 189           {:ok, user}
 190         else
 191           {:error, "You need to specify screen_name or user_id"}
 192         end
 193     end
 194   end
 195
 196   defp parse_int(string, default \\ nil)
 197   defp parse_int(string, default) when is_binary(string) do
 198     with {n, _} <- Integer.parse(string) do
 199       n
 200     else
 201       _e -> default
 202     end
 203   end
 204   defp parse_int(_, default), do: default
 205
 206   def search(user, %{"q" => query} = params) do
 207     limit = parse_int(params["rpp"], 20)
 208     page = parse_int(params["page"], 1)
 209     offset = (page - 1) * limit
 210
 211     q = from a in Activity,
 212       where: fragment("?->>'type' = 'Create'", a.data),
 213       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 214       limit: ^limit,
 215       offset: ^offset,
 216       order_by: [desc: :inserted_at] # this one isn't indexed so psql won't take the wrong index.
 217
 218     activities = Repo.all(q)
 219     activities_to_statuses(activities, %{for: user})
 220   end
 221
 222   defp activities_to_statuses(activities, opts) do
 223     Enum.map(activities, fn(activity) ->
 224       activity_to_status(activity, opts)
 225     end)
 226   end
 227
 228   # For likes, fetch the liked activity, too.
 229   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 230     actor = get_in(activity.data, ["actor"])
 231     user = User.get_cached_by_ap_id(actor)
 232     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 233
 234     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 235   end
 236
 237   # For announces, fetch the announced activity and the user.
 238   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 239     actor = get_in(activity.data, ["actor"])
 240     user = User.get_cached_by_ap_id(actor)
 241     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 242     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 243
 244     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 245   end
 246
 247   defp activity_to_status(%Activity{data: %{"type" => "Delete"}} = activity, opts) do
 248     actor = get_in(activity.data, ["actor"])
 249     user = User.get_cached_by_ap_id(actor)
 250     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user}))
 251   end
 252
 253   defp activity_to_status(activity, opts) do
 254     actor = get_in(activity.data, ["actor"])
 255     user = User.get_cached_by_ap_id(actor)
 256     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 257     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 258       if ap_id do
 259         User.get_cached_by_ap_id(ap_id)
 260       else
 261         nil
 262       end
 263     end)
 264     |> Enum.filter(&(&1))
 265
 266     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 267   end
 268
 269   defp make_date do
 270     DateTime.utc_now() |> DateTime.to_iso8601
 271   end
 272
 273   def context_to_conversation_id(context) do
 274     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 275       id
 276       else _e ->
 277         changeset = Object.context_mapping(context)
 278         case Repo.insert(changeset) do
 279           {:ok, %{id: id}} -> id
 280           # This should be solved by an upsert, but it seems ecto
 281           # has problems accessing the constraint inside the jsonb.
 282           {:error, _} -> Object.get_cached_by_ap_id(context).id
 283         end
 284     end
 285   end
 286
 287   def conversation_id_to_context(id) do
 288     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 289       context
 290     else _e ->
 291       {:error, "No such conversation"}
 292     end
 293   end
 294
 295   def get_external_profile(for_user, uri) do
 296     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 297       with url <- user.info["topic"],
 298            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 299         OStatus.handle_incoming(body)
 300       end
 301       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 302     else _e ->
 303         {:error, "Couldn't find user"}
 304     end
 305   end
 306 end