git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.{OStatus, CommonAPI}
   6   import Ecto.Query
   7
   8   @httpoison Application.get_env(:pleroma, :httpoison)
   9
  10   def create_status(%User{} = user, %{"status" => _} = data) do
  11     CommonAPI.post(user, data)
  12   end
  13
  14   def delete(%User{} = user, id) do
  15     # TwitterAPI does not have an "unretweet" endpoint; instead this is done
  16     # via the "destroy" endpoint.  Therefore, we need to handle
  17     # when the status to "delete" is actually an Announce (repeat) object.
  18     with %Activity{data: %{"type" => type}} <- Repo.get(Activity, id) do
  19       case type do
  20         "Announce" -> unrepeat(user, id)
  21         _ -> CommonAPI.delete(id, user)
  22       end
  23     end
  24   end
  25
  26   def follow(%User{} = follower, params) do
  27     with {:ok, %User{} = followed} <- get_user(params),
  28          {:ok, follower} <- User.follow(follower, followed),
  29          {:ok, activity} <- ActivityPub.follow(follower, followed) do
  30       {:ok, follower, followed, activity}
  31     else
  32       err -> err
  33     end
  34   end
  35
  36   def unfollow(%User{} = follower, params) do
  37     with {:ok, %User{} = unfollowed} <- get_user(params),
  38          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  39          {:ok, _activity} <-
  40            ActivityPub.insert(%{
  41              "type" => "Undo",
  42              "actor" => follower.ap_id,
  43              # get latest Follow for these users
  44              "object" => follow_activity.data["id"],
  45              "published" => make_date()
  46            }) do
  47       {:ok, follower, unfollowed}
  48     else
  49       err -> err
  50     end
  51   end
  52
  53   def block(%User{} = blocker, params) do
  54     with {:ok, %User{} = blocked} <- get_user(params),
  55          {:ok, blocker} <- User.block(blocker, blocked) do
  56       {:ok, blocker, blocked}
  57     else
  58       err -> err
  59     end
  60   end
  61
  62   def unblock(%User{} = blocker, params) do
  63     with {:ok, %User{} = blocked} <- get_user(params),
  64          {:ok, blocker} <- User.unblock(blocker, blocked) do
  65       {:ok, blocker, blocked}
  66     else
  67       err -> err
  68     end
  69   end
  70
  71   def repeat(%User{} = user, ap_id_or_id) do
  72     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  73          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  74       {:ok, activity}
  75     end
  76   end
  77
  78   defp unrepeat(%User{} = user, ap_id_or_id) do
  79     with {:ok, _unannounce, activity, _object} <- CommonAPI.unrepeat(ap_id_or_id, user) do
  80       {:ok, activity}
  81     end
  82   end
  83
  84   def fav(%User{} = user, ap_id_or_id) do
  85     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  86          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  87       {:ok, activity}
  88     end
  89   end
  90
  91   def unfav(%User{} = user, ap_id_or_id) do
  92     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
  93          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  94       {:ok, activity}
  95     end
  96   end
  97
  98   def upload(%Plug.Upload{} = file, format \\ "xml") do
  99     {:ok, object} = ActivityPub.upload(file)
 100
 101     url = List.first(object.data["url"])
 102     href = url["href"]
 103     type = url["mediaType"]
 104
 105     case format do
 106       "xml" ->
 107         # Fake this as good as possible...
 108         """
 109         <?xml version="1.0" encoding="UTF-8"?>
 110         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 111         <mediaid>#{object.id}</mediaid>
 112         <media_id>#{object.id}</media_id>
 113         <media_id_string>#{object.id}</media_id_string>
 114         <media_url>#{href}</media_url>
 115         <mediaurl>#{href}</mediaurl>
 116         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 117         </rsp>
 118         """
 119
 120       "json" ->
 121         %{
 122           media_id: object.id,
 123           media_id_string: "#{object.id}}",
 124           media_url: href,
 125           size: 0
 126         }
 127         |> Jason.encode!()
 128     end
 129   end
 130
 131   def register_user(params) do
 132     params = %{
 133       nickname: params["nickname"],
 134       name: params["fullname"],
 135       bio: params["bio"],
 136       email: params["email"],
 137       password: params["password"],
 138       password_confirmation: params["confirm"]
 139     }
 140
 141     changeset = User.register_changeset(%User{}, params)
 142
 143     with {:ok, user} <- Repo.insert(changeset) do
 144       {:ok, user}
 145     else
 146       {:error, changeset} ->
 147         errors =
 148           Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 149           |> Jason.encode!()
 150
 151         {:error, %{error: errors}}
 152     end
 153   end
 154
 155   def get_by_id_or_nickname(id_or_nickname) do
 156     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 157       Repo.get_by(User, nickname: id_or_nickname)
 158     else
 159       Repo.get(User, id_or_nickname)
 160     end
 161   end
 162
 163   def get_user(user \\ nil, params) do
 164     case params do
 165       %{"user_id" => user_id} ->
 166         case target = get_by_id_or_nickname(user_id) do
 167           nil ->
 168             {:error, "No user with such user_id"}
 169
 170           _ ->
 171             {:ok, target}
 172         end
 173
 174       %{"screen_name" => nickname} ->
 175         case target = Repo.get_by(User, nickname: nickname) do
 176           nil ->
 177             {:error, "No user with such screen_name"}
 178
 179           _ ->
 180             {:ok, target}
 181         end
 182
 183       _ ->
 184         if user do
 185           {:ok, user}
 186         else
 187           {:error, "You need to specify screen_name or user_id"}
 188         end
 189     end
 190   end
 191
 192   defp parse_int(string, default)
 193
 194   defp parse_int(string, default) when is_binary(string) do
 195     with {n, _} <- Integer.parse(string) do
 196       n
 197     else
 198       _e -> default
 199     end
 200   end
 201
 202   defp parse_int(_, default), do: default
 203
 204   def search(_user, %{"q" => query} = params) do
 205     limit = parse_int(params["rpp"], 20)
 206     page = parse_int(params["page"], 1)
 207     offset = (page - 1) * limit
 208
 209     q =
 210       from(
 211         a in Activity,
 212         where: fragment("?->>'type' = 'Create'", a.data),
 213         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 214         where:
 215           fragment(
 216             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 217             a.data,
 218             ^query
 219           ),
 220         limit: ^limit,
 221         offset: ^offset,
 222         # this one isn't indexed so psql won't take the wrong index.
 223         order_by: [desc: :inserted_at]
 224       )
 225
 226     _activities = Repo.all(q)
 227   end
 228
 229   defp make_date do
 230     DateTime.utc_now() |> DateTime.to_iso8601()
 231   end
 232
 233   # DEPRECATED mostly, context objects are now created at insertion time.
 234   def context_to_conversation_id(context) do
 235     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 236       id
 237     else
 238       _e ->
 239         changeset = Object.context_mapping(context)
 240
 241         case Repo.insert(changeset) do
 242           {:ok, %{id: id}} ->
 243             id
 244
 245           # This should be solved by an upsert, but it seems ecto
 246           # has problems accessing the constraint inside the jsonb.
 247           {:error, _} ->
 248             Object.get_cached_by_ap_id(context).id
 249         end
 250     end
 251   end
 252
 253   def conversation_id_to_context(id) do
 254     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 255       context
 256     else
 257       _e ->
 258         {:error, "No such conversation"}
 259     end
 260   end
 261
 262   def get_external_profile(for_user, uri) do
 263     with %User{} = user <- User.get_or_fetch(uri) do
 264       spawn(fn ->
 265         with url <- user.info["topic"],
 266              {:ok, %{body: body}} <-
 267                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 268           OStatus.handle_incoming(body)
 269         end
 270       end)
 271
 272       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 273     else
 274       _e ->
 275         {:error, "Couldn't find user"}
 276     end
 277   end
 278 end