git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   7   alias Pleroma.{UserEmail, Mailer}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.TwitterAPI.UserView
  10   alias Pleroma.Web.CommonAPI
  11
  12   import Ecto.Query
  13
  14   def create_status(%User{} = user, %{"status" => _} = data) do
  15     CommonAPI.post(user, data)
  16   end
  17
  18   def delete(%User{} = user, id) do
  19     with %Activity{data: %{"type" => _type}} <- Repo.get(Activity, id),
  20          {:ok, activity} <- CommonAPI.delete(id, user) do
  21       {:ok, activity}
  22     end
  23   end
  24
  25   def follow(%User{} = follower, params) do
  26     with {:ok, %User{} = followed} <- get_user(params),
  27          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  28          {:ok, activity} <- ActivityPub.follow(follower, followed),
  29          {:ok, follower, followed} <-
  30            User.wait_and_refresh(
  31              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  32              follower,
  33              followed
  34            ) do
  35       {:ok, follower, followed, activity}
  36     else
  37       err -> err
  38     end
  39   end
  40
  41   def unfollow(%User{} = follower, params) do
  42     with {:ok, %User{} = unfollowed} <- get_user(params),
  43          {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  44          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  45       {:ok, follower, unfollowed}
  46     else
  47       err -> err
  48     end
  49   end
  50
  51   def block(%User{} = blocker, params) do
  52     with {:ok, %User{} = blocked} <- get_user(params),
  53          {:ok, blocker} <- User.block(blocker, blocked),
  54          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  55       {:ok, blocker, blocked}
  56     else
  57       err -> err
  58     end
  59   end
  60
  61   def unblock(%User{} = blocker, params) do
  62     with {:ok, %User{} = blocked} <- get_user(params),
  63          {:ok, blocker} <- User.unblock(blocker, blocked),
  64          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  65       {:ok, blocker, blocked}
  66     else
  67       err -> err
  68     end
  69   end
  70
  71   def repeat(%User{} = user, ap_id_or_id) do
  72     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  73          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  74       {:ok, activity}
  75     end
  76   end
  77
  78   def unrepeat(%User{} = user, ap_id_or_id) do
  79     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  80          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  81       {:ok, activity}
  82     end
  83   end
  84
  85   def fav(%User{} = user, ap_id_or_id) do
  86     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  87          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  88       {:ok, activity}
  89     end
  90   end
  91
  92   def unfav(%User{} = user, ap_id_or_id) do
  93     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  94          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  95       {:ok, activity}
  96     end
  97   end
  98
  99   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
 100     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
 101
 102     url = List.first(object.data["url"])
 103     href = url["href"]
 104     type = url["mediaType"]
 105
 106     case format do
 107       "xml" ->
 108         # Fake this as good as possible...
 109         """
 110         <?xml version="1.0" encoding="UTF-8"?>
 111         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 112         <mediaid>#{object.id}</mediaid>
 113         <media_id>#{object.id}</media_id>
 114         <media_id_string>#{object.id}</media_id_string>
 115         <media_url>#{href}</media_url>
 116         <mediaurl>#{href}</mediaurl>
 117         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 118         </rsp>
 119         """
 120
 121       "json" ->
 122         %{
 123           media_id: object.id,
 124           media_id_string: "#{object.id}}",
 125           media_url: href,
 126           size: 0
 127         }
 128         |> Jason.encode!()
 129     end
 130   end
 131
 132   def register_user(params) do
 133     tokenString = params["token"]
 134
 135     params = %{
 136       nickname: params["nickname"],
 137       name: params["fullname"],
 138       bio: User.parse_bio(params["bio"]),
 139       email: params["email"],
 140       password: params["password"],
 141       password_confirmation: params["confirm"],
 142       captcha_solution: params["captcha_solution"],
 143       captcha_token: params["captcha_token"]
 144     }
 145
 146     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 147     # true if captcha is disabled or enabled and valid, false otherwise
 148     captcha_ok =
 149       if !captcha_enabled do
 150         true
 151       else
 152         Pleroma.Captcha.validate(params[:captcha_token], params[:captcha_solution])
 153       end
 154
 155     # Captcha invalid
 156     if not captcha_ok do
 157       # I have no idea how this error handling works
 158       {:error, %{error: Jason.encode!(%{captcha: ["Invalid CAPTCHA"]})}}
 159     else
 160       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 161
 162       # no need to query DB if registration is open
 163       token =
 164         unless registrations_open || is_nil(tokenString) do
 165           Repo.get_by(UserInviteToken, %{token: tokenString})
 166         end
 167
 168       cond do
 169         registrations_open || (!is_nil(token) && !token.used) ->
 170           changeset = User.register_changeset(%User{}, params)
 171
 172           with {:ok, user} <- User.register(changeset) do
 173             !registrations_open && UserInviteToken.mark_as_used(token.token)
 174
 175             {:ok, user}
 176           else
 177             {:error, changeset} ->
 178               errors =
 179                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 180                 |> Jason.encode!()
 181
 182               {:error, %{error: errors}}
 183           end
 184
 185         !registrations_open && is_nil(token) ->
 186           {:error, "Invalid token"}
 187
 188         !registrations_open && token.used ->
 189           {:error, "Expired token"}
 190       end
 191     end
 192   end
 193
 194   def password_reset(nickname_or_email) do
 195     with true <- is_binary(nickname_or_email),
 196          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 197          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 198       user
 199       |> UserEmail.password_reset_email(token_record.token)
 200       |> Mailer.deliver()
 201     else
 202       false ->
 203         {:error, "bad user identifier"}
 204
 205       %User{local: false} ->
 206         {:error, "remote user"}
 207
 208       nil ->
 209         {:error, "unknown user"}
 210     end
 211   end
 212
 213   def get_by_id_or_nickname(id_or_nickname) do
 214     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 215       Repo.get_by(User, nickname: id_or_nickname)
 216     else
 217       Repo.get(User, id_or_nickname)
 218     end
 219   end
 220
 221   def get_user(user \\ nil, params) do
 222     case params do
 223       %{"user_id" => user_id} ->
 224         case target = get_by_id_or_nickname(user_id) do
 225           nil ->
 226             {:error, "No user with such user_id"}
 227
 228           _ ->
 229             {:ok, target}
 230         end
 231
 232       %{"screen_name" => nickname} ->
 233         case target = Repo.get_by(User, nickname: nickname) do
 234           nil ->
 235             {:error, "No user with such screen_name"}
 236
 237           _ ->
 238             {:ok, target}
 239         end
 240
 241       _ ->
 242         if user do
 243           {:ok, user}
 244         else
 245           {:error, "You need to specify screen_name or user_id"}
 246         end
 247     end
 248   end
 249
 250   defp parse_int(string, default)
 251
 252   defp parse_int(string, default) when is_binary(string) do
 253     with {n, _} <- Integer.parse(string) do
 254       n
 255     else
 256       _e -> default
 257     end
 258   end
 259
 260   defp parse_int(_, default), do: default
 261
 262   def search(_user, %{"q" => query} = params) do
 263     limit = parse_int(params["rpp"], 20)
 264     page = parse_int(params["page"], 1)
 265     offset = (page - 1) * limit
 266
 267     q =
 268       from(
 269         a in Activity,
 270         where: fragment("?->>'type' = 'Create'", a.data),
 271         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 272         where:
 273           fragment(
 274             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 275             a.data,
 276             ^query
 277           ),
 278         limit: ^limit,
 279         offset: ^offset,
 280         # this one isn't indexed so psql won't take the wrong index.
 281         order_by: [desc: :inserted_at]
 282       )
 283
 284     _activities = Repo.all(q)
 285   end
 286
 287   # DEPRECATED mostly, context objects are now created at insertion time.
 288   def context_to_conversation_id(context) do
 289     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 290       id
 291     else
 292       _e ->
 293         changeset = Object.context_mapping(context)
 294
 295         case Repo.insert(changeset) do
 296           {:ok, %{id: id}} ->
 297             id
 298
 299           # This should be solved by an upsert, but it seems ecto
 300           # has problems accessing the constraint inside the jsonb.
 301           {:error, _} ->
 302             Object.get_cached_by_ap_id(context).id
 303         end
 304     end
 305   end
 306
 307   def conversation_id_to_context(id) do
 308     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 309       context
 310     else
 311       _e ->
 312         {:error, "No such conversation"}
 313     end
 314   end
 315
 316   def get_external_profile(for_user, uri) do
 317     with %User{} = user <- User.get_or_fetch(uri) do
 318       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 319     else
 320       _e ->
 321         {:error, "Couldn't find user"}
 322     end
 323   end
 324 end