git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5
   6   import Ecto.Query
   7
   8   def create_status(user = %User{}, data = %{}) do
   9     date = DateTime.utc_now() |> DateTime.to_iso8601
  10
  11     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  12       Repo.get(Object, media_id).data
  13     end)
  14
  15     context = ActivityPub.generate_context_id
  16
  17     content = HtmlSanitizeEx.strip_tags(data["status"])
  18
  19     mentions = parse_mentions(content)
  20
  21     default_to = [
  22       User.ap_followers(user),
  23       "https://www.w3.org/ns/activitystreams#Public"
  24     ]
  25
  26     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  27
  28     content_html = add_user_links(content, mentions)
  29
  30     activity = %{
  31       "type" => "Create",
  32       "to" => to,
  33       "actor" => user.ap_id,
  34       "object" => %{
  35         "type" => "Note",
  36         "to" => to,
  37         "content" => content_html,
  38         "published" => date,
  39         "context" => context,
  40         "attachment" => attachments
  41       },
  42       "published" => date,
  43       "context" => context
  44     }
  45
  46     # Wire up reply info.
  47     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  48                     inReplyTo <- Repo.get(Activity, inReplyToId),
  49                     context <- inReplyTo.data["context"]
  50                do
  51
  52                to = activity["to"] ++ [inReplyTo.data["actor"]]
  53
  54                activity
  55                |> put_in(["to"], to)
  56                |> put_in(["context"], context)
  57                |> put_in(["object", "context"], context)
  58                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  59                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  60                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  61                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  62                else _e ->
  63                  activity
  64                end
  65
  66     with {:ok, activity} <- ActivityPub.insert(activity) do
  67       add_conversation_id(activity)
  68     end
  69   end
  70
  71   def fetch_friend_statuses(user, opts \\ %{}) do
  72     ActivityPub.fetch_activities(user.following, opts)
  73     |> activities_to_statuses(%{for: user})
  74   end
  75
  76   def fetch_public_statuses(user, opts \\ %{}) do
  77     ActivityPub.fetch_public_activities(opts)
  78     |> activities_to_statuses(%{for: user})
  79   end
  80
  81   def fetch_conversation(user, id) do
  82     query = from activity in Activity,
  83       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
  84       limit: 1
  85
  86     with %Activity{} = activity <- Repo.one(query),
  87          context <- activity.data["context"],
  88          activities <- ActivityPub.fetch_activities_for_context(context),
  89          statuses <- activities |> activities_to_statuses(%{for: user})
  90     do
  91       statuses
  92     else e ->
  93       IO.inspect(e)
  94       []
  95     end
  96   end
  97
  98   def fetch_status(user, id) do
  99     with %Activity{} = activity <- Repo.get(Activity, id) do
 100       activity_to_status(activity, %{for: user})
 101     end
 102   end
 103
 104   def follow(%User{} = follower, followed_id) do
 105     with %User{} = followed <- Repo.get(User, followed_id),
 106          { :ok, follower } <- User.follow(follower, followed),
 107          { :ok, activity } <- ActivityPub.insert(%{
 108            "type" => "Follow",
 109            "actor" => follower.ap_id,
 110            "object" => followed.ap_id
 111          })
 112     do
 113       { :ok, follower, followed, activity }
 114     end
 115   end
 116
 117   def unfollow(%User{} = follower, followed_id) do
 118     with %User{} = followed <- Repo.get(User, followed_id),
 119          { :ok, follower } <- User.unfollow(follower, followed)
 120     do
 121       { :ok, follower, followed }
 122     end
 123   end
 124
 125   def upload(%Plug.Upload{} = file) do
 126     {:ok, object} = ActivityPub.upload(file)
 127
 128     url = List.first(object.data["url"])
 129     href = url["href"]
 130     type = url["mediaType"]
 131
 132     # Fake this as good as possible...
 133     """
 134     <?xml version="1.0" encoding="UTF-8"?>
 135     <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 136       <mediaid>#{object.id}</mediaid>
 137       <media_id>#{object.id}</media_id>
 138       <media_id_string>#{object.id}</media_id_string>
 139       <media_url>#{href}</media_url>
 140       <mediaurl>#{href}</mediaurl>
 141       <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 142     </rsp>
 143     """
 144   end
 145
 146   def parse_mentions(text) do
 147     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 148     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 149
 150     Regex.scan(regex, text)
 151     |> List.flatten
 152     |> Enum.uniq
 153     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, Repo.get_by(User, nickname: match)} end)
 154     |> Enum.filter(fn ({_match, user}) -> user end)
 155   end
 156
 157   def add_user_links(text, mentions) do
 158     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 159   end
 160
 161   defp add_conversation_id(activity) do
 162     if is_integer(activity.data["statusnetConversationId"]) do
 163       {:ok, activity}
 164     else
 165       data = activity.data
 166       |> put_in(["object", "statusnetConversationId"], activity.id)
 167       |> put_in(["statusnetConversationId"], activity.id)
 168
 169       changeset = Ecto.Changeset.change(activity, data: data)
 170       Repo.update(changeset)
 171     end
 172   end
 173
 174   defp activities_to_statuses(activities, opts) do
 175     Enum.map(activities, fn(activity) ->
 176       activity_to_status(activity, opts)
 177     end)
 178   end
 179
 180   defp activity_to_status(activity, opts) do
 181     actor = get_in(activity.data, ["actor"])
 182     user = Repo.get_by!(User, ap_id: actor)
 183     mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 184     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 185   end
 186 end