git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.{OStatus, CommonAPI}
   6   import Ecto.Query
   7
   8   @instance Application.get_env(:pleroma, :instance)
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10   @registrations_open Keyword.get(@instance, :registrations_open)
  11
  12   def create_status(%User{} = user, %{"status" => _} = data) do
  13     CommonAPI.post(user, data)
  14   end
  15
  16   def delete(%User{} = user, id) do
  17     with %Activity{data: %{"type" => type}} <- Repo.get(Activity, id),
  18          {:ok, activity} <- CommonAPI.delete(id, user) do
  19       {:ok, activity}
  20     end
  21   end
  22
  23   @activitypub Application.get_env(:pleroma, :activitypub)
  24   @follow_handshake_timeout Keyword.get(@activitypub, :follow_handshake_timeout)
  25
  26   def follow(%User{} = follower, params) do
  27     with {:ok, %User{} = followed} <- get_user(params),
  28          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  29          {:ok, activity} <- ActivityPub.follow(follower, followed),
  30          {:ok, follower, followed} <-
  31            User.wait_and_refresh(@follow_handshake_timeout, follower, followed) do
  32       {:ok, follower, followed, activity}
  33     else
  34       err -> err
  35     end
  36   end
  37
  38   def unfollow(%User{} = follower, params) do
  39     with {:ok, %User{} = unfollowed} <- get_user(params),
  40          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  41          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  42       {:ok, follower, unfollowed}
  43     else
  44       err -> err
  45     end
  46   end
  47
  48   def block(%User{} = blocker, params) do
  49     with {:ok, %User{} = blocked} <- get_user(params),
  50          {:ok, blocker} <- User.block(blocker, blocked),
  51          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  52       {:ok, blocker, blocked}
  53     else
  54       err -> err
  55     end
  56   end
  57
  58   def unblock(%User{} = blocker, params) do
  59     with {:ok, %User{} = blocked} <- get_user(params),
  60          {:ok, blocker} <- User.unblock(blocker, blocked),
  61          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  62       {:ok, blocker, blocked}
  63     else
  64       err -> err
  65     end
  66   end
  67
  68   def repeat(%User{} = user, ap_id_or_id) do
  69     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  70          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  71       {:ok, activity}
  72     end
  73   end
  74
  75   def unrepeat(%User{} = user, ap_id_or_id) do
  76     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  77          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  78       {:ok, activity}
  79     end
  80   end
  81
  82   def fav(%User{} = user, ap_id_or_id) do
  83     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  84          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  85       {:ok, activity}
  86     end
  87   end
  88
  89   def unfav(%User{} = user, ap_id_or_id) do
  90     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  91          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  92       {:ok, activity}
  93     end
  94   end
  95
  96   def upload(%Plug.Upload{} = file, format \\ "xml") do
  97     {:ok, object} = ActivityPub.upload(file)
  98
  99     url = List.first(object.data["url"])
 100     href = url["href"]
 101     type = url["mediaType"]
 102
 103     case format do
 104       "xml" ->
 105         # Fake this as good as possible...
 106         """
 107         <?xml version="1.0" encoding="UTF-8"?>
 108         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 109         <mediaid>#{object.id}</mediaid>
 110         <media_id>#{object.id}</media_id>
 111         <media_id_string>#{object.id}</media_id_string>
 112         <media_url>#{href}</media_url>
 113         <mediaurl>#{href}</mediaurl>
 114         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 115         </rsp>
 116         """
 117
 118       "json" ->
 119         %{
 120           media_id: object.id,
 121           media_id_string: "#{object.id}}",
 122           media_url: href,
 123           size: 0
 124         }
 125         |> Jason.encode!()
 126     end
 127   end
 128
 129   def register_user(params) do
 130     tokenString = params["token"]
 131
 132     params = %{
 133       nickname: params["nickname"],
 134       name: params["fullname"],
 135       bio: params["bio"],
 136       email: params["email"],
 137       password: params["password"],
 138       password_confirmation: params["confirm"]
 139     }
 140
 141     # no need to query DB if registration is open
 142     token =
 143       unless @registrations_open || is_nil(tokenString) do
 144         Repo.get_by(UserInviteToken, %{token: tokenString})
 145       end
 146
 147     cond do
 148       @registrations_open || (!is_nil(token) && !token.used) ->
 149         changeset = User.register_changeset(%User{}, params)
 150
 151         with {:ok, user} <- Repo.insert(changeset) do
 152           !@registrations_open && UserInviteToken.mark_as_used(token.token)
 153           {:ok, user}
 154         else
 155           {:error, changeset} ->
 156             errors =
 157               Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 158               |> Jason.encode!()
 159
 160             {:error, %{error: errors}}
 161         end
 162
 163       !@registrations_open && is_nil(token) ->
 164         {:error, "Invalid token"}
 165
 166       !@registrations_open && token.used ->
 167         {:error, "Expired token"}
 168     end
 169   end
 170
 171   def get_by_id_or_nickname(id_or_nickname) do
 172     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 173       Repo.get_by(User, nickname: id_or_nickname)
 174     else
 175       Repo.get(User, id_or_nickname)
 176     end
 177   end
 178
 179   def get_user(user \\ nil, params) do
 180     case params do
 181       %{"user_id" => user_id} ->
 182         case target = get_by_id_or_nickname(user_id) do
 183           nil ->
 184             {:error, "No user with such user_id"}
 185
 186           _ ->
 187             {:ok, target}
 188         end
 189
 190       %{"screen_name" => nickname} ->
 191         case target = Repo.get_by(User, nickname: nickname) do
 192           nil ->
 193             {:error, "No user with such screen_name"}
 194
 195           _ ->
 196             {:ok, target}
 197         end
 198
 199       _ ->
 200         if user do
 201           {:ok, user}
 202         else
 203           {:error, "You need to specify screen_name or user_id"}
 204         end
 205     end
 206   end
 207
 208   defp parse_int(string, default)
 209
 210   defp parse_int(string, default) when is_binary(string) do
 211     with {n, _} <- Integer.parse(string) do
 212       n
 213     else
 214       _e -> default
 215     end
 216   end
 217
 218   defp parse_int(_, default), do: default
 219
 220   def search(_user, %{"q" => query} = params) do
 221     limit = parse_int(params["rpp"], 20)
 222     page = parse_int(params["page"], 1)
 223     offset = (page - 1) * limit
 224
 225     q =
 226       from(
 227         a in Activity,
 228         where: fragment("?->>'type' = 'Create'", a.data),
 229         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 230         where:
 231           fragment(
 232             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 233             a.data,
 234             ^query
 235           ),
 236         limit: ^limit,
 237         offset: ^offset,
 238         # this one isn't indexed so psql won't take the wrong index.
 239         order_by: [desc: :inserted_at]
 240       )
 241
 242     _activities = Repo.all(q)
 243   end
 244
 245   defp make_date do
 246     DateTime.utc_now() |> DateTime.to_iso8601()
 247   end
 248
 249   # DEPRECATED mostly, context objects are now created at insertion time.
 250   def context_to_conversation_id(context) do
 251     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 252       id
 253     else
 254       _e ->
 255         changeset = Object.context_mapping(context)
 256
 257         case Repo.insert(changeset) do
 258           {:ok, %{id: id}} ->
 259             id
 260
 261           # This should be solved by an upsert, but it seems ecto
 262           # has problems accessing the constraint inside the jsonb.
 263           {:error, _} ->
 264             Object.get_cached_by_ap_id(context).id
 265         end
 266     end
 267   end
 268
 269   def conversation_id_to_context(id) do
 270     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 271       context
 272     else
 273       _e ->
 274         {:error, "No such conversation"}
 275     end
 276   end
 277
 278   def get_external_profile(for_user, uri) do
 279     with %User{} = user <- User.get_or_fetch(uri) do
 280       spawn(fn ->
 281         with url <- user.info["topic"],
 282              {:ok, %{body: body}} <-
 283                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 284           OStatus.handle_incoming(body)
 285         end
 286       end)
 287
 288       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 289     else
 290       _e ->
 291         {:error, "Couldn't find user"}
 292     end
 293   end
 294 end