git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   5
   6   import Ecto.Query
   7
   8   def create_status(user = %User{}, data = %{}) do
   9     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  10       Repo.get(Object, media_id).data
  11     end)
  12
  13     context = ActivityPub.generate_context_id
  14
  15     content = HtmlSanitizeEx.strip_tags(data["status"])
  16     |> String.replace("\n", "<br>")
  17
  18     mentions = parse_mentions(content)
  19
  20     default_to = [
  21       User.ap_followers(user),
  22       "https://www.w3.org/ns/activitystreams#Public"
  23     ]
  24
  25     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  26
  27     content_html = add_user_links(content, mentions)
  28
  29     date = make_date()
  30
  31     activity = %{
  32       "type" => "Create",
  33       "to" => to,
  34       "actor" => user.ap_id,
  35       "object" => %{
  36         "type" => "Note",
  37         "to" => to,
  38         "content" => content_html,
  39         "published" => date,
  40         "context" => context,
  41         "attachment" => attachments,
  42         "actor" => user.ap_id
  43       },
  44       "published" => date,
  45       "context" => context
  46     }
  47
  48     # Wire up reply info.
  49     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  50                     inReplyTo <- Repo.get(Activity, inReplyToId),
  51                     context <- inReplyTo.data["context"]
  52                do
  53
  54                to = activity["to"] ++ [inReplyTo.data["actor"]]
  55
  56                activity
  57                |> put_in(["to"], to)
  58                |> put_in(["context"], context)
  59                |> put_in(["object", "context"], context)
  60                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  61                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  62                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  63                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  64                else _e ->
  65                  activity
  66                end
  67
  68     with {:ok, activity} <- ActivityPub.insert(activity) do
  69       add_conversation_id(activity)
  70     end
  71   end
  72
  73   def fetch_friend_statuses(user, opts \\ %{}) do
  74     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  75     |> activities_to_statuses(%{for: user})
  76   end
  77
  78   def fetch_public_statuses(user, opts \\ %{}) do
  79     ActivityPub.fetch_public_activities(opts)
  80     |> activities_to_statuses(%{for: user})
  81   end
  82
  83   def fetch_user_statuses(user, opts \\ %{}) do
  84     target = get_user(user, opts)
  85     ActivityPub.fetch_activities([], Map.merge(opts, %{"actor_id" => target.ap_id}))
  86     |> activities_to_statuses(%{for: user})
  87   end
  88
  89   def fetch_conversation(user, id) do
  90     query = from activity in Activity,
  91       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
  92       limit: 1
  93
  94     with %Activity{} = activity <- Repo.one(query),
  95          context <- activity.data["context"],
  96          activities <- ActivityPub.fetch_activities_for_context(context),
  97          statuses <- activities |> activities_to_statuses(%{for: user})
  98     do
  99       statuses
 100     else e ->
 101       IO.inspect(e)
 102       []
 103     end
 104   end
 105
 106   def fetch_status(user, id) do
 107     with %Activity{} = activity <- Repo.get(Activity, id) do
 108       activity_to_status(activity, %{for: user})
 109     end
 110   end
 111
 112   def follow(%User{} = follower, followed_id) do
 113     with %User{} = followed <- Repo.get(User, followed_id),
 114          { :ok, follower } <- User.follow(follower, followed),
 115          { :ok, activity } <- ActivityPub.insert(%{
 116            "type" => "Follow",
 117            "actor" => follower.ap_id,
 118            "object" => followed.ap_id,
 119            "published" => make_date()
 120          })
 121     do
 122       { :ok, follower, followed, activity }
 123     end
 124   end
 125
 126   def unfollow(%User{} = follower, followed_id) do
 127     with %User{} = followed <- Repo.get(User, followed_id),
 128          { :ok, follower } <- User.unfollow(follower, followed)
 129     do
 130       { :ok, follower, followed }
 131     end
 132   end
 133
 134   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 135     object = Object.get_by_ap_id(object["id"])
 136
 137     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 138     new_data = activity.data
 139     |> Map.put("object", object.data)
 140
 141     status = %{activity | data: new_data}
 142     |> activity_to_status(%{for: user})
 143
 144     {:ok, status}
 145   end
 146
 147   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 148     object = Object.get_by_ap_id(object["id"])
 149
 150     {:ok, object} = ActivityPub.unlike(user, object)
 151     new_data = activity.data
 152     |> Map.put("object", object.data)
 153
 154     status = %{activity | data: new_data}
 155     |> activity_to_status(%{for: user})
 156
 157     {:ok, status}
 158   end
 159
 160   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 161     object = Object.get_by_ap_id(object["id"])
 162
 163     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 164     new_data = activity.data
 165     |> Map.put("object", object.data)
 166
 167     status = %{activity | data: new_data}
 168     |> activity_to_status(%{for: user})
 169
 170     {:ok, status}
 171   end
 172
 173   def upload(%Plug.Upload{} = file, format \\ "xml") do
 174     {:ok, object} = ActivityPub.upload(file)
 175
 176     url = List.first(object.data["url"])
 177     href = url["href"]
 178     type = url["mediaType"]
 179
 180     case format do
 181       "xml" ->
 182         # Fake this as good as possible...
 183         """
 184         <?xml version="1.0" encoding="UTF-8"?>
 185         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 186         <mediaid>#{object.id}</mediaid>
 187         <media_id>#{object.id}</media_id>
 188         <media_id_string>#{object.id}</media_id_string>
 189         <media_url>#{href}</media_url>
 190         <mediaurl>#{href}</mediaurl>
 191         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 192         </rsp>
 193         """
 194       "json" ->
 195         %{
 196           media_id: object.id,
 197           media_id_string: "#{object.id}}",
 198           media_url: href,
 199           size: 0
 200         } |> Poison.encode!
 201     end
 202   end
 203
 204   def parse_mentions(text) do
 205     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 206     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 207
 208     Regex.scan(regex, text)
 209     |> List.flatten
 210     |> Enum.uniq
 211     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 212     |> Enum.filter(fn ({_match, user}) -> user end)
 213   end
 214
 215   def add_user_links(text, mentions) do
 216     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 217   end
 218
 219   defp add_conversation_id(activity) do
 220     if is_integer(activity.data["statusnetConversationId"]) do
 221       {:ok, activity}
 222     else
 223       data = activity.data
 224       |> put_in(["object", "statusnetConversationId"], activity.id)
 225       |> put_in(["statusnetConversationId"], activity.id)
 226
 227       object = Object.get_by_ap_id(activity.data["object"]["id"])
 228
 229       changeset = Ecto.Changeset.change(object, data: data["object"])
 230       Repo.update(changeset)
 231
 232       changeset = Ecto.Changeset.change(activity, data: data)
 233       Repo.update(changeset)
 234     end
 235   end
 236
 237   def register_user(params) do
 238     params = %{
 239       nickname: params["nickname"],
 240       name: params["fullname"],
 241       bio: params["bio"],
 242       email: params["email"],
 243       password: params["password"],
 244       password_confirmation: params["confirm"]
 245     }
 246
 247     changeset = User.register_changeset(%User{}, params)
 248
 249     with {:ok, user} <- Repo.insert(changeset) do
 250       {:ok, UserRepresenter.to_map(user)}
 251     else
 252       {:error, changeset} ->
 253         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, opts} -> msg end)
 254         |> Poison.encode!
 255         {:error, %{error: errors}}
 256     end
 257   end
 258
 259   defp activities_to_statuses(activities, opts) do
 260     Enum.map(activities, fn(activity) ->
 261       activity_to_status(activity, opts)
 262     end)
 263   end
 264
 265   # For likes, fetch the liked activity, too.
 266   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 267     actor = get_in(activity.data, ["actor"])
 268     user = User.get_cached_by_ap_id(actor)
 269     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 270
 271     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 272   end
 273
 274   # For announces, fetch the announced activity and the user.
 275   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 276     actor = get_in(activity.data, ["actor"])
 277     user = User.get_cached_by_ap_id(actor)
 278     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 279     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 280
 281     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 282   end
 283
 284   defp activity_to_status(activity, opts) do
 285     actor = get_in(activity.data, ["actor"])
 286     user = User.get_cached_by_ap_id(actor)
 287     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 288     mentioned_users = Enum.map(activity.data["to"], fn (ap_id) ->
 289       User.get_cached_by_ap_id(ap_id)
 290     end)
 291     |> Enum.filter(&(&1))
 292
 293     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 294   end
 295
 296   defp make_date do
 297     DateTime.utc_now() |> DateTime.to_iso8601
 298   end
 299
 300   defp get_user(user, params) do
 301     case params do
 302       %{ "user_id" => user_id } ->
 303         Repo.get(User, user_id)
 304       %{ "screen_name" => nickname } ->
 305         Repo.get_by!(User, nickname: nickname)
 306       _ ->
 307         user
 308     end
 309   end
 310 end