git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   alias Pleroma.Activity
   7   alias Pleroma.Mailer
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.UserEmail
  11   alias Pleroma.UserInviteToken
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.TwitterAPI.UserView
  15
  16   import Ecto.Query
  17
  18   def create_status(%User{} = user, %{"status" => _} = data) do
  19     CommonAPI.post(user, data)
  20   end
  21
  22   def delete(%User{} = user, id) do
  23     with %Activity{data: %{"type" => _type}} <- Activity.get_by_id(id),
  24          {:ok, activity} <- CommonAPI.delete(id, user) do
  25       {:ok, activity}
  26     end
  27   end
  28
  29   def follow(%User{} = follower, params) do
  30     with {:ok, %User{} = followed} <- get_user(params) do
  31       CommonAPI.follow(follower, followed)
  32     end
  33   end
  34
  35   def unfollow(%User{} = follower, params) do
  36     with {:ok, %User{} = unfollowed} <- get_user(params),
  37          {:ok, follower} <- CommonAPI.unfollow(follower, unfollowed) do
  38       {:ok, follower, unfollowed}
  39     end
  40   end
  41
  42   def block(%User{} = blocker, params) do
  43     with {:ok, %User{} = blocked} <- get_user(params),
  44          {:ok, blocker} <- User.block(blocker, blocked),
  45          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  46       {:ok, blocker, blocked}
  47     else
  48       err -> err
  49     end
  50   end
  51
  52   def unblock(%User{} = blocker, params) do
  53     with {:ok, %User{} = blocked} <- get_user(params),
  54          {:ok, blocker} <- User.unblock(blocker, blocked),
  55          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  56       {:ok, blocker, blocked}
  57     else
  58       err -> err
  59     end
  60   end
  61
  62   def subscribe(%User{} = subscriber, params) do
  63     with {:ok, %User{} = subscribed} <- get_user(params) do
  64       User.subscribe(subscriber, subscribed)
  65     end
  66   end
  67
  68   def unsubscribe(%User{} = unsubscriber, params) do
  69     with {:ok, %User{} = unsubscribed} <- get_user(params) do
  70       User.unsubscribe(unsubscriber, unsubscribed)
  71     end
  72   end
  73
  74   def repeat(%User{} = user, ap_id_or_id) do
  75     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  76          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  77       {:ok, activity}
  78     end
  79   end
  80
  81   def unrepeat(%User{} = user, ap_id_or_id) do
  82     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  83          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  84       {:ok, activity}
  85     end
  86   end
  87
  88   def pin(%User{} = user, ap_id_or_id) do
  89     CommonAPI.pin(ap_id_or_id, user)
  90   end
  91
  92   def unpin(%User{} = user, ap_id_or_id) do
  93     CommonAPI.unpin(ap_id_or_id, user)
  94   end
  95
  96   def fav(%User{} = user, ap_id_or_id) do
  97     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  98          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  99       {:ok, activity}
 100     end
 101   end
 102
 103   def unfav(%User{} = user, ap_id_or_id) do
 104     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
 105          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
 106       {:ok, activity}
 107     end
 108   end
 109
 110   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
 111     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
 112
 113     url = List.first(object.data["url"])
 114     href = url["href"]
 115     type = url["mediaType"]
 116
 117     case format do
 118       "xml" ->
 119         # Fake this as good as possible...
 120         """
 121         <?xml version="1.0" encoding="UTF-8"?>
 122         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 123         <mediaid>#{object.id}</mediaid>
 124         <media_id>#{object.id}</media_id>
 125         <media_id_string>#{object.id}</media_id_string>
 126         <media_url>#{href}</media_url>
 127         <mediaurl>#{href}</mediaurl>
 128         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 129         </rsp>
 130         """
 131
 132       "json" ->
 133         %{
 134           media_id: object.id,
 135           media_id_string: "#{object.id}}",
 136           media_url: href,
 137           size: 0
 138         }
 139         |> Jason.encode!()
 140     end
 141   end
 142
 143   def register_user(params) do
 144     token_string = params["token"]
 145
 146     params = %{
 147       nickname: params["nickname"],
 148       name: params["fullname"],
 149       bio: User.parse_bio(params["bio"]),
 150       email: params["email"],
 151       password: params["password"],
 152       password_confirmation: params["confirm"],
 153       captcha_solution: params["captcha_solution"],
 154       captcha_token: params["captcha_token"],
 155       captcha_answer_data: params["captcha_answer_data"]
 156     }
 157
 158     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 159     # true if captcha is disabled or enabled and valid, false otherwise
 160     captcha_ok =
 161       if !captcha_enabled do
 162         :ok
 163       else
 164         Pleroma.Captcha.validate(
 165           params[:captcha_token],
 166           params[:captcha_solution],
 167           params[:captcha_answer_data]
 168         )
 169       end
 170
 171     # Captcha invalid
 172     if captcha_ok != :ok do
 173       {:error, error} = captcha_ok
 174       # I have no idea how this error handling works
 175       {:error, %{error: Jason.encode!(%{captcha: [error]})}}
 176     else
 177       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 178
 179       # no need to query DB if registration is open
 180       token =
 181         unless registrations_open || is_nil(token_string) do
 182           Repo.get_by(UserInviteToken, %{token: token_string})
 183         end
 184
 185       cond do
 186         registrations_open || (!is_nil(token) && !token.used) ->
 187           changeset = User.register_changeset(%User{}, params)
 188
 189           with {:ok, user} <- User.register(changeset) do
 190             !registrations_open && UserInviteToken.mark_as_used(token.token)
 191
 192             {:ok, user}
 193           else
 194             {:error, changeset} ->
 195               errors =
 196                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 197                 |> Jason.encode!()
 198
 199               {:error, %{error: errors}}
 200           end
 201
 202         !registrations_open && is_nil(token) ->
 203           {:error, "Invalid token"}
 204
 205         !registrations_open && token.used ->
 206           {:error, "Expired token"}
 207       end
 208     end
 209   end
 210
 211   def password_reset(nickname_or_email) do
 212     with true <- is_binary(nickname_or_email),
 213          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 214          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 215       user
 216       |> UserEmail.password_reset_email(token_record.token)
 217       |> Mailer.deliver_async()
 218     else
 219       false ->
 220         {:error, "bad user identifier"}
 221
 222       %User{local: false} ->
 223         {:error, "remote user"}
 224
 225       nil ->
 226         {:error, "unknown user"}
 227     end
 228   end
 229
 230   def get_user(user \\ nil, params) do
 231     case params do
 232       %{"user_id" => user_id} ->
 233         case target = User.get_cached_by_nickname_or_id(user_id) do
 234           nil ->
 235             {:error, "No user with such user_id"}
 236
 237           _ ->
 238             {:ok, target}
 239         end
 240
 241       %{"screen_name" => nickname} ->
 242         case User.get_by_nickname(nickname) do
 243           nil -> {:error, "No user with such screen_name"}
 244           target -> {:ok, target}
 245         end
 246
 247       _ ->
 248         if user do
 249           {:ok, user}
 250         else
 251           {:error, "You need to specify screen_name or user_id"}
 252         end
 253     end
 254   end
 255
 256   defp parse_int(string, default)
 257
 258   defp parse_int(string, default) when is_binary(string) do
 259     with {n, _} <- Integer.parse(string) do
 260       n
 261     else
 262       _e -> default
 263     end
 264   end
 265
 266   defp parse_int(_, default), do: default
 267
 268   def search(_user, %{"q" => query} = params) do
 269     limit = parse_int(params["rpp"], 20)
 270     page = parse_int(params["page"], 1)
 271     offset = (page - 1) * limit
 272
 273     q =
 274       from(
 275         a in Activity,
 276         where: fragment("?->>'type' = 'Create'", a.data),
 277         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 278         where:
 279           fragment(
 280             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 281             a.data,
 282             ^query
 283           ),
 284         limit: ^limit,
 285         offset: ^offset,
 286         # this one isn't indexed so psql won't take the wrong index.
 287         order_by: [desc: :inserted_at]
 288       )
 289
 290     _activities = Repo.all(q)
 291   end
 292
 293   def get_external_profile(for_user, uri) do
 294     with %User{} = user <- User.get_or_fetch(uri) do
 295       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 296     else
 297       _e ->
 298         {:error, "Couldn't find user"}
 299     end
 300   end
 301 end