git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.{OStatus, CommonAPI}
   6   import Ecto.Query
   7
   8   @httpoison Application.get_env(:pleroma, :httpoison)
   9
  10   def create_status(%User{} = user, %{"status" => _} = data) do
  11     CommonAPI.post(user, data)
  12   end
  13
  14   def follow(%User{} = follower, params) do
  15     with {:ok, %User{} = followed} <- get_user(params),
  16          {:ok, follower} <- User.follow(follower, followed),
  17          {:ok, activity} <- ActivityPub.follow(follower, followed) do
  18       {:ok, follower, followed, activity}
  19     else
  20       err -> err
  21     end
  22   end
  23
  24   def unfollow(%User{} = follower, params) do
  25     with {:ok, %User{} = unfollowed} <- get_user(params),
  26          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  27          {:ok, _activity} <-
  28            ActivityPub.insert(%{
  29              "type" => "Undo",
  30              "actor" => follower.ap_id,
  31              # get latest Follow for these users
  32              "object" => follow_activity.data["id"],
  33              "published" => make_date()
  34            }) do
  35       {:ok, follower, unfollowed}
  36     else
  37       err -> err
  38     end
  39   end
  40
  41   def block(%User{} = blocker, params) do
  42     with {:ok, %User{} = blocked} <- get_user(params),
  43          {:ok, blocker} <- User.block(blocker, blocked) do
  44       {:ok, blocker, blocked}
  45     else
  46       err -> err
  47     end
  48   end
  49
  50   def unblock(%User{} = blocker, params) do
  51     with {:ok, %User{} = blocked} <- get_user(params),
  52          {:ok, blocker} <- User.unblock(blocker, blocked) do
  53       {:ok, blocker, blocked}
  54     else
  55       err -> err
  56     end
  57   end
  58
  59   def repeat(%User{} = user, ap_id_or_id) do
  60     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  61          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  62       {:ok, activity}
  63     end
  64   end
  65
  66   def fav(%User{} = user, ap_id_or_id) do
  67     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  68          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  69       {:ok, activity}
  70     end
  71   end
  72
  73   def unfav(%User{} = user, ap_id_or_id) do
  74     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
  75          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  76       {:ok, activity}
  77     end
  78   end
  79
  80   def upload(%Plug.Upload{} = file, format \\ "xml") do
  81     {:ok, object} = ActivityPub.upload(file)
  82
  83     url = List.first(object.data["url"])
  84     href = url["href"]
  85     type = url["mediaType"]
  86
  87     case format do
  88       "xml" ->
  89         # Fake this as good as possible...
  90         """
  91         <?xml version="1.0" encoding="UTF-8"?>
  92         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
  93         <mediaid>#{object.id}</mediaid>
  94         <media_id>#{object.id}</media_id>
  95         <media_id_string>#{object.id}</media_id_string>
  96         <media_url>#{href}</media_url>
  97         <mediaurl>#{href}</mediaurl>
  98         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
  99         </rsp>
 100         """
 101
 102       "json" ->
 103         %{
 104           media_id: object.id,
 105           media_id_string: "#{object.id}}",
 106           media_url: href,
 107           size: 0
 108         }
 109         |> Jason.encode!()
 110     end
 111   end
 112
 113   def register_user(params) do
 114     params = %{
 115       nickname: params["nickname"],
 116       name: params["fullname"],
 117       bio: params["bio"],
 118       email: params["email"],
 119       password: params["password"],
 120       password_confirmation: params["confirm"]
 121     }
 122
 123     changeset = User.register_changeset(%User{}, params)
 124
 125     with {:ok, user} <- Repo.insert(changeset) do
 126       {:ok, user}
 127     else
 128       {:error, changeset} ->
 129         errors =
 130           Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 131           |> Jason.encode!()
 132
 133         {:error, %{error: errors}}
 134     end
 135   end
 136
 137   def get_by_id_or_nickname(id_or_nickname) do
 138     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 139       Repo.get_by(User, nickname: id_or_nickname)
 140     else
 141       Repo.get(User, id_or_nickname)
 142     end
 143   end
 144
 145   def get_user(user \\ nil, params) do
 146     case params do
 147       %{"user_id" => user_id} ->
 148         case target = get_by_id_or_nickname(user_id) do
 149           nil ->
 150             {:error, "No user with such user_id"}
 151
 152           _ ->
 153             {:ok, target}
 154         end
 155
 156       %{"screen_name" => nickname} ->
 157         case target = Repo.get_by(User, nickname: nickname) do
 158           nil ->
 159             {:error, "No user with such screen_name"}
 160
 161           _ ->
 162             {:ok, target}
 163         end
 164
 165       _ ->
 166         if user do
 167           {:ok, user}
 168         else
 169           {:error, "You need to specify screen_name or user_id"}
 170         end
 171     end
 172   end
 173
 174   defp parse_int(string, default)
 175
 176   defp parse_int(string, default) when is_binary(string) do
 177     with {n, _} <- Integer.parse(string) do
 178       n
 179     else
 180       _e -> default
 181     end
 182   end
 183
 184   defp parse_int(_, default), do: default
 185
 186   def search(_user, %{"q" => query} = params) do
 187     limit = parse_int(params["rpp"], 20)
 188     page = parse_int(params["page"], 1)
 189     offset = (page - 1) * limit
 190
 191     q =
 192       from(
 193         a in Activity,
 194         where: fragment("?->>'type' = 'Create'", a.data),
 195         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 196         where:
 197           fragment(
 198             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 199             a.data,
 200             ^query
 201           ),
 202         limit: ^limit,
 203         offset: ^offset,
 204         # this one isn't indexed so psql won't take the wrong index.
 205         order_by: [desc: :inserted_at]
 206       )
 207
 208     _activities = Repo.all(q)
 209   end
 210
 211   defp make_date do
 212     DateTime.utc_now() |> DateTime.to_iso8601()
 213   end
 214
 215   # DEPRECATED mostly, context objects are now created at insertion time.
 216   def context_to_conversation_id(context) do
 217     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 218       id
 219     else
 220       _e ->
 221         changeset = Object.context_mapping(context)
 222
 223         case Repo.insert(changeset) do
 224           {:ok, %{id: id}} ->
 225             id
 226
 227           # This should be solved by an upsert, but it seems ecto
 228           # has problems accessing the constraint inside the jsonb.
 229           {:error, _} ->
 230             Object.get_cached_by_ap_id(context).id
 231         end
 232     end
 233   end
 234
 235   def conversation_id_to_context(id) do
 236     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 237       context
 238     else
 239       _e ->
 240         {:error, "No such conversation"}
 241     end
 242   end
 243
 244   def get_external_profile(for_user, uri) do
 245     with %User{} = user <- User.get_or_fetch(uri) do
 246       spawn(fn ->
 247         with url <- user.info["topic"],
 248              {:ok, %{body: body}} <-
 249                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 250           OStatus.handle_incoming(body)
 251         end
 252       end)
 253
 254       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 255     else
 256       _e ->
 257         {:error, "Couldn't find user"}
 258     end
 259   end
 260 end