git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   import Pleroma.Web.Gettext
   7
   8   alias Pleroma.Emails.Mailer
   9   alias Pleroma.Emails.UserEmail
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.UserInviteToken
  13
  14   def register_user(params, opts \\ []) do
  15     params =
  16       params
  17       |> Map.take([:email, :token, :password])
  18       |> Map.put(:bio, params |> Map.get(:bio, "") |> User.parse_bio())
  19       |> Map.put(:nickname, params[:username])
  20       |> Map.put(:name, Map.get(params, :fullname, params[:username]))
  21       |> Map.put(:password_confirmation, params[:password])
  22       |> Map.put(:registration_reason, params[:reason])
  23
  24     if Pleroma.Config.get([:instance, :registrations_open]) do
  25       create_user(params, opts)
  26     else
  27       create_user_with_invite(params, opts)
  28     end
  29   end
  30
  31   defp create_user_with_invite(params, opts) do
  32     with %{token: token} when is_binary(token) <- params,
  33          %UserInviteToken{} = invite <- Repo.get_by(UserInviteToken, %{token: token}),
  34          true <- UserInviteToken.valid_invite?(invite) do
  35       UserInviteToken.update_usage!(invite)
  36       create_user(params, opts)
  37     else
  38       nil -> {:error, "Invalid token"}
  39       _ -> {:error, "Expired token"}
  40     end
  41   end
  42
  43   defp create_user(params, opts) do
  44     changeset = User.register_changeset(%User{}, params, opts)
  45
  46     case User.register(changeset) do
  47       {:ok, user} ->
  48         {:ok, user}
  49
  50       {:error, changeset} ->
  51         errors =
  52           changeset
  53           |> Ecto.Changeset.traverse_errors(fn {msg, _opts} -> msg end)
  54           |> Jason.encode!()
  55
  56         {:error, errors}
  57     end
  58   end
  59
  60   def password_reset(nickname_or_email) do
  61     with true <- is_binary(nickname_or_email),
  62          %User{local: true, email: email} = user when is_binary(email) <-
  63            User.get_by_nickname_or_email(nickname_or_email),
  64          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
  65       user
  66       |> UserEmail.password_reset_email(token_record.token)
  67       |> Mailer.deliver_async()
  68
  69       {:ok, :enqueued}
  70     else
  71       false ->
  72         {:error, "bad user identifier"}
  73
  74       %User{local: true, email: nil} ->
  75         {:ok, :noop}
  76
  77       %User{local: false} ->
  78         {:error, "remote user"}
  79
  80       nil ->
  81         {:error, "unknown user"}
  82     end
  83   end
  84
  85   def validate_captcha(app, params) do
  86     if app.trusted || not Pleroma.Captcha.enabled?() do
  87       :ok
  88     else
  89       do_validate_captcha(params)
  90     end
  91   end
  92
  93   defp do_validate_captcha(params) do
  94     with :ok <- validate_captcha_presence(params),
  95          :ok <-
  96            Pleroma.Captcha.validate(
  97              params[:captcha_token],
  98              params[:captcha_solution],
  99              params[:captcha_answer_data]
 100            ) do
 101       :ok
 102     else
 103       {:error, :captcha_error} ->
 104         captcha_error(dgettext("errors", "CAPTCHA Error"))
 105
 106       {:error, :invalid} ->
 107         captcha_error(dgettext("errors", "Invalid CAPTCHA"))
 108
 109       {:error, :kocaptcha_service_unavailable} ->
 110         captcha_error(dgettext("errors", "Kocaptcha service unavailable"))
 111
 112       {:error, :expired} ->
 113         captcha_error(dgettext("errors", "CAPTCHA expired"))
 114
 115       {:error, :already_used} ->
 116         captcha_error(dgettext("errors", "CAPTCHA already used"))
 117
 118       {:error, :invalid_answer_data} ->
 119         captcha_error(dgettext("errors", "Invalid answer data"))
 120
 121       {:error, error} ->
 122         captcha_error(error)
 123     end
 124   end
 125
 126   defp validate_captcha_presence(params) do
 127     [:captcha_solution, :captcha_token, :captcha_answer_data]
 128     |> Enum.find_value(:ok, fn key ->
 129       unless is_binary(params[key]) do
 130         error = dgettext("errors", "Invalid CAPTCHA (Missing parameter: %{name})", name: key)
 131         {:error, error}
 132       end
 133     end)
 134   end
 135
 136   # For some reason FE expects error message to be a serialized JSON
 137   defp captcha_error(error), do: {:error, Jason.encode!(%{captcha: [error]})}
 138 end