git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.{OStatus, CommonAPI}
   6   import Ecto.Query
   7
   8   @instance Application.get_env(:pleroma, :instance)
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10   @registrations_open Keyword.get(@instance, :registrations_open)
  11
  12   def create_status(%User{} = user, %{"status" => _} = data) do
  13     CommonAPI.post(user, data)
  14   end
  15
  16   def delete(%User{} = user, id) do
  17     with %Activity{data: %{"type" => type}} <- Repo.get(Activity, id),
  18          {:ok, activity} <- CommonAPI.delete(id, user) do
  19       {:ok, activity}
  20     end
  21   end
  22
  23   def follow(%User{} = follower, params) do
  24     with {:ok, %User{} = followed} <- get_user(params),
  25          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  26          {:ok, activity} <- ActivityPub.follow(follower, followed) do
  27       {:ok, follower, followed, activity}
  28     else
  29       err -> err
  30     end
  31   end
  32
  33   def unfollow(%User{} = follower, params) do
  34     with {:ok, %User{} = unfollowed} <- get_user(params),
  35          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  36          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  37       {:ok, follower, unfollowed}
  38     else
  39       err -> err
  40     end
  41   end
  42
  43   def block(%User{} = blocker, params) do
  44     with {:ok, %User{} = blocked} <- get_user(params),
  45          {:ok, blocker} <- User.block(blocker, blocked),
  46          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  47       {:ok, blocker, blocked}
  48     else
  49       err -> err
  50     end
  51   end
  52
  53   def unblock(%User{} = blocker, params) do
  54     with {:ok, %User{} = blocked} <- get_user(params),
  55          {:ok, blocker} <- User.unblock(blocker, blocked),
  56          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  57       {:ok, blocker, blocked}
  58     else
  59       err -> err
  60     end
  61   end
  62
  63   def repeat(%User{} = user, ap_id_or_id) do
  64     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  65          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  66       {:ok, activity}
  67     end
  68   end
  69
  70   def unrepeat(%User{} = user, ap_id_or_id) do
  71     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  72          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  73       {:ok, activity}
  74     end
  75   end
  76
  77   def fav(%User{} = user, ap_id_or_id) do
  78     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  79          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  80       {:ok, activity}
  81     end
  82   end
  83
  84   def unfav(%User{} = user, ap_id_or_id) do
  85     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  86          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  87       {:ok, activity}
  88     end
  89   end
  90
  91   def upload(%Plug.Upload{} = file, format \\ "xml") do
  92     {:ok, object} = ActivityPub.upload(file)
  93
  94     url = List.first(object.data["url"])
  95     href = url["href"]
  96     type = url["mediaType"]
  97
  98     case format do
  99       "xml" ->
 100         # Fake this as good as possible...
 101         """
 102         <?xml version="1.0" encoding="UTF-8"?>
 103         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 104         <mediaid>#{object.id}</mediaid>
 105         <media_id>#{object.id}</media_id>
 106         <media_id_string>#{object.id}</media_id_string>
 107         <media_url>#{href}</media_url>
 108         <mediaurl>#{href}</mediaurl>
 109         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 110         </rsp>
 111         """
 112
 113       "json" ->
 114         %{
 115           media_id: object.id,
 116           media_id_string: "#{object.id}}",
 117           media_url: href,
 118           size: 0
 119         }
 120         |> Jason.encode!()
 121     end
 122   end
 123
 124   def register_user(params) do
 125     tokenString = params["token"]
 126
 127     params = %{
 128       nickname: params["nickname"],
 129       name: params["fullname"],
 130       bio: params["bio"],
 131       email: params["email"],
 132       password: params["password"],
 133       password_confirmation: params["confirm"]
 134     }
 135
 136     # no need to query DB if registration is open
 137     token =
 138       unless @registrations_open || is_nil(tokenString) do
 139         Repo.get_by(UserInviteToken, %{token: tokenString})
 140       end
 141
 142     cond do
 143       @registrations_open || (!is_nil(token) && !token.used) ->
 144         changeset = User.register_changeset(%User{}, params)
 145
 146         with {:ok, user} <- Repo.insert(changeset) do
 147           !@registrations_open && UserInviteToken.mark_as_used(token.token)
 148           {:ok, user}
 149         else
 150           {:error, changeset} ->
 151             errors =
 152               Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 153               |> Jason.encode!()
 154
 155             {:error, %{error: errors}}
 156         end
 157
 158       !@registrations_open && is_nil(token) ->
 159         {:error, "Invalid token"}
 160
 161       !@registrations_open && token.used ->
 162         {:error, "Expired token"}
 163     end
 164   end
 165
 166   def get_by_id_or_nickname(id_or_nickname) do
 167     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 168       Repo.get_by(User, nickname: id_or_nickname)
 169     else
 170       Repo.get(User, id_or_nickname)
 171     end
 172   end
 173
 174   def get_user(user \\ nil, params) do
 175     case params do
 176       %{"user_id" => user_id} ->
 177         case target = get_by_id_or_nickname(user_id) do
 178           nil ->
 179             {:error, "No user with such user_id"}
 180
 181           _ ->
 182             {:ok, target}
 183         end
 184
 185       %{"screen_name" => nickname} ->
 186         case target = Repo.get_by(User, nickname: nickname) do
 187           nil ->
 188             {:error, "No user with such screen_name"}
 189
 190           _ ->
 191             {:ok, target}
 192         end
 193
 194       _ ->
 195         if user do
 196           {:ok, user}
 197         else
 198           {:error, "You need to specify screen_name or user_id"}
 199         end
 200     end
 201   end
 202
 203   defp parse_int(string, default)
 204
 205   defp parse_int(string, default) when is_binary(string) do
 206     with {n, _} <- Integer.parse(string) do
 207       n
 208     else
 209       _e -> default
 210     end
 211   end
 212
 213   defp parse_int(_, default), do: default
 214
 215   def search(_user, %{"q" => query} = params) do
 216     limit = parse_int(params["rpp"], 20)
 217     page = parse_int(params["page"], 1)
 218     offset = (page - 1) * limit
 219
 220     q =
 221       from(
 222         a in Activity,
 223         where: fragment("?->>'type' = 'Create'", a.data),
 224         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 225         where:
 226           fragment(
 227             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 228             a.data,
 229             ^query
 230           ),
 231         limit: ^limit,
 232         offset: ^offset,
 233         # this one isn't indexed so psql won't take the wrong index.
 234         order_by: [desc: :inserted_at]
 235       )
 236
 237     _activities = Repo.all(q)
 238   end
 239
 240   defp make_date do
 241     DateTime.utc_now() |> DateTime.to_iso8601()
 242   end
 243
 244   # DEPRECATED mostly, context objects are now created at insertion time.
 245   def context_to_conversation_id(context) do
 246     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 247       id
 248     else
 249       _e ->
 250         changeset = Object.context_mapping(context)
 251
 252         case Repo.insert(changeset) do
 253           {:ok, %{id: id}} ->
 254             id
 255
 256           # This should be solved by an upsert, but it seems ecto
 257           # has problems accessing the constraint inside the jsonb.
 258           {:error, _} ->
 259             Object.get_cached_by_ap_id(context).id
 260         end
 261     end
 262   end
 263
 264   def conversation_id_to_context(id) do
 265     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 266       context
 267     else
 268       _e ->
 269         {:error, "No such conversation"}
 270     end
 271   end
 272
 273   def get_external_profile(for_user, uri) do
 274     with %User{} = user <- User.get_or_fetch(uri) do
 275       spawn(fn ->
 276         with url <- user.info["topic"],
 277              {:ok, %{body: body}} <-
 278                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 279           OStatus.handle_incoming(body)
 280         end
 281       end)
 282
 283       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 284     else
 285       _e ->
 286         {:error, "Couldn't find user"}
 287     end
 288   end
 289 end