git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   5
   6   import Ecto.Query
   7
   8   def create_status(user = %User{}, data = %{}) do
   9     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  10       Repo.get(Object, media_id).data
  11     end)
  12
  13     context = ActivityPub.generate_context_id
  14
  15     content = HtmlSanitizeEx.strip_tags(data["status"])
  16     |> String.replace("\n", "<br>")
  17
  18     mentions = parse_mentions(content)
  19
  20     default_to = [
  21       User.ap_followers(user),
  22       "https://www.w3.org/ns/activitystreams#Public"
  23     ]
  24
  25     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  26
  27     content_html = add_user_links(content, mentions)
  28
  29     date = make_date()
  30
  31     activity = %{
  32       "type" => "Create",
  33       "to" => to,
  34       "actor" => user.ap_id,
  35       "object" => %{
  36         "type" => "Note",
  37         "to" => to,
  38         "content" => content_html,
  39         "published" => date,
  40         "context" => context,
  41         "attachment" => attachments,
  42         "actor" => user.ap_id
  43       },
  44       "published" => date,
  45       "context" => context
  46     }
  47
  48     # Wire up reply info.
  49     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  50                     inReplyTo <- Repo.get(Activity, inReplyToId),
  51                     context <- inReplyTo.data["context"]
  52                do
  53
  54                to = activity["to"] ++ [inReplyTo.data["actor"]]
  55
  56                activity
  57                |> put_in(["to"], to)
  58                |> put_in(["context"], context)
  59                |> put_in(["object", "context"], context)
  60                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  61                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  62                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  63                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  64                else _e ->
  65                  activity
  66                end
  67
  68     with {:ok, activity} <- ActivityPub.insert(activity) do
  69       add_conversation_id(activity)
  70     end
  71   end
  72
  73   def fetch_friend_statuses(user, opts \\ %{}) do
  74     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  75     |> activities_to_statuses(%{for: user})
  76   end
  77
  78   def fetch_public_statuses(user, opts \\ %{}) do
  79     ActivityPub.fetch_public_activities(opts)
  80     |> activities_to_statuses(%{for: user})
  81   end
  82
  83   def fetch_user_statuses(user, opts \\ %{}) do
  84     ActivityPub.fetch_activities([], opts)
  85     |> activities_to_statuses(%{for: user})
  86   end
  87
  88   def fetch_mentions(user, opts \\ %{}) do
  89     ActivityPub.fetch_activities([user.ap_id], opts)
  90     |> activities_to_statuses(%{for: user})
  91   end
  92
  93   def fetch_conversation(user, id) do
  94     query = from activity in Activity,
  95       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
  96       limit: 1
  97
  98     with %Activity{} = activity <- Repo.one(query),
  99          context <- activity.data["context"],
 100          activities <- ActivityPub.fetch_activities_for_context(context),
 101          statuses <- activities |> activities_to_statuses(%{for: user})
 102     do
 103       statuses
 104     else e ->
 105       IO.inspect(e)
 106       []
 107     end
 108   end
 109
 110   def fetch_status(user, id) do
 111     with %Activity{} = activity <- Repo.get(Activity, id) do
 112       activity_to_status(activity, %{for: user})
 113     end
 114   end
 115
 116   def follow(%User{} = follower, followed_id) do
 117     with %User{} = followed <- Repo.get(User, followed_id),
 118     { :ok, follower } <- User.follow(follower, followed),
 119          { :ok, activity } <- ActivityPub.insert(%{
 120            "type" => "Follow",
 121            "actor" => follower.ap_id,
 122            "object" => followed.ap_id,
 123            "published" => make_date()
 124          })
 125     do
 126       { :ok, follower, followed, activity }
 127     else
 128       err -> err
 129     end
 130   end
 131
 132   def unfollow(%User{} = follower, followed_id) do
 133     with %User{} = followed <- Repo.get(User, followed_id),
 134          { :ok, follower } <- User.unfollow(follower, followed)
 135     do
 136       { :ok, follower, followed }
 137     else
 138       err -> err
 139     end
 140   end
 141
 142   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 143     object = Object.get_by_ap_id(object["id"])
 144
 145     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 146     new_data = activity.data
 147     |> Map.put("object", object.data)
 148
 149     status = %{activity | data: new_data}
 150     |> activity_to_status(%{for: user})
 151
 152     {:ok, status}
 153   end
 154
 155   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 156     object = Object.get_by_ap_id(object["id"])
 157
 158     {:ok, object} = ActivityPub.unlike(user, object)
 159     new_data = activity.data
 160     |> Map.put("object", object.data)
 161
 162     status = %{activity | data: new_data}
 163     |> activity_to_status(%{for: user})
 164
 165     {:ok, status}
 166   end
 167
 168   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 169     object = Object.get_by_ap_id(object["id"])
 170
 171     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 172     new_data = activity.data
 173     |> Map.put("object", object.data)
 174
 175     status = %{activity | data: new_data}
 176     |> activity_to_status(%{for: user})
 177
 178     {:ok, status}
 179   end
 180
 181   def upload(%Plug.Upload{} = file, format \\ "xml") do
 182     {:ok, object} = ActivityPub.upload(file)
 183
 184     url = List.first(object.data["url"])
 185     href = url["href"]
 186     type = url["mediaType"]
 187
 188     case format do
 189       "xml" ->
 190         # Fake this as good as possible...
 191         """
 192         <?xml version="1.0" encoding="UTF-8"?>
 193         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 194         <mediaid>#{object.id}</mediaid>
 195         <media_id>#{object.id}</media_id>
 196         <media_id_string>#{object.id}</media_id_string>
 197         <media_url>#{href}</media_url>
 198         <mediaurl>#{href}</mediaurl>
 199         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 200         </rsp>
 201         """
 202       "json" ->
 203         %{
 204           media_id: object.id,
 205           media_id_string: "#{object.id}}",
 206           media_url: href,
 207           size: 0
 208         } |> Poison.encode!
 209     end
 210   end
 211
 212   def parse_mentions(text) do
 213     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 214     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 215
 216     Regex.scan(regex, text)
 217     |> List.flatten
 218     |> Enum.uniq
 219     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 220     |> Enum.filter(fn ({_match, user}) -> user end)
 221   end
 222
 223   def add_user_links(text, mentions) do
 224     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 225   end
 226
 227   defp add_conversation_id(activity) do
 228     if is_integer(activity.data["statusnetConversationId"]) do
 229       {:ok, activity}
 230     else
 231       data = activity.data
 232       |> put_in(["object", "statusnetConversationId"], activity.id)
 233       |> put_in(["statusnetConversationId"], activity.id)
 234
 235       object = Object.get_by_ap_id(activity.data["object"]["id"])
 236
 237       changeset = Ecto.Changeset.change(object, data: data["object"])
 238       Repo.update(changeset)
 239
 240       changeset = Ecto.Changeset.change(activity, data: data)
 241       Repo.update(changeset)
 242     end
 243   end
 244
 245   def register_user(params) do
 246     params = %{
 247       nickname: params["nickname"],
 248       name: params["fullname"],
 249       bio: params["bio"],
 250       email: params["email"],
 251       password: params["password"],
 252       password_confirmation: params["confirm"]
 253     }
 254
 255     changeset = User.register_changeset(%User{}, params)
 256
 257     with {:ok, user} <- Repo.insert(changeset) do
 258       {:ok, UserRepresenter.to_map(user)}
 259     else
 260       {:error, changeset} ->
 261         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 262       |> Poison.encode!
 263         {:error, %{error: errors}}
 264     end
 265   end
 266
 267   def get_user(user, params) do
 268     case params do
 269       %{ "user_id" => user_id } ->
 270         case target = Repo.get(User, user_id) do
 271           nil ->
 272             {:error, "No user with such user_id"}
 273           _ ->
 274             {:ok, target}
 275         end
 276       %{ "screen_name" => nickname } ->
 277         case target = Repo.get_by(User, nickname: nickname) do
 278           nil ->
 279             {:error, "No user with such screen_name"}
 280           _ ->
 281             {:ok, target}
 282         end
 283       _ ->
 284         if user do
 285           {:ok, user}
 286         else
 287           {:error, "You need to specify screen_name or user_id"}
 288         end
 289     end
 290   end
 291
 292   defp activities_to_statuses(activities, opts) do
 293     Enum.map(activities, fn(activity) ->
 294       activity_to_status(activity, opts)
 295     end)
 296   end
 297
 298   # For likes, fetch the liked activity, too.
 299   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 300     actor = get_in(activity.data, ["actor"])
 301     user = User.get_cached_by_ap_id(actor)
 302     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 303
 304     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 305   end
 306
 307   # For announces, fetch the announced activity and the user.
 308   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 309     actor = get_in(activity.data, ["actor"])
 310     user = User.get_cached_by_ap_id(actor)
 311     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 312     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 313
 314     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 315   end
 316
 317   defp activity_to_status(activity, opts) do
 318     actor = get_in(activity.data, ["actor"])
 319     user = User.get_cached_by_ap_id(actor)
 320     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 321     mentioned_users = Enum.map(activity.data["to"], fn (ap_id) ->
 322       User.get_cached_by_ap_id(ap_id)
 323     end)
 324     |> Enum.filter(&(&1))
 325
 326     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 327   end
 328
 329   defp make_date do
 330     DateTime.utc_now() |> DateTime.to_iso8601
 331   end
 332 end