git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   3   alias Pleroma.{UserEmail, Mailer}
   4   alias Pleroma.Web.ActivityPub.ActivityPub
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.CommonAPI
   7
   8   import Ecto.Query
   9
  10   def create_status(%User{} = user, %{"status" => _} = data) do
  11     CommonAPI.post(user, data)
  12   end
  13
  14   def delete(%User{} = user, id) do
  15     with %Activity{data: %{"type" => _type}} <- Repo.get(Activity, id),
  16          {:ok, activity} <- CommonAPI.delete(id, user) do
  17       {:ok, activity}
  18     end
  19   end
  20
  21   def follow(%User{} = follower, params) do
  22     with {:ok, %User{} = followed} <- get_user(params),
  23          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  24          {:ok, activity} <- ActivityPub.follow(follower, followed),
  25          {:ok, follower, followed} <-
  26            User.wait_and_refresh(
  27              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  28              follower,
  29              followed
  30            ) do
  31       {:ok, follower, followed, activity}
  32     else
  33       err -> err
  34     end
  35   end
  36
  37   def unfollow(%User{} = follower, params) do
  38     with {:ok, %User{} = unfollowed} <- get_user(params),
  39          {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  40          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  41       {:ok, follower, unfollowed}
  42     else
  43       err -> err
  44     end
  45   end
  46
  47   def block(%User{} = blocker, params) do
  48     with {:ok, %User{} = blocked} <- get_user(params),
  49          {:ok, blocker} <- User.block(blocker, blocked),
  50          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  51       {:ok, blocker, blocked}
  52     else
  53       err -> err
  54     end
  55   end
  56
  57   def unblock(%User{} = blocker, params) do
  58     with {:ok, %User{} = blocked} <- get_user(params),
  59          {:ok, blocker} <- User.unblock(blocker, blocked),
  60          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  61       {:ok, blocker, blocked}
  62     else
  63       err -> err
  64     end
  65   end
  66
  67   def repeat(%User{} = user, ap_id_or_id) do
  68     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  69          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  70       {:ok, activity}
  71     end
  72   end
  73
  74   def unrepeat(%User{} = user, ap_id_or_id) do
  75     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  76          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  77       {:ok, activity}
  78     end
  79   end
  80
  81   def fav(%User{} = user, ap_id_or_id) do
  82     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  83          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  84       {:ok, activity}
  85     end
  86   end
  87
  88   def unfav(%User{} = user, ap_id_or_id) do
  89     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  90          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  91       {:ok, activity}
  92     end
  93   end
  94
  95   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
  96     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
  97
  98     url = List.first(object.data["url"])
  99     href = url["href"]
 100     type = url["mediaType"]
 101
 102     case format do
 103       "xml" ->
 104         # Fake this as good as possible...
 105         """
 106         <?xml version="1.0" encoding="UTF-8"?>
 107         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 108         <mediaid>#{object.id}</mediaid>
 109         <media_id>#{object.id}</media_id>
 110         <media_id_string>#{object.id}</media_id_string>
 111         <media_url>#{href}</media_url>
 112         <mediaurl>#{href}</mediaurl>
 113         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 114         </rsp>
 115         """
 116
 117       "json" ->
 118         %{
 119           media_id: object.id,
 120           media_id_string: "#{object.id}}",
 121           media_url: href,
 122           size: 0
 123         }
 124         |> Jason.encode!()
 125     end
 126   end
 127
 128   def register_user(params) do
 129     tokenString = params["token"]
 130
 131     params = %{
 132       nickname: params["nickname"],
 133       name: params["fullname"],
 134       bio: User.parse_bio(params["bio"]),
 135       email: params["email"],
 136       password: params["password"],
 137       password_confirmation: params["confirm"],
 138       captcha_solution: params["captcha_solution"],
 139       captcha_token: params["captcha_token"]
 140     }
 141
 142     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 143     # true if captcha is disabled or enabled and valid, false otherwise
 144     captcha_ok =
 145       if !captcha_enabled do
 146         true
 147       else
 148         Pleroma.Captcha.validate(params[:captcha_token], params[:captcha_solution])
 149       end
 150
 151     # Captcha invalid
 152     if not captcha_ok do
 153       # I have no idea how this error handling works
 154       {:error, %{error: Jason.encode!(%{captcha: ["Invalid CAPTCHA"]})}}
 155     else
 156       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 157
 158       # no need to query DB if registration is open
 159       token =
 160         unless registrations_open || is_nil(tokenString) do
 161           Repo.get_by(UserInviteToken, %{token: tokenString})
 162         end
 163
 164       cond do
 165         registrations_open || (!is_nil(token) && !token.used) ->
 166           changeset = User.register_changeset(%User{}, params)
 167
 168           with {:ok, user} <- User.register(changeset) do
 169             !registrations_open && UserInviteToken.mark_as_used(token.token)
 170
 171             {:ok, user}
 172           else
 173             {:error, changeset} ->
 174               errors =
 175                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 176                 |> Jason.encode!()
 177
 178               {:error, %{error: errors}}
 179           end
 180
 181         !registrations_open && is_nil(token) ->
 182           {:error, "Invalid token"}
 183
 184         !registrations_open && token.used ->
 185           {:error, "Expired token"}
 186       end
 187     end
 188   end
 189
 190   def password_reset(nickname_or_email) do
 191     with true <- is_binary(nickname_or_email),
 192          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 193          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 194       user
 195       |> UserEmail.password_reset_email(token_record.token)
 196       |> Mailer.deliver()
 197     else
 198       false ->
 199         {:error, "bad user identifier"}
 200
 201       %User{local: false} ->
 202         {:error, "remote user"}
 203
 204       nil ->
 205         {:error, "unknown user"}
 206     end
 207   end
 208
 209   def get_by_id_or_nickname(id_or_nickname) do
 210     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 211       Repo.get_by(User, nickname: id_or_nickname)
 212     else
 213       Repo.get(User, id_or_nickname)
 214     end
 215   end
 216
 217   def get_user(user \\ nil, params) do
 218     case params do
 219       %{"user_id" => user_id} ->
 220         case target = get_by_id_or_nickname(user_id) do
 221           nil ->
 222             {:error, "No user with such user_id"}
 223
 224           _ ->
 225             {:ok, target}
 226         end
 227
 228       %{"screen_name" => nickname} ->
 229         case target = Repo.get_by(User, nickname: nickname) do
 230           nil ->
 231             {:error, "No user with such screen_name"}
 232
 233           _ ->
 234             {:ok, target}
 235         end
 236
 237       _ ->
 238         if user do
 239           {:ok, user}
 240         else
 241           {:error, "You need to specify screen_name or user_id"}
 242         end
 243     end
 244   end
 245
 246   defp parse_int(string, default)
 247
 248   defp parse_int(string, default) when is_binary(string) do
 249     with {n, _} <- Integer.parse(string) do
 250       n
 251     else
 252       _e -> default
 253     end
 254   end
 255
 256   defp parse_int(_, default), do: default
 257
 258   def search(_user, %{"q" => query} = params) do
 259     limit = parse_int(params["rpp"], 20)
 260     page = parse_int(params["page"], 1)
 261     offset = (page - 1) * limit
 262
 263     q =
 264       from(
 265         a in Activity,
 266         where: fragment("?->>'type' = 'Create'", a.data),
 267         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 268         where:
 269           fragment(
 270             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 271             a.data,
 272             ^query
 273           ),
 274         limit: ^limit,
 275         offset: ^offset,
 276         # this one isn't indexed so psql won't take the wrong index.
 277         order_by: [desc: :inserted_at]
 278       )
 279
 280     _activities = Repo.all(q)
 281   end
 282
 283   # DEPRECATED mostly, context objects are now created at insertion time.
 284   def context_to_conversation_id(context) do
 285     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 286       id
 287     else
 288       _e ->
 289         changeset = Object.context_mapping(context)
 290
 291         case Repo.insert(changeset) do
 292           {:ok, %{id: id}} ->
 293             id
 294
 295           # This should be solved by an upsert, but it seems ecto
 296           # has problems accessing the constraint inside the jsonb.
 297           {:error, _} ->
 298             Object.get_cached_by_ap_id(context).id
 299         end
 300     end
 301   end
 302
 303   def conversation_id_to_context(id) do
 304     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 305       context
 306     else
 307       _e ->
 308         {:error, "No such conversation"}
 309     end
 310   end
 311
 312   def get_external_profile(for_user, uri) do
 313     with %User{} = user <- User.get_or_fetch(uri) do
 314       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 315     else
 316       _e ->
 317         {:error, "Couldn't find user"}
 318     end
 319   end
 320 end