git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   5
   6   import Ecto.Query
   7
   8   def create_status(user = %User{}, data = %{}) do
   9     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  10       Repo.get(Object, media_id).data
  11     end)
  12
  13     context = ActivityPub.generate_context_id
  14
  15     content = HtmlSanitizeEx.strip_tags(data["status"])
  16     |> String.replace("\n", "<br>")
  17
  18     mentions = parse_mentions(content)
  19
  20     default_to = [
  21       User.ap_followers(user),
  22       "https://www.w3.org/ns/activitystreams#Public"
  23     ]
  24
  25     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  26
  27     content_html = add_user_links(content, mentions)
  28
  29     date = make_date()
  30
  31     activity = %{
  32       "type" => "Create",
  33       "to" => to,
  34       "actor" => user.ap_id,
  35       "object" => %{
  36         "type" => "Note",
  37         "to" => to,
  38         "content" => content_html,
  39         "published" => date,
  40         "context" => context,
  41         "attachment" => attachments,
  42         "actor" => user.ap_id
  43       },
  44       "published" => date,
  45       "context" => context
  46     }
  47
  48     # Wire up reply info.
  49     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  50                     inReplyTo <- Repo.get(Activity, inReplyToId),
  51                     context <- inReplyTo.data["context"]
  52                do
  53
  54                to = activity["to"] ++ [inReplyTo.data["actor"]]
  55
  56                activity
  57                |> put_in(["to"], to)
  58                |> put_in(["context"], context)
  59                |> put_in(["object", "context"], context)
  60                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  61                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  62                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  63                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  64                else _e ->
  65                  activity
  66                end
  67
  68     with {:ok, activity} <- ActivityPub.insert(activity) do
  69       add_conversation_id(activity)
  70     end
  71   end
  72
  73   def fetch_friend_statuses(user, opts \\ %{}) do
  74     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  75     |> activities_to_statuses(%{for: user})
  76   end
  77
  78   def fetch_public_statuses(user, opts \\ %{}) do
  79     ActivityPub.fetch_public_activities(opts)
  80     |> activities_to_statuses(%{for: user})
  81   end
  82
  83   def fetch_user_statuses(user, opts \\ %{}) do
  84     ActivityPub.fetch_activities([], opts)
  85     |> activities_to_statuses(%{for: user})
  86   end
  87
  88   def fetch_mentions(user, opts \\ %{}) do
  89     ActivityPub.fetch_activities([user.ap_id], opts)
  90     |> activities_to_statuses(%{for: user})
  91   end
  92
  93   def fetch_conversation(user, id) do
  94     query = from activity in Activity,
  95       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
  96       limit: 1
  97
  98     with %Activity{} = activity <- Repo.one(query),
  99          context <- activity.data["context"],
 100          activities <- ActivityPub.fetch_activities_for_context(context),
 101          statuses <- activities |> activities_to_statuses(%{for: user})
 102     do
 103       statuses
 104     else e ->
 105       IO.inspect(e)
 106       []
 107     end
 108   end
 109
 110   def fetch_status(user, id) do
 111     with %Activity{} = activity <- Repo.get(Activity, id) do
 112       activity_to_status(activity, %{for: user})
 113     end
 114   end
 115
 116   def follow(%User{} = follower, params) do
 117     with { :ok, %User{} = followed } <- get_user(params),
 118          { :ok, follower } <- User.follow(follower, followed),
 119          { :ok, activity } <- ActivityPub.insert(%{
 120            "type" => "Follow",
 121            "actor" => follower.ap_id,
 122            "object" => followed.ap_id,
 123            "published" => make_date()
 124          })
 125     do
 126       { :ok, follower, followed, activity }
 127     else
 128       err -> err
 129     end
 130   end
 131
 132 def unfollow(%User{} = follower, params) do
 133     with { :ok, %User{} = unfollowed } <- get_user(params),
 134          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
 135          { :ok, _activity } <- ActivityPub.insert(%{
 136            "type" => "Undo",
 137            "actor" => follower.ap_id,
 138            "object" => follow_activity, # get latest Follow for these users
 139            "published" => make_date()
 140          })
 141     do
 142       { :ok, follower, unfollowed }
 143     else
 144       err -> err
 145     end
 146   end
 147
 148   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 149     object = Object.get_by_ap_id(object["id"])
 150
 151     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 152     new_data = activity.data
 153     |> Map.put("object", object.data)
 154
 155     status = %{activity | data: new_data}
 156     |> activity_to_status(%{for: user})
 157
 158     {:ok, status}
 159   end
 160
 161   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 162     object = Object.get_by_ap_id(object["id"])
 163
 164     {:ok, object} = ActivityPub.unlike(user, object)
 165     new_data = activity.data
 166     |> Map.put("object", object.data)
 167
 168     status = %{activity | data: new_data}
 169     |> activity_to_status(%{for: user})
 170
 171     {:ok, status}
 172   end
 173
 174   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 175     object = Object.get_by_ap_id(object["id"])
 176
 177     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 178     new_data = activity.data
 179     |> Map.put("object", object.data)
 180
 181     status = %{activity | data: new_data}
 182     |> activity_to_status(%{for: user})
 183
 184     {:ok, status}
 185   end
 186
 187   def upload(%Plug.Upload{} = file, format \\ "xml") do
 188     {:ok, object} = ActivityPub.upload(file)
 189
 190     url = List.first(object.data["url"])
 191     href = url["href"]
 192     type = url["mediaType"]
 193
 194     case format do
 195       "xml" ->
 196         # Fake this as good as possible...
 197         """
 198         <?xml version="1.0" encoding="UTF-8"?>
 199         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 200         <mediaid>#{object.id}</mediaid>
 201         <media_id>#{object.id}</media_id>
 202         <media_id_string>#{object.id}</media_id_string>
 203         <media_url>#{href}</media_url>
 204         <mediaurl>#{href}</mediaurl>
 205         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 206         </rsp>
 207         """
 208       "json" ->
 209         %{
 210           media_id: object.id,
 211           media_id_string: "#{object.id}}",
 212           media_url: href,
 213           size: 0
 214         } |> Poison.encode!
 215     end
 216   end
 217
 218   def parse_mentions(text) do
 219     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 220     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 221
 222     Regex.scan(regex, text)
 223     |> List.flatten
 224     |> Enum.uniq
 225     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 226     |> Enum.filter(fn ({_match, user}) -> user end)
 227   end
 228
 229   def add_user_links(text, mentions) do
 230     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 231   end
 232
 233   defp add_conversation_id(activity) do
 234     if is_integer(activity.data["statusnetConversationId"]) do
 235       {:ok, activity}
 236     else
 237       data = activity.data
 238       |> put_in(["object", "statusnetConversationId"], activity.id)
 239       |> put_in(["statusnetConversationId"], activity.id)
 240
 241       object = Object.get_by_ap_id(activity.data["object"]["id"])
 242
 243       changeset = Ecto.Changeset.change(object, data: data["object"])
 244       Repo.update(changeset)
 245
 246       changeset = Ecto.Changeset.change(activity, data: data)
 247       Repo.update(changeset)
 248     end
 249   end
 250
 251   def register_user(params) do
 252     params = %{
 253       nickname: params["nickname"],
 254       name: params["fullname"],
 255       bio: params["bio"],
 256       email: params["email"],
 257       password: params["password"],
 258       password_confirmation: params["confirm"]
 259     }
 260
 261     changeset = User.register_changeset(%User{}, params)
 262
 263     with {:ok, user} <- Repo.insert(changeset) do
 264       {:ok, UserRepresenter.to_map(user)}
 265     else
 266       {:error, changeset} ->
 267         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 268       |> Poison.encode!
 269         {:error, %{error: errors}}
 270     end
 271   end
 272
 273   def get_user(user \\ nil, params) do
 274     case params do
 275       %{ "user_id" => user_id } ->
 276         case target = Repo.get(User, user_id) do
 277           nil ->
 278             {:error, "No user with such user_id"}
 279           _ ->
 280             {:ok, target}
 281         end
 282       %{ "screen_name" => nickname } ->
 283         case target = Repo.get_by(User, nickname: nickname) do
 284           nil ->
 285             {:error, "No user with such screen_name"}
 286           _ ->
 287             {:ok, target}
 288         end
 289       _ ->
 290         if user do
 291           {:ok, user}
 292         else
 293           {:error, "You need to specify screen_name or user_id"}
 294         end
 295     end
 296   end
 297
 298   defp activities_to_statuses(activities, opts) do
 299     Enum.map(activities, fn(activity) ->
 300       activity_to_status(activity, opts)
 301     end)
 302   end
 303
 304   # For likes, fetch the liked activity, too.
 305   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 306     actor = get_in(activity.data, ["actor"])
 307     user = User.get_cached_by_ap_id(actor)
 308     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 309
 310     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 311   end
 312
 313   # For announces, fetch the announced activity and the user.
 314   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 315     actor = get_in(activity.data, ["actor"])
 316     user = User.get_cached_by_ap_id(actor)
 317     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 318     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 319
 320     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 321   end
 322
 323   defp activity_to_status(activity, opts) do
 324     actor = get_in(activity.data, ["actor"])
 325     user = User.get_cached_by_ap_id(actor)
 326     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 327     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 328       User.get_cached_by_ap_id(ap_id)
 329     end)
 330     |> Enum.filter(&(&1))
 331
 332     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 333   end
 334
 335   defp make_date do
 336     DateTime.utc_now() |> DateTime.to_iso8601
 337   end
 338 end