git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5
   6   import Ecto.Query
   7
   8   def create_status(user = %User{}, data = %{}) do
   9     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  10       Repo.get(Object, media_id).data
  11     end)
  12
  13     context = ActivityPub.generate_context_id
  14
  15     content = HtmlSanitizeEx.strip_tags(data["status"])
  16
  17     mentions = parse_mentions(content)
  18
  19     default_to = [
  20       User.ap_followers(user),
  21       "https://www.w3.org/ns/activitystreams#Public"
  22     ]
  23
  24     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  25
  26     content_html = add_user_links(content, mentions)
  27
  28     date = make_date()
  29
  30     activity = %{
  31       "type" => "Create",
  32       "to" => to,
  33       "actor" => user.ap_id,
  34       "object" => %{
  35         "type" => "Note",
  36         "to" => to,
  37         "content" => content_html,
  38         "published" => date,
  39         "context" => context,
  40         "attachment" => attachments
  41       },
  42       "published" => date,
  43       "context" => context
  44     }
  45
  46     # Wire up reply info.
  47     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  48                     inReplyTo <- Repo.get(Activity, inReplyToId),
  49                     context <- inReplyTo.data["context"]
  50                do
  51
  52                to = activity["to"] ++ [inReplyTo.data["actor"]]
  53
  54                activity
  55                |> put_in(["to"], to)
  56                |> put_in(["context"], context)
  57                |> put_in(["object", "context"], context)
  58                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  59                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  60                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  61                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  62                else _e ->
  63                  activity
  64                end
  65
  66     with {:ok, activity} <- ActivityPub.insert(activity) do
  67       add_conversation_id(activity)
  68     end
  69   end
  70
  71   def fetch_friend_statuses(user, opts \\ %{}) do
  72     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  73     |> activities_to_statuses(%{for: user})
  74   end
  75
  76   def fetch_public_statuses(user, opts \\ %{}) do
  77     ActivityPub.fetch_public_activities(opts)
  78     |> activities_to_statuses(%{for: user})
  79   end
  80
  81   def fetch_user_statuses(user, opts \\ %{}) do
  82     target = get_user(user, opts)
  83     ActivityPub.fetch_activities([], Map.merge(opts, %{"actor_id" => target.ap_id}))
  84     |> activities_to_statuses(%{for: user})
  85   end
  86
  87   def fetch_conversation(user, id) do
  88     query = from activity in Activity,
  89       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
  90       limit: 1
  91
  92     with %Activity{} = activity <- Repo.one(query),
  93          context <- activity.data["context"],
  94          activities <- ActivityPub.fetch_activities_for_context(context),
  95          statuses <- activities |> activities_to_statuses(%{for: user})
  96     do
  97       statuses
  98     else e ->
  99       IO.inspect(e)
 100       []
 101     end
 102   end
 103
 104   def fetch_status(user, id) do
 105     with %Activity{} = activity <- Repo.get(Activity, id) do
 106       activity_to_status(activity, %{for: user})
 107     end
 108   end
 109
 110   def follow(%User{} = follower, followed_id) do
 111     with %User{} = followed <- Repo.get(User, followed_id),
 112          { :ok, follower } <- User.follow(follower, followed),
 113          { :ok, activity } <- ActivityPub.insert(%{
 114            "type" => "Follow",
 115            "actor" => follower.ap_id,
 116            "object" => followed.ap_id,
 117            "published" => make_date()
 118          })
 119     do
 120       { :ok, follower, followed, activity }
 121     end
 122   end
 123
 124   def unfollow(%User{} = follower, followed_id) do
 125     with %User{} = followed <- Repo.get(User, followed_id),
 126          { :ok, follower } <- User.unfollow(follower, followed)
 127     do
 128       { :ok, follower, followed }
 129     end
 130   end
 131
 132   def upload(%Plug.Upload{} = file) do
 133     {:ok, object} = ActivityPub.upload(file)
 134
 135     url = List.first(object.data["url"])
 136     href = url["href"]
 137     type = url["mediaType"]
 138
 139     # Fake this as good as possible...
 140     """
 141     <?xml version="1.0" encoding="UTF-8"?>
 142     <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 143       <mediaid>#{object.id}</mediaid>
 144       <media_id>#{object.id}</media_id>
 145       <media_id_string>#{object.id}</media_id_string>
 146       <media_url>#{href}</media_url>
 147       <mediaurl>#{href}</mediaurl>
 148       <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 149     </rsp>
 150     """
 151   end
 152
 153   def parse_mentions(text) do
 154     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 155     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 156
 157     Regex.scan(regex, text)
 158     |> List.flatten
 159     |> Enum.uniq
 160     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, Repo.get_by(User, nickname: match)} end)
 161     |> Enum.filter(fn ({_match, user}) -> user end)
 162   end
 163
 164   def add_user_links(text, mentions) do
 165     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 166   end
 167
 168   defp add_conversation_id(activity) do
 169     if is_integer(activity.data["statusnetConversationId"]) do
 170       {:ok, activity}
 171     else
 172       data = activity.data
 173       |> put_in(["object", "statusnetConversationId"], activity.id)
 174       |> put_in(["statusnetConversationId"], activity.id)
 175
 176       changeset = Ecto.Changeset.change(activity, data: data)
 177       Repo.update(changeset)
 178     end
 179   end
 180
 181   defp activities_to_statuses(activities, opts) do
 182     Enum.map(activities, fn(activity) ->
 183       activity_to_status(activity, opts)
 184     end)
 185   end
 186
 187   defp activity_to_status(activity, opts) do
 188     actor = get_in(activity.data, ["actor"])
 189     user = Repo.get_by!(User, ap_id: actor)
 190     mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 191     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 192   end
 193
 194   defp make_date do
 195     DateTime.utc_now() |> DateTime.to_iso8601
 196   end
 197
 198   defp get_user(user, params) do
 199     case params do
 200       %{ "user_id" => user_id } ->
 201         Repo.get(User, user_id)
 202       %{ "screen_name" => nickname } ->
 203         Repo.get_by!(User, nickname: nickname)
 204       _ ->
 205         user
 206     end
 207   end
 208 end