git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   alias Pleroma.UserInviteToken
   7   alias Pleroma.User
   8   alias Pleroma.Activity
   9   alias Pleroma.Repo
  10   alias Pleroma.Object
  11   alias Pleroma.UserEmail
  12   alias Pleroma.Mailer
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.TwitterAPI.UserView
  15   alias Pleroma.Web.CommonAPI
  16
  17   import Ecto.Query
  18
  19   def create_status(%User{} = user, %{"status" => _} = data) do
  20     CommonAPI.post(user, data)
  21   end
  22
  23   def delete(%User{} = user, id) do
  24     with %Activity{data: %{"type" => _type}} <- Repo.get(Activity, id),
  25          {:ok, activity} <- CommonAPI.delete(id, user) do
  26       {:ok, activity}
  27     end
  28   end
  29
  30   def follow(%User{} = follower, params) do
  31     with {:ok, %User{} = followed} <- get_user(params) do
  32       CommonAPI.follow(follower, followed)
  33     end
  34   end
  35
  36   def unfollow(%User{} = follower, params) do
  37     with {:ok, %User{} = unfollowed} <- get_user(params),
  38          {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  39          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  40       {:ok, follower, unfollowed}
  41     else
  42       err -> err
  43     end
  44   end
  45
  46   def block(%User{} = blocker, params) do
  47     with {:ok, %User{} = blocked} <- get_user(params),
  48          {:ok, blocker} <- User.block(blocker, blocked),
  49          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  50       {:ok, blocker, blocked}
  51     else
  52       err -> err
  53     end
  54   end
  55
  56   def unblock(%User{} = blocker, params) do
  57     with {:ok, %User{} = blocked} <- get_user(params),
  58          {:ok, blocker} <- User.unblock(blocker, blocked),
  59          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  60       {:ok, blocker, blocked}
  61     else
  62       err -> err
  63     end
  64   end
  65
  66   def repeat(%User{} = user, ap_id_or_id) do
  67     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  68          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  69       {:ok, activity}
  70     end
  71   end
  72
  73   def unrepeat(%User{} = user, ap_id_or_id) do
  74     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  75          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  76       {:ok, activity}
  77     end
  78   end
  79
  80   def pin(%User{} = user, ap_id_or_id) do
  81     CommonAPI.pin(ap_id_or_id, user)
  82   end
  83
  84   def unpin(%User{} = user, ap_id_or_id) do
  85     CommonAPI.unpin(ap_id_or_id, user)
  86   end
  87
  88   def fav(%User{} = user, ap_id_or_id) do
  89     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  90          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  91       {:ok, activity}
  92     end
  93   end
  94
  95   def unfav(%User{} = user, ap_id_or_id) do
  96     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  97          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  98       {:ok, activity}
  99     end
 100   end
 101
 102   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
 103     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
 104
 105     url = List.first(object.data["url"])
 106     href = url["href"]
 107     type = url["mediaType"]
 108
 109     case format do
 110       "xml" ->
 111         # Fake this as good as possible...
 112         """
 113         <?xml version="1.0" encoding="UTF-8"?>
 114         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 115         <mediaid>#{object.id}</mediaid>
 116         <media_id>#{object.id}</media_id>
 117         <media_id_string>#{object.id}</media_id_string>
 118         <media_url>#{href}</media_url>
 119         <mediaurl>#{href}</mediaurl>
 120         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 121         </rsp>
 122         """
 123
 124       "json" ->
 125         %{
 126           media_id: object.id,
 127           media_id_string: "#{object.id}}",
 128           media_url: href,
 129           size: 0
 130         }
 131         |> Jason.encode!()
 132     end
 133   end
 134
 135   def register_user(params) do
 136     tokenString = params["token"]
 137
 138     params = %{
 139       nickname: params["nickname"],
 140       name: params["fullname"],
 141       bio: User.parse_bio(params["bio"]),
 142       email: params["email"],
 143       password: params["password"],
 144       password_confirmation: params["confirm"],
 145       captcha_solution: params["captcha_solution"],
 146       captcha_token: params["captcha_token"],
 147       captcha_answer_data: params["captcha_answer_data"]
 148     }
 149
 150     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 151     # true if captcha is disabled or enabled and valid, false otherwise
 152     captcha_ok =
 153       if !captcha_enabled do
 154         :ok
 155       else
 156         Pleroma.Captcha.validate(
 157           params[:captcha_token],
 158           params[:captcha_solution],
 159           params[:captcha_answer_data]
 160         )
 161       end
 162
 163     # Captcha invalid
 164     if captcha_ok != :ok do
 165       {:error, error} = captcha_ok
 166       # I have no idea how this error handling works
 167       {:error, %{error: Jason.encode!(%{captcha: [error]})}}
 168     else
 169       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 170
 171       # no need to query DB if registration is open
 172       token =
 173         unless registrations_open || is_nil(tokenString) do
 174           Repo.get_by(UserInviteToken, %{token: tokenString})
 175         end
 176
 177       cond do
 178         registrations_open || (!is_nil(token) && !token.used) ->
 179           changeset = User.register_changeset(%User{}, params)
 180
 181           with {:ok, user} <- User.register(changeset) do
 182             !registrations_open && UserInviteToken.mark_as_used(token.token)
 183
 184             {:ok, user}
 185           else
 186             {:error, changeset} ->
 187               errors =
 188                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 189                 |> Jason.encode!()
 190
 191               {:error, %{error: errors}}
 192           end
 193
 194         !registrations_open && is_nil(token) ->
 195           {:error, "Invalid token"}
 196
 197         !registrations_open && token.used ->
 198           {:error, "Expired token"}
 199       end
 200     end
 201   end
 202
 203   def password_reset(nickname_or_email) do
 204     with true <- is_binary(nickname_or_email),
 205          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 206          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 207       user
 208       |> UserEmail.password_reset_email(token_record.token)
 209       |> Mailer.deliver_async()
 210     else
 211       false ->
 212         {:error, "bad user identifier"}
 213
 214       %User{local: false} ->
 215         {:error, "remote user"}
 216
 217       nil ->
 218         {:error, "unknown user"}
 219     end
 220   end
 221
 222   def get_user(user \\ nil, params) do
 223     case params do
 224       %{"user_id" => user_id} ->
 225         case target = User.get_cached_by_nickname_or_id(user_id) do
 226           nil ->
 227             {:error, "No user with such user_id"}
 228
 229           _ ->
 230             {:ok, target}
 231         end
 232
 233       %{"screen_name" => nickname} ->
 234         case target = Repo.get_by(User, nickname: nickname) do
 235           nil ->
 236             {:error, "No user with such screen_name"}
 237
 238           _ ->
 239             {:ok, target}
 240         end
 241
 242       _ ->
 243         if user do
 244           {:ok, user}
 245         else
 246           {:error, "You need to specify screen_name or user_id"}
 247         end
 248     end
 249   end
 250
 251   defp parse_int(string, default)
 252
 253   defp parse_int(string, default) when is_binary(string) do
 254     with {n, _} <- Integer.parse(string) do
 255       n
 256     else
 257       _e -> default
 258     end
 259   end
 260
 261   defp parse_int(_, default), do: default
 262
 263   def search(_user, %{"q" => query} = params) do
 264     limit = parse_int(params["rpp"], 20)
 265     page = parse_int(params["page"], 1)
 266     offset = (page - 1) * limit
 267
 268     q =
 269       from(
 270         a in Activity,
 271         where: fragment("?->>'type' = 'Create'", a.data),
 272         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 273         where:
 274           fragment(
 275             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 276             a.data,
 277             ^query
 278           ),
 279         limit: ^limit,
 280         offset: ^offset,
 281         # this one isn't indexed so psql won't take the wrong index.
 282         order_by: [desc: :inserted_at]
 283       )
 284
 285     _activities = Repo.all(q)
 286   end
 287
 288   # DEPRECATED mostly, context objects are now created at insertion time.
 289   def context_to_conversation_id(context) do
 290     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 291       id
 292     else
 293       _e ->
 294         changeset = Object.context_mapping(context)
 295
 296         case Repo.insert(changeset) do
 297           {:ok, %{id: id}} ->
 298             id
 299
 300           # This should be solved by an upsert, but it seems ecto
 301           # has problems accessing the constraint inside the jsonb.
 302           {:error, _} ->
 303             Object.get_cached_by_ap_id(context).id
 304         end
 305     end
 306   end
 307
 308   def conversation_id_to_context(id) do
 309     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 310       context
 311     else
 312       _e ->
 313         {:error, "No such conversation"}
 314     end
 315   end
 316
 317   def get_external_profile(for_user, uri) do
 318     with %User{} = user <- User.get_or_fetch(uri) do
 319       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 320     else
 321       _e ->
 322         {:error, "Couldn't find user"}
 323     end
 324   end
 325 end