git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   6   alias Pleroma.Web.OStatus
   7   alias Pleroma.Formatter
   8
   9   import Ecto.Query
  10   import Pleroma.Web.TwitterAPI.Utils
  11
  12   def to_for_user_and_mentions(user, mentions, inReplyTo) do
  13     default_to = [
  14       User.ap_followers(user),
  15       "https://www.w3.org/ns/activitystreams#Public"
  16     ]
  17
  18     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  19     if inReplyTo do
  20       Enum.uniq([inReplyTo.data["actor"] | to])
  21     else
  22       to
  23     end
  24   end
  25
  26   def get_replied_to_activity(id) when not is_nil(id) do
  27     Repo.get(Activity, id)
  28   end
  29
  30   def get_replied_to_activity(_), do: nil
  31
  32   def create_status(%User{} = user, %{"status" => status} = data) do
  33     with attachments <- attachments_from_ids(data["media_ids"]),
  34          mentions <- parse_mentions(status),
  35          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  36          to <- to_for_user_and_mentions(user, mentions, inReplyTo),
  37          content_html <- make_content_html(status, mentions, attachments),
  38          context <- make_context(inReplyTo),
  39          tags <- Formatter.parse_tags(status),
  40          object <- make_note_data(user.ap_id, to, context, content_html, attachments, inReplyTo, tags) do
  41       ActivityPub.create(to, user, context, object)
  42     end
  43   end
  44
  45   def fetch_friend_statuses(user, opts \\ %{}) do
  46     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  47     |> activities_to_statuses(%{for: user})
  48   end
  49
  50   def fetch_public_statuses(user, opts \\ %{}) do
  51     opts = Map.put(opts, "local_only", true)
  52     ActivityPub.fetch_public_activities(opts)
  53     |> activities_to_statuses(%{for: user})
  54   end
  55
  56   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  57     ActivityPub.fetch_public_activities(opts)
  58     |> activities_to_statuses(%{for: user})
  59   end
  60
  61   def fetch_user_statuses(user, opts \\ %{}) do
  62     ActivityPub.fetch_activities([], opts)
  63     |> activities_to_statuses(%{for: user})
  64   end
  65
  66   def fetch_mentions(user, opts \\ %{}) do
  67     ActivityPub.fetch_activities([user.ap_id], opts)
  68     |> activities_to_statuses(%{for: user})
  69   end
  70
  71   def fetch_conversation(user, id) do
  72     with context when is_binary(context) <- conversation_id_to_context(id),
  73          activities <- ActivityPub.fetch_activities_for_context(context),
  74          statuses <- activities |> activities_to_statuses(%{for: user})
  75     do
  76       statuses
  77     else _e ->
  78       []
  79     end
  80   end
  81
  82   def fetch_status(user, id) do
  83     with %Activity{} = activity <- Repo.get(Activity, id) do
  84       activity_to_status(activity, %{for: user})
  85     end
  86   end
  87
  88   def follow(%User{} = follower, params) do
  89     with {:ok, %User{} = followed} <- get_user(params),
  90          {:ok, follower} <- User.follow(follower, followed),
  91          {:ok, activity} <- ActivityPub.follow(follower, followed)
  92     do
  93       {:ok, follower, followed, activity}
  94     else
  95       err -> err
  96     end
  97   end
  98
  99   def unfollow(%User{} = follower, params) do
 100     with { :ok, %User{} = unfollowed } <- get_user(params),
 101          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
 102          { :ok, _activity } <- ActivityPub.insert(%{
 103            "type" => "Undo",
 104            "actor" => follower.ap_id,
 105            "object" => follow_activity.data["id"], # get latest Follow for these users
 106            "published" => make_date()
 107          })
 108     do
 109       { :ok, follower, unfollowed }
 110     else
 111       err -> err
 112     end
 113   end
 114
 115   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 116     object = Object.get_by_ap_id(object["id"])
 117
 118     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 119     new_data = activity.data
 120     |> Map.put("object", object.data)
 121
 122     status = %{activity | data: new_data}
 123     |> activity_to_status(%{for: user})
 124
 125     {:ok, status}
 126   end
 127
 128   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 129     object = Object.get_by_ap_id(object["id"])
 130
 131     {:ok, object} = ActivityPub.unlike(user, object)
 132     new_data = activity.data
 133     |> Map.put("object", object.data)
 134
 135     status = %{activity | data: new_data}
 136     |> activity_to_status(%{for: user})
 137
 138     {:ok, status}
 139   end
 140
 141   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 142     object = Object.get_by_ap_id(object["id"])
 143
 144     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 145     new_data = activity.data
 146     |> Map.put("object", object.data)
 147
 148     status = %{activity | data: new_data}
 149     |> activity_to_status(%{for: user})
 150
 151     {:ok, status}
 152   end
 153
 154   def upload(%Plug.Upload{} = file, format \\ "xml") do
 155     {:ok, object} = ActivityPub.upload(file)
 156
 157     url = List.first(object.data["url"])
 158     href = url["href"]
 159     type = url["mediaType"]
 160
 161     case format do
 162       "xml" ->
 163         # Fake this as good as possible...
 164         """
 165         <?xml version="1.0" encoding="UTF-8"?>
 166         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 167         <mediaid>#{object.id}</mediaid>
 168         <media_id>#{object.id}</media_id>
 169         <media_id_string>#{object.id}</media_id_string>
 170         <media_url>#{href}</media_url>
 171         <mediaurl>#{href}</mediaurl>
 172         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 173         </rsp>
 174         """
 175       "json" ->
 176         %{
 177           media_id: object.id,
 178           media_id_string: "#{object.id}}",
 179           media_url: href,
 180           size: 0
 181         } |> Poison.encode!
 182     end
 183   end
 184
 185   def parse_mentions(text) do
 186     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 187     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 188
 189     Regex.scan(regex, text)
 190     |> List.flatten
 191     |> Enum.uniq
 192     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 193     |> Enum.filter(fn ({_match, user}) -> user end)
 194   end
 195
 196   def register_user(params) do
 197     params = %{
 198       nickname: params["nickname"],
 199       name: params["fullname"],
 200       bio: params["bio"],
 201       email: params["email"],
 202       password: params["password"],
 203       password_confirmation: params["confirm"]
 204     }
 205
 206     changeset = User.register_changeset(%User{}, params)
 207
 208     with {:ok, user} <- Repo.insert(changeset) do
 209       {:ok, UserRepresenter.to_map(user)}
 210     else
 211       {:error, changeset} ->
 212         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 213       |> Poison.encode!
 214       {:error, %{error: errors}}
 215     end
 216   end
 217
 218   def get_user(user \\ nil, params) do
 219     case params do
 220       %{"user_id" => user_id} ->
 221         case target = Repo.get(User, user_id) do
 222           nil ->
 223             {:error, "No user with such user_id"}
 224           _ ->
 225             {:ok, target}
 226         end
 227       %{"screen_name" => nickname} ->
 228         case target = Repo.get_by(User, nickname: nickname) do
 229           nil ->
 230             {:error, "No user with such screen_name"}
 231           _ ->
 232             {:ok, target}
 233         end
 234       _ ->
 235         if user do
 236           {:ok, user}
 237         else
 238           {:error, "You need to specify screen_name or user_id"}
 239         end
 240     end
 241   end
 242
 243   defp activities_to_statuses(activities, opts) do
 244     Enum.map(activities, fn(activity) ->
 245       activity_to_status(activity, opts)
 246     end)
 247   end
 248
 249   # For likes, fetch the liked activity, too.
 250   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 251     actor = get_in(activity.data, ["actor"])
 252     user = User.get_cached_by_ap_id(actor)
 253     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 254
 255     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 256   end
 257
 258   # For announces, fetch the announced activity and the user.
 259   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 260     actor = get_in(activity.data, ["actor"])
 261     user = User.get_cached_by_ap_id(actor)
 262     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 263     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 264
 265     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 266   end
 267
 268   defp activity_to_status(activity, opts) do
 269     actor = get_in(activity.data, ["actor"])
 270     user = User.get_cached_by_ap_id(actor)
 271     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 272     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 273       User.get_cached_by_ap_id(ap_id)
 274     end)
 275     |> Enum.filter(&(&1))
 276
 277     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 278   end
 279
 280   defp make_date do
 281     DateTime.utc_now() |> DateTime.to_iso8601
 282   end
 283
 284   def context_to_conversation_id(context) do
 285     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 286       id
 287     else _e ->
 288       changeset = Object.context_mapping(context)
 289       {:ok, %{id: id}} = Repo.insert(changeset)
 290       id
 291     end
 292   end
 293
 294   def conversation_id_to_context(id) do
 295     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 296       context
 297     else _e ->
 298       {:error, "No such conversation"}
 299     end
 300   end
 301
 302   def get_external_profile(for_user, uri) do
 303     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 304       {:ok, UserRepresenter.to_map(user, %{for: for_user})}
 305     else _e ->
 306         {:error, "Couldn't find user"}
 307     end
 308   end
 309 end