git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{UserInviteToken, User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.CommonAPI
   6   import Ecto.Query
   7
   8   def create_status(%User{} = user, %{"status" => _} = data) do
   9     CommonAPI.post(user, data)
  10   end
  11
  12   def delete(%User{} = user, id) do
  13     with %Activity{data: %{"type" => _type}} <- Repo.get(Activity, id),
  14          {:ok, activity} <- CommonAPI.delete(id, user) do
  15       {:ok, activity}
  16     end
  17   end
  18
  19   def follow(%User{} = follower, params) do
  20     with {:ok, %User{} = followed} <- get_user(params),
  21          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  22          {:ok, activity} <- ActivityPub.follow(follower, followed),
  23          {:ok, follower, followed} <-
  24            User.wait_and_refresh(
  25              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  26              follower,
  27              followed
  28            ) do
  29       {:ok, follower, followed, activity}
  30     else
  31       err -> err
  32     end
  33   end
  34
  35   def unfollow(%User{} = follower, params) do
  36     with {:ok, %User{} = unfollowed} <- get_user(params),
  37          {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  38          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  39       {:ok, follower, unfollowed}
  40     else
  41       err -> err
  42     end
  43   end
  44
  45   def block(%User{} = blocker, params) do
  46     with {:ok, %User{} = blocked} <- get_user(params),
  47          {:ok, blocker} <- User.block(blocker, blocked),
  48          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  49       {:ok, blocker, blocked}
  50     else
  51       err -> err
  52     end
  53   end
  54
  55   def unblock(%User{} = blocker, params) do
  56     with {:ok, %User{} = blocked} <- get_user(params),
  57          {:ok, blocker} <- User.unblock(blocker, blocked),
  58          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  59       {:ok, blocker, blocked}
  60     else
  61       err -> err
  62     end
  63   end
  64
  65   def repeat(%User{} = user, ap_id_or_id) do
  66     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  67          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  68       {:ok, activity}
  69     end
  70   end
  71
  72   def unrepeat(%User{} = user, ap_id_or_id) do
  73     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  74          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  75       {:ok, activity}
  76     end
  77   end
  78
  79   def fav(%User{} = user, ap_id_or_id) do
  80     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  81          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  82       {:ok, activity}
  83     end
  84   end
  85
  86   def unfav(%User{} = user, ap_id_or_id) do
  87     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  88          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  89       {:ok, activity}
  90     end
  91   end
  92
  93   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
  94     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
  95
  96     url = List.first(object.data["url"])
  97     href = url["href"]
  98     type = url["mediaType"]
  99
 100     case format do
 101       "xml" ->
 102         # Fake this as good as possible...
 103         """
 104         <?xml version="1.0" encoding="UTF-8"?>
 105         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 106         <mediaid>#{object.id}</mediaid>
 107         <media_id>#{object.id}</media_id>
 108         <media_id_string>#{object.id}</media_id_string>
 109         <media_url>#{href}</media_url>
 110         <mediaurl>#{href}</mediaurl>
 111         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 112         </rsp>
 113         """
 114
 115       "json" ->
 116         %{
 117           media_id: object.id,
 118           media_id_string: "#{object.id}}",
 119           media_url: href,
 120           size: 0
 121         }
 122         |> Jason.encode!()
 123     end
 124   end
 125
 126   def register_user(params) do
 127     tokenString = params["token"]
 128
 129     params = %{
 130       nickname: params["nickname"],
 131       name: params["fullname"],
 132       bio: User.parse_bio(params["bio"]),
 133       email: params["email"],
 134       password: params["password"],
 135       password_confirmation: params["confirm"]
 136     }
 137
 138     registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 139
 140     # no need to query DB if registration is open
 141     token =
 142       unless registrations_open || is_nil(tokenString) do
 143         Repo.get_by(UserInviteToken, %{token: tokenString})
 144       end
 145
 146     cond do
 147       registrations_open || (!is_nil(token) && !token.used) ->
 148         changeset = User.register_changeset(%User{info: %{}}, params)
 149
 150         with {:ok, user} <- Repo.insert(changeset) do
 151           !registrations_open && UserInviteToken.mark_as_used(token.token)
 152           {:ok, user}
 153         else
 154           {:error, changeset} ->
 155             errors =
 156               Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 157               |> Jason.encode!()
 158
 159             {:error, %{error: errors}}
 160         end
 161
 162       !registrations_open && is_nil(token) ->
 163         {:error, "Invalid token"}
 164
 165       !registrations_open && token.used ->
 166         {:error, "Expired token"}
 167     end
 168   end
 169
 170   def get_by_id_or_nickname(id_or_nickname) do
 171     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 172       Repo.get_by(User, nickname: id_or_nickname)
 173     else
 174       Repo.get(User, id_or_nickname)
 175     end
 176   end
 177
 178   def get_user(user \\ nil, params) do
 179     case params do
 180       %{"user_id" => user_id} ->
 181         case target = get_by_id_or_nickname(user_id) do
 182           nil ->
 183             {:error, "No user with such user_id"}
 184
 185           _ ->
 186             {:ok, target}
 187         end
 188
 189       %{"screen_name" => nickname} ->
 190         case target = Repo.get_by(User, nickname: nickname) do
 191           nil ->
 192             {:error, "No user with such screen_name"}
 193
 194           _ ->
 195             {:ok, target}
 196         end
 197
 198       _ ->
 199         if user do
 200           {:ok, user}
 201         else
 202           {:error, "You need to specify screen_name or user_id"}
 203         end
 204     end
 205   end
 206
 207   defp parse_int(string, default)
 208
 209   defp parse_int(string, default) when is_binary(string) do
 210     with {n, _} <- Integer.parse(string) do
 211       n
 212     else
 213       _e -> default
 214     end
 215   end
 216
 217   defp parse_int(_, default), do: default
 218
 219   def search(_user, %{"q" => query} = params) do
 220     limit = parse_int(params["rpp"], 20)
 221     page = parse_int(params["page"], 1)
 222     offset = (page - 1) * limit
 223
 224     q =
 225       from(
 226         a in Activity,
 227         where: fragment("?->>'type' = 'Create'", a.data),
 228         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 229         where:
 230           fragment(
 231             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 232             a.data,
 233             ^query
 234           ),
 235         limit: ^limit,
 236         offset: ^offset,
 237         # this one isn't indexed so psql won't take the wrong index.
 238         order_by: [desc: :inserted_at]
 239       )
 240
 241     _activities = Repo.all(q)
 242   end
 243
 244   # DEPRECATED mostly, context objects are now created at insertion time.
 245   def context_to_conversation_id(context) do
 246     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 247       id
 248     else
 249       _e ->
 250         changeset = Object.context_mapping(context)
 251
 252         case Repo.insert(changeset) do
 253           {:ok, %{id: id}} ->
 254             id
 255
 256           # This should be solved by an upsert, but it seems ecto
 257           # has problems accessing the constraint inside the jsonb.
 258           {:error, _} ->
 259             Object.get_cached_by_ap_id(context).id
 260         end
 261     end
 262   end
 263
 264   def conversation_id_to_context(id) do
 265     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 266       context
 267     else
 268       _e ->
 269         {:error, "No such conversation"}
 270     end
 271   end
 272
 273   def get_external_profile(for_user, uri) do
 274     with %User{} = user <- User.get_or_fetch(uri) do
 275       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 276     else
 277       _e ->
 278         {:error, "Couldn't find user"}
 279     end
 280   end
 281 end