git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   6   alias Pleroma.Activity
   7   alias Pleroma.Mailer
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.UserEmail
  11   alias Pleroma.UserInviteToken
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.TwitterAPI.UserView
  15
  16   import Ecto.Query
  17
  18   def create_status(%User{} = user, %{"status" => _} = data) do
  19     CommonAPI.post(user, data)
  20   end
  21
  22   def delete(%User{} = user, id) do
  23     with %Activity{data: %{"type" => _type}} <- Activity.get_by_id(id),
  24          {:ok, activity} <- CommonAPI.delete(id, user) do
  25       {:ok, activity}
  26     end
  27   end
  28
  29   def follow(%User{} = follower, params) do
  30     with {:ok, %User{} = followed} <- get_user(params) do
  31       CommonAPI.follow(follower, followed)
  32     end
  33   end
  34
  35   def unfollow(%User{} = follower, params) do
  36     with {:ok, %User{} = unfollowed} <- get_user(params),
  37          {:ok, follower} <- CommonAPI.unfollow(follower, unfollowed) do
  38       {:ok, follower, unfollowed}
  39     end
  40   end
  41
  42   def block(%User{} = blocker, params) do
  43     with {:ok, %User{} = blocked} <- get_user(params),
  44          {:ok, blocker} <- User.block(blocker, blocked),
  45          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  46       {:ok, blocker, blocked}
  47     else
  48       err -> err
  49     end
  50   end
  51
  52   def unblock(%User{} = blocker, params) do
  53     with {:ok, %User{} = blocked} <- get_user(params),
  54          {:ok, blocker} <- User.unblock(blocker, blocked),
  55          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  56       {:ok, blocker, blocked}
  57     else
  58       err -> err
  59     end
  60   end
  61
  62   def subscribe(%User{} = subscriber, params) do
  63     with {:ok, %User{} = subscribed} <- get_user(params) do
  64       User.subscribe(subscriber, subscribed)
  65       |> IO.inspect
  66     end
  67   end
  68
  69   def unsubscribe(%User{} = unsubscriber, params) do
  70     with {:ok, %User{} = unsubscribed} <- get_user(params) do
  71       User.unsubscribe(unsubscriber, unsubscribed)
  72     end
  73   end
  74
  75   def repeat(%User{} = user, ap_id_or_id) do
  76     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  77          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  78       {:ok, activity}
  79     end
  80   end
  81
  82   def unrepeat(%User{} = user, ap_id_or_id) do
  83     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  84          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
  85       {:ok, activity}
  86     end
  87   end
  88
  89   def pin(%User{} = user, ap_id_or_id) do
  90     CommonAPI.pin(ap_id_or_id, user)
  91   end
  92
  93   def unpin(%User{} = user, ap_id_or_id) do
  94     CommonAPI.unpin(ap_id_or_id, user)
  95   end
  96
  97   def fav(%User{} = user, ap_id_or_id) do
  98     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  99          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
 100       {:ok, activity}
 101     end
 102   end
 103
 104   def unfav(%User{} = user, ap_id_or_id) do
 105     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
 106          %Activity{} = activity <- Activity.get_create_by_object_ap_id(id) do
 107       {:ok, activity}
 108     end
 109   end
 110
 111   def upload(%Plug.Upload{} = file, %User{} = user, format \\ "xml") do
 112     {:ok, object} = ActivityPub.upload(file, actor: User.ap_id(user))
 113
 114     url = List.first(object.data["url"])
 115     href = url["href"]
 116     type = url["mediaType"]
 117
 118     case format do
 119       "xml" ->
 120         # Fake this as good as possible...
 121         """
 122         <?xml version="1.0" encoding="UTF-8"?>
 123         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 124         <mediaid>#{object.id}</mediaid>
 125         <media_id>#{object.id}</media_id>
 126         <media_id_string>#{object.id}</media_id_string>
 127         <media_url>#{href}</media_url>
 128         <mediaurl>#{href}</mediaurl>
 129         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 130         </rsp>
 131         """
 132
 133       "json" ->
 134         %{
 135           media_id: object.id,
 136           media_id_string: "#{object.id}}",
 137           media_url: href,
 138           size: 0
 139         }
 140         |> Jason.encode!()
 141     end
 142   end
 143
 144   def register_user(params) do
 145     token_string = params["token"]
 146
 147     params = %{
 148       nickname: params["nickname"],
 149       name: params["fullname"],
 150       bio: User.parse_bio(params["bio"]),
 151       email: params["email"],
 152       password: params["password"],
 153       password_confirmation: params["confirm"],
 154       captcha_solution: params["captcha_solution"],
 155       captcha_token: params["captcha_token"],
 156       captcha_answer_data: params["captcha_answer_data"]
 157     }
 158
 159     captcha_enabled = Pleroma.Config.get([Pleroma.Captcha, :enabled])
 160     # true if captcha is disabled or enabled and valid, false otherwise
 161     captcha_ok =
 162       if !captcha_enabled do
 163         :ok
 164       else
 165         Pleroma.Captcha.validate(
 166           params[:captcha_token],
 167           params[:captcha_solution],
 168           params[:captcha_answer_data]
 169         )
 170       end
 171
 172     # Captcha invalid
 173     if captcha_ok != :ok do
 174       {:error, error} = captcha_ok
 175       # I have no idea how this error handling works
 176       {:error, %{error: Jason.encode!(%{captcha: [error]})}}
 177     else
 178       registrations_open = Pleroma.Config.get([:instance, :registrations_open])
 179
 180       # no need to query DB if registration is open
 181       token =
 182         unless registrations_open || is_nil(token_string) do
 183           Repo.get_by(UserInviteToken, %{token: token_string})
 184         end
 185
 186       cond do
 187         registrations_open || (!is_nil(token) && !token.used) ->
 188           changeset = User.register_changeset(%User{}, params)
 189
 190           with {:ok, user} <- User.register(changeset) do
 191             !registrations_open && UserInviteToken.mark_as_used(token.token)
 192
 193             {:ok, user}
 194           else
 195             {:error, changeset} ->
 196               errors =
 197                 Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 198                 |> Jason.encode!()
 199
 200               {:error, %{error: errors}}
 201           end
 202
 203         !registrations_open && is_nil(token) ->
 204           {:error, "Invalid token"}
 205
 206         !registrations_open && token.used ->
 207           {:error, "Expired token"}
 208       end
 209     end
 210   end
 211
 212   def password_reset(nickname_or_email) do
 213     with true <- is_binary(nickname_or_email),
 214          %User{local: true} = user <- User.get_by_nickname_or_email(nickname_or_email),
 215          {:ok, token_record} <- Pleroma.PasswordResetToken.create_token(user) do
 216       user
 217       |> UserEmail.password_reset_email(token_record.token)
 218       |> Mailer.deliver_async()
 219     else
 220       false ->
 221         {:error, "bad user identifier"}
 222
 223       %User{local: false} ->
 224         {:error, "remote user"}
 225
 226       nil ->
 227         {:error, "unknown user"}
 228     end
 229   end
 230
 231   def get_user(user \\ nil, params) do
 232     case params do
 233       %{"user_id" => user_id} ->
 234         case target = User.get_cached_by_nickname_or_id(user_id) do
 235           nil ->
 236             {:error, "No user with such user_id"}
 237
 238           _ ->
 239             {:ok, target}
 240         end
 241
 242       %{"screen_name" => nickname} ->
 243         case User.get_by_nickname(nickname) do
 244           nil -> {:error, "No user with such screen_name"}
 245           target -> {:ok, target}
 246         end
 247
 248       _ ->
 249         if user do
 250           {:ok, user}
 251         else
 252           {:error, "You need to specify screen_name or user_id"}
 253         end
 254     end
 255   end
 256
 257   defp parse_int(string, default)
 258
 259   defp parse_int(string, default) when is_binary(string) do
 260     with {n, _} <- Integer.parse(string) do
 261       n
 262     else
 263       _e -> default
 264     end
 265   end
 266
 267   defp parse_int(_, default), do: default
 268
 269   def search(_user, %{"q" => query} = params) do
 270     limit = parse_int(params["rpp"], 20)
 271     page = parse_int(params["page"], 1)
 272     offset = (page - 1) * limit
 273
 274     q =
 275       from(
 276         a in Activity,
 277         where: fragment("?->>'type' = 'Create'", a.data),
 278         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 279         where:
 280           fragment(
 281             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 282             a.data,
 283             ^query
 284           ),
 285         limit: ^limit,
 286         offset: ^offset,
 287         # this one isn't indexed so psql won't take the wrong index.
 288         order_by: [desc: :inserted_at]
 289       )
 290
 291     _activities = Repo.all(q)
 292   end
 293
 294   def get_external_profile(for_user, uri) do
 295     with %User{} = user <- User.get_or_fetch(uri) do
 296       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 297     else
 298       _e ->
 299         {:error, "Couldn't find user"}
 300     end
 301   end
 302 end