git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.OStatus
   7   alias Pleroma.Formatter
   8
   9   import Pleroma.Web.TwitterAPI.Utils
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   def to_for_user_and_mentions(user, mentions, inReplyTo) do
  14     default_to = [
  15       user.follower_address,
  16       "https://www.w3.org/ns/activitystreams#Public"
  17     ]
  18
  19     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  20     if inReplyTo do
  21       Enum.uniq([inReplyTo.data["actor"] | to])
  22     else
  23       to
  24     end
  25   end
  26
  27   def get_replied_to_activity(id) when not is_nil(id) do
  28     Repo.get(Activity, id)
  29   end
  30
  31   def get_replied_to_activity(_), do: nil
  32
  33   def create_status(%User{} = user, %{"status" => status} = data) do
  34     with attachments <- attachments_from_ids(data["media_ids"]),
  35          mentions <- Formatter.parse_mentions(status),
  36          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  37          to <- to_for_user_and_mentions(user, mentions, inReplyTo),
  38          content_html <- make_content_html(status, mentions, attachments),
  39          context <- make_context(inReplyTo),
  40          tags <- Formatter.parse_tags(status),
  41          object <- make_note_data(user.ap_id, to, context, content_html, attachments, inReplyTo, tags) do
  42       res = ActivityPub.create(to, user, context, object)
  43       User.update_note_count(user)
  44       res
  45     end
  46   end
  47
  48   def fetch_friend_statuses(user, opts \\ %{}) do
  49     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  50     |> activities_to_statuses(%{for: user})
  51   end
  52
  53   def fetch_public_statuses(user, opts \\ %{}) do
  54     opts = Map.put(opts, "local_only", true)
  55     ActivityPub.fetch_public_activities(opts)
  56     |> activities_to_statuses(%{for: user})
  57   end
  58
  59   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  60     ActivityPub.fetch_public_activities(opts)
  61     |> activities_to_statuses(%{for: user})
  62   end
  63
  64   def fetch_user_statuses(user, opts \\ %{}) do
  65     ActivityPub.fetch_activities([], opts)
  66     |> activities_to_statuses(%{for: user})
  67   end
  68
  69   def fetch_mentions(user, opts \\ %{}) do
  70     ActivityPub.fetch_activities([user.ap_id], opts)
  71     |> activities_to_statuses(%{for: user})
  72   end
  73
  74   def fetch_conversation(user, id) do
  75     with context when is_binary(context) <- conversation_id_to_context(id),
  76          activities <- ActivityPub.fetch_activities_for_context(context),
  77          statuses <- activities |> activities_to_statuses(%{for: user})
  78     do
  79       statuses
  80     else _e ->
  81       []
  82     end
  83   end
  84
  85   def fetch_status(user, id) do
  86     with %Activity{} = activity <- Repo.get(Activity, id) do
  87       activity_to_status(activity, %{for: user})
  88     end
  89   end
  90
  91   def follow(%User{} = follower, params) do
  92     with {:ok, %User{} = followed} <- get_user(params),
  93          {:ok, follower} <- User.follow(follower, followed),
  94          {:ok, activity} <- ActivityPub.follow(follower, followed)
  95     do
  96       {:ok, follower, followed, activity}
  97     else
  98       err -> err
  99     end
 100   end
 101
 102   def unfollow(%User{} = follower, params) do
 103     with { :ok, %User{} = unfollowed } <- get_user(params),
 104          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
 105          { :ok, _activity } <- ActivityPub.insert(%{
 106            "type" => "Undo",
 107            "actor" => follower.ap_id,
 108            "object" => follow_activity.data["id"], # get latest Follow for these users
 109            "published" => make_date()
 110          })
 111     do
 112       { :ok, follower, unfollowed }
 113     else
 114       err -> err
 115     end
 116   end
 117
 118   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 119     object = Object.get_by_ap_id(object["id"])
 120
 121     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 122     new_data = activity.data
 123     |> Map.put("object", object.data)
 124
 125     status = %{activity | data: new_data}
 126     |> activity_to_status(%{for: user})
 127
 128     {:ok, status}
 129   end
 130
 131   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 132     object = Object.get_by_ap_id(object["id"])
 133
 134     {:ok, object} = ActivityPub.unlike(user, object)
 135     new_data = activity.data
 136     |> Map.put("object", object.data)
 137
 138     status = %{activity | data: new_data}
 139     |> activity_to_status(%{for: user})
 140
 141     {:ok, status}
 142   end
 143
 144   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 145     object = Object.get_by_ap_id(object["id"])
 146
 147     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 148     new_data = activity.data
 149     |> Map.put("object", object.data)
 150
 151     status = %{activity | data: new_data}
 152     |> activity_to_status(%{for: user})
 153
 154     {:ok, status}
 155   end
 156
 157   def upload(%Plug.Upload{} = file, format \\ "xml") do
 158     {:ok, object} = ActivityPub.upload(file)
 159
 160     url = List.first(object.data["url"])
 161     href = url["href"]
 162     type = url["mediaType"]
 163
 164     case format do
 165       "xml" ->
 166         # Fake this as good as possible...
 167         """
 168         <?xml version="1.0" encoding="UTF-8"?>
 169         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 170         <mediaid>#{object.id}</mediaid>
 171         <media_id>#{object.id}</media_id>
 172         <media_id_string>#{object.id}</media_id_string>
 173         <media_url>#{href}</media_url>
 174         <mediaurl>#{href}</mediaurl>
 175         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 176         </rsp>
 177         """
 178       "json" ->
 179         %{
 180           media_id: object.id,
 181           media_id_string: "#{object.id}}",
 182           media_url: href,
 183           size: 0
 184         } |> Poison.encode!
 185     end
 186   end
 187
 188   def register_user(params) do
 189     params = %{
 190       nickname: params["nickname"],
 191       name: params["fullname"],
 192       bio: params["bio"],
 193       email: params["email"],
 194       password: params["password"],
 195       password_confirmation: params["confirm"]
 196     }
 197
 198     changeset = User.register_changeset(%User{}, params)
 199
 200     with {:ok, user} <- Repo.insert(changeset) do
 201       {:ok, user}
 202     else
 203       {:error, changeset} ->
 204         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 205       |> Poison.encode!
 206       {:error, %{error: errors}}
 207     end
 208   end
 209
 210   def get_by_id_or_nickname(id_or_nickname) do
 211     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 212       Repo.get_by(User, nickname: id_or_nickname)
 213     else
 214       Repo.get(User, id_or_nickname)
 215     end
 216   end
 217
 218   def get_user(user \\ nil, params) do
 219     case params do
 220       %{"user_id" => user_id} ->
 221         case target = get_by_id_or_nickname(user_id) do
 222           nil ->
 223             {:error, "No user with such user_id"}
 224           _ ->
 225             {:ok, target}
 226         end
 227       %{"screen_name" => nickname} ->
 228         case target = Repo.get_by(User, nickname: nickname) do
 229           nil ->
 230             {:error, "No user with such screen_name"}
 231           _ ->
 232             {:ok, target}
 233         end
 234       _ ->
 235         if user do
 236           {:ok, user}
 237         else
 238           {:error, "You need to specify screen_name or user_id"}
 239         end
 240     end
 241   end
 242
 243   defp activities_to_statuses(activities, opts) do
 244     Enum.map(activities, fn(activity) ->
 245       activity_to_status(activity, opts)
 246     end)
 247   end
 248
 249   # For likes, fetch the liked activity, too.
 250   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 251     actor = get_in(activity.data, ["actor"])
 252     user = User.get_cached_by_ap_id(actor)
 253     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 254
 255     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 256   end
 257
 258   # For announces, fetch the announced activity and the user.
 259   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 260     actor = get_in(activity.data, ["actor"])
 261     user = User.get_cached_by_ap_id(actor)
 262     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 263     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 264
 265     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 266   end
 267
 268   defp activity_to_status(activity, opts) do
 269     actor = get_in(activity.data, ["actor"])
 270     user = User.get_cached_by_ap_id(actor)
 271     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 272     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 273       if ap_id do
 274         User.get_cached_by_ap_id(ap_id)
 275       else
 276         nil
 277       end
 278     end)
 279     |> Enum.filter(&(&1))
 280
 281     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 282   end
 283
 284   defp make_date do
 285     DateTime.utc_now() |> DateTime.to_iso8601
 286   end
 287
 288   def context_to_conversation_id(context) do
 289     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 290       id
 291       else _e ->
 292         changeset = Object.context_mapping(context)
 293         case Repo.insert(changeset) do
 294           {:ok, %{id: id}} -> id
 295           # This should be solved by an upsert, but it seems ecto
 296           # has problems accessing the constraint inside the jsonb.
 297           {:error, _} -> Object.get_cached_by_ap_id(context).id
 298         end
 299     end
 300   end
 301
 302   def conversation_id_to_context(id) do
 303     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 304       context
 305     else _e ->
 306       {:error, "No such conversation"}
 307     end
 308   end
 309
 310   def get_external_profile(for_user, uri) do
 311     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 312       with url <- user.info["topic"],
 313            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 314         OStatus.handle_incoming(body)
 315       end
 316       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 317     else _e ->
 318         {:error, "Couldn't find user"}
 319     end
 320   end
 321 end