git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   5
   6   import Ecto.Query
   7
   8   def to_for_user_and_mentions(user, mentions) do
   9     default_to = [
  10       User.ap_followers(user),
  11       "https://www.w3.org/ns/activitystreams#Public"
  12     ]
  13
  14     default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  15   end
  16
  17   def format_input(text, mentions) do
  18     HtmlSanitizeEx.strip_tags(text)
  19     |> String.replace("\n", "<br>")
  20     |> add_user_links(mentions)
  21   end
  22
  23   def attachments_from_ids(ids) do
  24     Enum.map(ids || [], fn (media_id) ->
  25       Repo.get(Object, media_id).data
  26     end)
  27   end
  28
  29   def get_replied_to_activity(id) when not is_nil(id) do
  30     Repo.get(Activity, id)
  31   end
  32
  33   def get_replied_to_activity(_), do: nil
  34
  35   def create_status(user = %User{}, data = %{"status" => status}) do
  36     attachments = attachments_from_ids(data["media_ids"])
  37     context = ActivityPub.generate_context_id
  38     mentions = parse_mentions(status)
  39     content_html = format_input(status, mentions)
  40     to = to_for_user_and_mentions(user, mentions)
  41     date = make_date()
  42
  43     inReplyTo = get_replied_to_activity(data["in_reply_to_status_id"])
  44
  45     # Wire up reply info.
  46     [to, context, object, additional] =
  47       if inReplyTo do
  48       context = inReplyTo.data["context"]
  49       to = to ++ [inReplyTo.data["actor"]]
  50
  51       object = %{
  52         "type" => "Note",
  53         "to" => to,
  54         "content" => content_html,
  55         "published" => date,
  56         "context" => context,
  57         "attachment" => attachments,
  58         "actor" => user.ap_id,
  59         "inReplyTo" => inReplyTo.data["object"]["id"],
  60         "inReplyToStatusId" => inReplyTo.id,
  61         "statusnetConversationId" => inReplyTo.data["statusnetConversationId"]
  62       }
  63       additional = %{
  64         "statusnetConversationId" => inReplyTo.data["statusnetConversationId"]
  65       }
  66
  67       [to, context, object, additional]
  68       else
  69       object = %{
  70         "type" => "Note",
  71         "to" => to,
  72         "content" => content_html,
  73         "published" => date,
  74         "context" => context,
  75         "attachment" => attachments,
  76         "actor" => user.ap_id
  77       }
  78       [to, context, object, %{}]
  79     end
  80
  81     ActivityPub.create(to, user, context, object, additional, data)
  82   end
  83
  84   def fetch_friend_statuses(user, opts \\ %{}) do
  85     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  86     |> activities_to_statuses(%{for: user})
  87   end
  88
  89   def fetch_public_statuses(user, opts \\ %{}) do
  90     ActivityPub.fetch_public_activities(opts)
  91     |> activities_to_statuses(%{for: user})
  92   end
  93
  94   def fetch_user_statuses(user, opts \\ %{}) do
  95     ActivityPub.fetch_activities([], opts)
  96     |> activities_to_statuses(%{for: user})
  97   end
  98
  99   def fetch_mentions(user, opts \\ %{}) do
 100     ActivityPub.fetch_activities([user.ap_id], opts)
 101     |> activities_to_statuses(%{for: user})
 102   end
 103
 104   def fetch_conversation(user, id) do
 105     query = from activity in Activity,
 106       where: fragment("? @> ?", activity.data, ^%{ statusnetConversationId: id}),
 107       limit: 1
 108
 109     with %Activity{} = activity <- Repo.one(query),
 110          context <- activity.data["context"],
 111          activities <- ActivityPub.fetch_activities_for_context(context),
 112          statuses <- activities |> activities_to_statuses(%{for: user})
 113     do
 114       statuses
 115     else e ->
 116       IO.inspect(e)
 117       []
 118     end
 119   end
 120
 121   def fetch_status(user, id) do
 122     with %Activity{} = activity <- Repo.get(Activity, id) do
 123       activity_to_status(activity, %{for: user})
 124     end
 125   end
 126
 127   def follow(%User{} = follower, followed_id) do
 128     with %User{} = followed <- Repo.get(User, followed_id),
 129     { :ok, follower } <- User.follow(follower, followed),
 130          { :ok, activity } <- ActivityPub.insert(%{
 131            "type" => "Follow",
 132            "actor" => follower.ap_id,
 133            "object" => followed.ap_id,
 134            "published" => make_date()
 135          })
 136     do
 137       { :ok, follower, followed, activity }
 138     else
 139       err -> err
 140     end
 141   end
 142
 143   def unfollow(%User{} = follower, followed_id) do
 144     with %User{} = followed <- Repo.get(User, followed_id),
 145          { :ok, follower } <- User.unfollow(follower, followed)
 146     do
 147       { :ok, follower, followed }
 148     else
 149       err -> err
 150     end
 151   end
 152
 153   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 154     object = Object.get_by_ap_id(object["id"])
 155
 156     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 157     new_data = activity.data
 158     |> Map.put("object", object.data)
 159
 160     status = %{activity | data: new_data}
 161     |> activity_to_status(%{for: user})
 162
 163     {:ok, status}
 164   end
 165
 166   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 167     object = Object.get_by_ap_id(object["id"])
 168
 169     {:ok, object} = ActivityPub.unlike(user, object)
 170     new_data = activity.data
 171     |> Map.put("object", object.data)
 172
 173     status = %{activity | data: new_data}
 174     |> activity_to_status(%{for: user})
 175
 176     {:ok, status}
 177   end
 178
 179   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 180     object = Object.get_by_ap_id(object["id"])
 181
 182     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 183     new_data = activity.data
 184     |> Map.put("object", object.data)
 185
 186     status = %{activity | data: new_data}
 187     |> activity_to_status(%{for: user})
 188
 189     {:ok, status}
 190   end
 191
 192   def upload(%Plug.Upload{} = file, format \\ "xml") do
 193     {:ok, object} = ActivityPub.upload(file)
 194
 195     url = List.first(object.data["url"])
 196     href = url["href"]
 197     type = url["mediaType"]
 198
 199     case format do
 200       "xml" ->
 201         # Fake this as good as possible...
 202         """
 203         <?xml version="1.0" encoding="UTF-8"?>
 204         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 205         <mediaid>#{object.id}</mediaid>
 206         <media_id>#{object.id}</media_id>
 207         <media_id_string>#{object.id}</media_id_string>
 208         <media_url>#{href}</media_url>
 209         <mediaurl>#{href}</mediaurl>
 210         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 211         </rsp>
 212         """
 213       "json" ->
 214         %{
 215           media_id: object.id,
 216           media_id_string: "#{object.id}}",
 217           media_url: href,
 218           size: 0
 219         } |> Poison.encode!
 220     end
 221   end
 222
 223   def parse_mentions(text) do
 224     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 225     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 226
 227     Regex.scan(regex, text)
 228     |> List.flatten
 229     |> Enum.uniq
 230     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 231     |> Enum.filter(fn ({_match, user}) -> user end)
 232   end
 233
 234   def add_user_links(text, mentions) do
 235     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 236   end
 237
 238   def register_user(params) do
 239     params = %{
 240       nickname: params["nickname"],
 241       name: params["fullname"],
 242       bio: params["bio"],
 243       email: params["email"],
 244       password: params["password"],
 245       password_confirmation: params["confirm"]
 246     }
 247
 248     changeset = User.register_changeset(%User{}, params)
 249
 250     with {:ok, user} <- Repo.insert(changeset) do
 251       {:ok, UserRepresenter.to_map(user)}
 252     else
 253       {:error, changeset} ->
 254         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 255       |> Poison.encode!
 256         {:error, %{error: errors}}
 257     end
 258   end
 259
 260   def get_user(user, params) do
 261     case params do
 262       %{ "user_id" => user_id } ->
 263         case target = Repo.get(User, user_id) do
 264           nil ->
 265             {:error, "No user with such user_id"}
 266           _ ->
 267             {:ok, target}
 268         end
 269       %{ "screen_name" => nickname } ->
 270         case target = Repo.get_by(User, nickname: nickname) do
 271           nil ->
 272             {:error, "No user with such screen_name"}
 273           _ ->
 274             {:ok, target}
 275         end
 276       _ ->
 277         if user do
 278           {:ok, user}
 279         else
 280           {:error, "You need to specify screen_name or user_id"}
 281         end
 282     end
 283   end
 284
 285   defp activities_to_statuses(activities, opts) do
 286     Enum.map(activities, fn(activity) ->
 287       activity_to_status(activity, opts)
 288     end)
 289   end
 290
 291   # For likes, fetch the liked activity, too.
 292   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 293     actor = get_in(activity.data, ["actor"])
 294     user = User.get_cached_by_ap_id(actor)
 295     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 296
 297     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 298   end
 299
 300   # For announces, fetch the announced activity and the user.
 301   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 302     actor = get_in(activity.data, ["actor"])
 303     user = User.get_cached_by_ap_id(actor)
 304     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 305     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 306
 307     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 308   end
 309
 310   defp activity_to_status(activity, opts) do
 311     actor = get_in(activity.data, ["actor"])
 312     user = User.get_cached_by_ap_id(actor)
 313     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 314     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 315       User.get_cached_by_ap_id(ap_id)
 316     end)
 317     |> Enum.filter(&(&1))
 318
 319     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 320   end
 321
 322   defp make_date do
 323     DateTime.utc_now() |> DateTime.to_iso8601
 324   end
 325 end