git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.UserView
   5   alias Pleroma.Web.{OStatus, CommonAPI}
   6   import Ecto.Query
   7
   8   @httpoison Application.get_env(:pleroma, :httpoison)
   9
  10   def create_status(%User{} = user, %{"status" => _} = data) do
  11     CommonAPI.post(user, data)
  12   end
  13
  14   def delete(%User{} = user, id) do
  15     with %Activity{data: %{"type" => type}} <- Repo.get(Activity, id),
  16          {:ok, activity} <- CommonAPI.delete(id, user) do
  17       {:ok, activity}
  18     end
  19   end
  20
  21   def follow(%User{} = follower, params) do
  22     with {:ok, %User{} = followed} <- get_user(params),
  23          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  24          {:ok, activity} <- ActivityPub.follow(follower, followed) do
  25       {:ok, follower, followed, activity}
  26     else
  27       err -> err
  28     end
  29   end
  30
  31   def unfollow(%User{} = follower, params) do
  32     with {:ok, %User{} = unfollowed} <- get_user(params),
  33          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  34          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  35       {:ok, follower, unfollowed}
  36     else
  37       err -> err
  38     end
  39   end
  40
  41   def block(%User{} = blocker, params) do
  42     with {:ok, %User{} = blocked} <- get_user(params),
  43          {:ok, blocker} <- User.block(blocker, blocked),
  44          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
  45       {:ok, blocker, blocked}
  46     else
  47       err -> err
  48     end
  49   end
  50
  51   def unblock(%User{} = blocker, params) do
  52     with {:ok, %User{} = blocked} <- get_user(params),
  53          {:ok, blocker} <- User.unblock(blocker, blocked),
  54          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
  55       {:ok, blocker, blocked}
  56     else
  57       err -> err
  58     end
  59   end
  60
  61   def repeat(%User{} = user, ap_id_or_id) do
  62     with {:ok, _announce, %{data: %{"id" => id}}} <- CommonAPI.repeat(ap_id_or_id, user),
  63          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  64       {:ok, activity}
  65     end
  66   end
  67
  68   def unrepeat(%User{} = user, ap_id_or_id) do
  69     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
  70          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  71       {:ok, activity}
  72     end
  73   end
  74
  75   def fav(%User{} = user, ap_id_or_id) do
  76     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
  77          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  78       {:ok, activity}
  79     end
  80   end
  81
  82   def unfav(%User{} = user, ap_id_or_id) do
  83     with {:ok, _unfav, _fav, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
  84          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  85       {:ok, activity}
  86     end
  87   end
  88
  89   def upload(%Plug.Upload{} = file, format \\ "xml") do
  90     {:ok, object} = ActivityPub.upload(file)
  91
  92     url = List.first(object.data["url"])
  93     href = url["href"]
  94     type = url["mediaType"]
  95
  96     case format do
  97       "xml" ->
  98         # Fake this as good as possible...
  99         """
 100         <?xml version="1.0" encoding="UTF-8"?>
 101         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 102         <mediaid>#{object.id}</mediaid>
 103         <media_id>#{object.id}</media_id>
 104         <media_id_string>#{object.id}</media_id_string>
 105         <media_url>#{href}</media_url>
 106         <mediaurl>#{href}</mediaurl>
 107         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 108         </rsp>
 109         """
 110
 111       "json" ->
 112         %{
 113           media_id: object.id,
 114           media_id_string: "#{object.id}}",
 115           media_url: href,
 116           size: 0
 117         }
 118         |> Jason.encode!()
 119     end
 120   end
 121
 122   def register_user(params) do
 123     params = %{
 124       nickname: params["nickname"],
 125       name: params["fullname"],
 126       bio: params["bio"],
 127       email: params["email"],
 128       password: params["password"],
 129       password_confirmation: params["confirm"]
 130     }
 131
 132     changeset = User.register_changeset(%User{}, params)
 133
 134     with {:ok, user} <- Repo.insert(changeset) do
 135       {:ok, user}
 136     else
 137       {:error, changeset} ->
 138         errors =
 139           Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 140           |> Jason.encode!()
 141
 142         {:error, %{error: errors}}
 143     end
 144   end
 145
 146   def get_by_id_or_nickname(id_or_nickname) do
 147     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 148       Repo.get_by(User, nickname: id_or_nickname)
 149     else
 150       Repo.get(User, id_or_nickname)
 151     end
 152   end
 153
 154   def get_user(user \\ nil, params) do
 155     case params do
 156       %{"user_id" => user_id} ->
 157         case target = get_by_id_or_nickname(user_id) do
 158           nil ->
 159             {:error, "No user with such user_id"}
 160
 161           _ ->
 162             {:ok, target}
 163         end
 164
 165       %{"screen_name" => nickname} ->
 166         case target = Repo.get_by(User, nickname: nickname) do
 167           nil ->
 168             {:error, "No user with such screen_name"}
 169
 170           _ ->
 171             {:ok, target}
 172         end
 173
 174       _ ->
 175         if user do
 176           {:ok, user}
 177         else
 178           {:error, "You need to specify screen_name or user_id"}
 179         end
 180     end
 181   end
 182
 183   defp parse_int(string, default)
 184
 185   defp parse_int(string, default) when is_binary(string) do
 186     with {n, _} <- Integer.parse(string) do
 187       n
 188     else
 189       _e -> default
 190     end
 191   end
 192
 193   defp parse_int(_, default), do: default
 194
 195   def search(_user, %{"q" => query} = params) do
 196     limit = parse_int(params["rpp"], 20)
 197     page = parse_int(params["page"], 1)
 198     offset = (page - 1) * limit
 199
 200     q =
 201       from(
 202         a in Activity,
 203         where: fragment("?->>'type' = 'Create'", a.data),
 204         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 205         where:
 206           fragment(
 207             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 208             a.data,
 209             ^query
 210           ),
 211         limit: ^limit,
 212         offset: ^offset,
 213         # this one isn't indexed so psql won't take the wrong index.
 214         order_by: [desc: :inserted_at]
 215       )
 216
 217     _activities = Repo.all(q)
 218   end
 219
 220   defp make_date do
 221     DateTime.utc_now() |> DateTime.to_iso8601()
 222   end
 223
 224   # DEPRECATED mostly, context objects are now created at insertion time.
 225   def context_to_conversation_id(context) do
 226     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 227       id
 228     else
 229       _e ->
 230         changeset = Object.context_mapping(context)
 231
 232         case Repo.insert(changeset) do
 233           {:ok, %{id: id}} ->
 234             id
 235
 236           # This should be solved by an upsert, but it seems ecto
 237           # has problems accessing the constraint inside the jsonb.
 238           {:error, _} ->
 239             Object.get_cached_by_ap_id(context).id
 240         end
 241     end
 242   end
 243
 244   def conversation_id_to_context(id) do
 245     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 246       context
 247     else
 248       _e ->
 249         {:error, "No such conversation"}
 250     end
 251   end
 252
 253   def get_external_profile(for_user, uri) do
 254     with %User{} = user <- User.get_or_fetch(uri) do
 255       spawn(fn ->
 256         with url <- user.info["topic"],
 257              {:ok, %{body: body}} <-
 258                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 259           OStatus.handle_incoming(body)
 260         end
 261       end)
 262
 263       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 264     else
 265       _e ->
 266         {:error, "Couldn't find user"}
 267     end
 268   end
 269 end