git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.{OStatus, CommonAPI}
   7   import Ecto.Query
   8
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10
  11   def create_status(%User{} = user, %{"status" => _} = data) do
  12     CommonAPI.post(user, data)
  13   end
  14
  15   def follow(%User{} = follower, params) do
  16     with {:ok, %User{} = followed} <- get_user(params),
  17          {:ok, follower} <- User.follow(follower, followed),
  18          {:ok, activity} <- ActivityPub.follow(follower, followed) do
  19       {:ok, follower, followed, activity}
  20     else
  21       err -> err
  22     end
  23   end
  24
  25   def unfollow(%User{} = follower, params) do
  26     with {:ok, %User{} = unfollowed} <- get_user(params),
  27          {:ok, follower, follow_activity} <- User.unfollow(follower, unfollowed),
  28          {:ok, _activity} <-
  29            ActivityPub.insert(%{
  30              "type" => "Undo",
  31              "actor" => follower.ap_id,
  32              # get latest Follow for these users
  33              "object" => follow_activity.data["id"],
  34              "published" => make_date()
  35            }) do
  36       {:ok, follower, unfollowed}
  37     else
  38       err -> err
  39     end
  40   end
  41
  42   def block(%User{} = blocker, params) do
  43     with {:ok, %User{} = blocked} <- get_user(params),
  44          {:ok, blocker} <- User.block(blocker, blocked) do
  45       {:ok, blocker, blocked}
  46     else
  47       err -> err
  48     end
  49   end
  50
  51   def unblock(%User{} = blocker, params) do
  52     with {:ok, %User{} = blocked} <- get_user(params),
  53          {:ok, blocker} <- User.unblock(blocker, blocked) do
  54       {:ok, blocker, blocked}
  55     else
  56       err -> err
  57     end
  58   end
  59
  60   def repeat(%User{} = user, ap_id_or_id) do
  61     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
  62          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  63       {:ok, activity}
  64     end
  65   end
  66
  67   def fav(%User{} = user, ap_id_or_id) do
  68     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
  69          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  70       {:ok, activity}
  71     end
  72   end
  73
  74   def unfav(%User{} = user, ap_id_or_id) do
  75     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
  76          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
  77       {:ok, activity}
  78     end
  79   end
  80
  81   def upload(%Plug.Upload{} = file, format \\ "xml") do
  82     {:ok, object} = ActivityPub.upload(file)
  83
  84     url = List.first(object.data["url"])
  85     href = url["href"]
  86     type = url["mediaType"]
  87
  88     case format do
  89       "xml" ->
  90         # Fake this as good as possible...
  91         """
  92         <?xml version="1.0" encoding="UTF-8"?>
  93         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
  94         <mediaid>#{object.id}</mediaid>
  95         <media_id>#{object.id}</media_id>
  96         <media_id_string>#{object.id}</media_id_string>
  97         <media_url>#{href}</media_url>
  98         <mediaurl>#{href}</mediaurl>
  99         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 100         </rsp>
 101         """
 102
 103       "json" ->
 104         %{
 105           media_id: object.id,
 106           media_id_string: "#{object.id}}",
 107           media_url: href,
 108           size: 0
 109         }
 110         |> Jason.encode!()
 111     end
 112   end
 113
 114   def register_user(params) do
 115     params = %{
 116       nickname: params["nickname"],
 117       name: params["fullname"],
 118       bio: params["bio"],
 119       email: params["email"],
 120       password: params["password"],
 121       password_confirmation: params["confirm"]
 122     }
 123
 124     changeset = User.register_changeset(%User{}, params)
 125
 126     with {:ok, user} <- Repo.insert(changeset) do
 127       {:ok, user}
 128     else
 129       {:error, changeset} ->
 130         errors =
 131           Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 132           |> Jason.encode!()
 133
 134         {:error, %{error: errors}}
 135     end
 136   end
 137
 138   def get_by_id_or_nickname(id_or_nickname) do
 139     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 140       Repo.get_by(User, nickname: id_or_nickname)
 141     else
 142       Repo.get(User, id_or_nickname)
 143     end
 144   end
 145
 146   def get_user(user \\ nil, params) do
 147     case params do
 148       %{"user_id" => user_id} ->
 149         case target = get_by_id_or_nickname(user_id) do
 150           nil ->
 151             {:error, "No user with such user_id"}
 152
 153           _ ->
 154             {:ok, target}
 155         end
 156
 157       %{"screen_name" => nickname} ->
 158         case target = Repo.get_by(User, nickname: nickname) do
 159           nil ->
 160             {:error, "No user with such screen_name"}
 161
 162           _ ->
 163             {:ok, target}
 164         end
 165
 166       _ ->
 167         if user do
 168           {:ok, user}
 169         else
 170           {:error, "You need to specify screen_name or user_id"}
 171         end
 172     end
 173   end
 174
 175   defp parse_int(string, default)
 176
 177   defp parse_int(string, default) when is_binary(string) do
 178     with {n, _} <- Integer.parse(string) do
 179       n
 180     else
 181       _e -> default
 182     end
 183   end
 184
 185   defp parse_int(_, default), do: default
 186
 187   def search(user, %{"q" => query} = params) do
 188     limit = parse_int(params["rpp"], 20)
 189     page = parse_int(params["page"], 1)
 190     offset = (page - 1) * limit
 191
 192     q =
 193       from(
 194         a in Activity,
 195         where: fragment("?->>'type' = 'Create'", a.data),
 196         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 197         where:
 198           fragment(
 199             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 200             a.data,
 201             ^query
 202           ),
 203         limit: ^limit,
 204         offset: ^offset,
 205         # this one isn't indexed so psql won't take the wrong index.
 206         order_by: [desc: :inserted_at]
 207       )
 208
 209     activities = Repo.all(q)
 210   end
 211
 212   defp make_date do
 213     DateTime.utc_now() |> DateTime.to_iso8601()
 214   end
 215
 216   # DEPRECATED mostly, context objects are now created at insertion time.
 217   def context_to_conversation_id(context) do
 218     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 219       id
 220     else
 221       _e ->
 222         changeset = Object.context_mapping(context)
 223
 224         case Repo.insert(changeset) do
 225           {:ok, %{id: id}} ->
 226             id
 227
 228           # This should be solved by an upsert, but it seems ecto
 229           # has problems accessing the constraint inside the jsonb.
 230           {:error, _} ->
 231             Object.get_cached_by_ap_id(context).id
 232         end
 233     end
 234   end
 235
 236   def conversation_id_to_context(id) do
 237     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 238       context
 239     else
 240       _e ->
 241         {:error, "No such conversation"}
 242     end
 243   end
 244
 245   def get_external_profile(for_user, uri) do
 246     with %User{} = user <- User.get_or_fetch(uri) do
 247       spawn(fn ->
 248         with url <- user.info["topic"],
 249              {:ok, %{body: body}} <-
 250                @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 251           OStatus.handle_incoming(body)
 252         end
 253       end)
 254
 255       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 256     else
 257       _e ->
 258         {:error, "Couldn't find user"}
 259     end
 260   end
 261 end