git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   5   alias Pleroma.Web.TwitterAPI.UserView
   6   alias Pleroma.Web.{OStatus, CommonAPI}
   7   alias Pleroma.Formatter
   8   import Ecto.Query
   9
  10   @httpoison Application.get_env(:pleroma, :httpoison)
  11
  12   def create_status(%User{} = user, %{"status" => status} = data) do
  13     CommonAPI.post(user, data)
  14   end
  15
  16   def fetch_friend_statuses(user, opts \\ %{}) do
  17     opts = Map.put(opts, "blocking_user", user)
  18     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  19     |> activities_to_statuses(%{for: user})
  20   end
  21
  22   def fetch_public_statuses(user, opts \\ %{}) do
  23     opts = Map.put(opts, "local_only", true)
  24     opts = Map.put(opts, "blocking_user", user)
  25     ActivityPub.fetch_public_activities(opts)
  26     |> activities_to_statuses(%{for: user})
  27   end
  28
  29   def fetch_public_and_external_statuses(user, opts \\ %{}) do
  30     opts = Map.put(opts, "blocking_user", user)
  31     ActivityPub.fetch_public_activities(opts)
  32     |> activities_to_statuses(%{for: user})
  33   end
  34
  35   def fetch_user_statuses(user, opts \\ %{}) do
  36     ActivityPub.fetch_activities([], opts)
  37     |> activities_to_statuses(%{for: user})
  38   end
  39
  40   def fetch_mentions(user, opts \\ %{}) do
  41     ActivityPub.fetch_activities([user.ap_id], opts)
  42     |> activities_to_statuses(%{for: user})
  43   end
  44
  45   def fetch_conversation(user, id) do
  46     with context when is_binary(context) <- conversation_id_to_context(id),
  47          activities <- ActivityPub.fetch_activities_for_context(context, %{"blocking_user" => user}),
  48          statuses <- activities |> activities_to_statuses(%{for: user})
  49     do
  50       statuses
  51     else _e ->
  52       []
  53     end
  54   end
  55
  56   def fetch_status(user, id) do
  57     with %Activity{} = activity <- Repo.get(Activity, id) do
  58       activity_to_status(activity, %{for: user})
  59     end
  60   end
  61
  62   def follow(%User{} = follower, params) do
  63     with {:ok, %User{} = followed} <- get_user(params),
  64          {:ok, follower} <- User.follow(follower, followed),
  65          {:ok, activity} <- ActivityPub.follow(follower, followed)
  66     do
  67       {:ok, follower, followed, activity}
  68     else
  69       err -> err
  70     end
  71   end
  72
  73   def unfollow(%User{} = follower, params) do
  74     with { :ok, %User{} = unfollowed } <- get_user(params),
  75          { :ok, follower, follow_activity } <- User.unfollow(follower, unfollowed),
  76          { :ok, _activity } <- ActivityPub.insert(%{
  77            "type" => "Undo",
  78            "actor" => follower.ap_id,
  79            "object" => follow_activity.data["id"], # get latest Follow for these users
  80            "published" => make_date()
  81          })
  82     do
  83       { :ok, follower, unfollowed }
  84     else
  85       err -> err
  86     end
  87   end
  88
  89   def block(%User{} = blocker, params) do
  90     with {:ok, %User{} = blocked} <- get_user(params),
  91          {:ok, blocker} <- User.block(blocker, blocked)
  92     do
  93       {:ok, blocker, blocked}
  94     else
  95       err -> err
  96     end
  97   end
  98
  99   def unblock(%User{} = blocker, params) do
 100     with {:ok, %User{} = blocked} <- get_user(params),
 101          {:ok, blocker} <- User.unblock(blocker, blocked)
 102     do
 103       {:ok, blocker, blocked}
 104     else
 105       err -> err
 106     end
 107   end
 108
 109   def repeat(%User{} = user, ap_id_or_id) do
 110     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
 111          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 112          status <- activity_to_status(activity, %{for: user}) do
 113       {:ok, status}
 114     end
 115   end
 116
 117   def fav(%User{} = user, ap_id_or_id) do
 118     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 119          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 120          status <- activity_to_status(activity, %{for: user}) do
 121       {:ok, status}
 122     end
 123   end
 124
 125   def unfav(%User{} = user, ap_id_or_id) do
 126     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 127          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id),
 128          status <- activity_to_status(activity, %{for: user}) do
 129       {:ok, status}
 130     end
 131   end
 132
 133   def upload(%Plug.Upload{} = file, format \\ "xml") do
 134     {:ok, object} = ActivityPub.upload(file)
 135
 136     url = List.first(object.data["url"])
 137     href = url["href"]
 138     type = url["mediaType"]
 139
 140     case format do
 141       "xml" ->
 142         # Fake this as good as possible...
 143         """
 144         <?xml version="1.0" encoding="UTF-8"?>
 145         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 146         <mediaid>#{object.id}</mediaid>
 147         <media_id>#{object.id}</media_id>
 148         <media_id_string>#{object.id}</media_id_string>
 149         <media_url>#{href}</media_url>
 150         <mediaurl>#{href}</mediaurl>
 151         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 152         </rsp>
 153         """
 154       "json" ->
 155         %{
 156           media_id: object.id,
 157           media_id_string: "#{object.id}}",
 158           media_url: href,
 159           size: 0
 160         } |> Poison.encode!
 161     end
 162   end
 163
 164   def register_user(params) do
 165     params = %{
 166       nickname: params["nickname"],
 167       name: params["fullname"],
 168       bio: params["bio"],
 169       email: params["email"],
 170       password: params["password"],
 171       password_confirmation: params["confirm"]
 172     }
 173
 174     changeset = User.register_changeset(%User{}, params)
 175
 176     with {:ok, user} <- Repo.insert(changeset) do
 177       {:ok, user}
 178     else
 179       {:error, changeset} ->
 180         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 181       |> Poison.encode!
 182       {:error, %{error: errors}}
 183     end
 184   end
 185
 186   def get_by_id_or_nickname(id_or_nickname) do
 187     if !is_integer(id_or_nickname) && :error == Integer.parse(id_or_nickname) do
 188       Repo.get_by(User, nickname: id_or_nickname)
 189     else
 190       Repo.get(User, id_or_nickname)
 191     end
 192   end
 193
 194   def get_user(user \\ nil, params) do
 195     case params do
 196       %{"user_id" => user_id} ->
 197         case target = get_by_id_or_nickname(user_id) do
 198           nil ->
 199             {:error, "No user with such user_id"}
 200           _ ->
 201             {:ok, target}
 202         end
 203       %{"screen_name" => nickname} ->
 204         case target = Repo.get_by(User, nickname: nickname) do
 205           nil ->
 206             {:error, "No user with such screen_name"}
 207           _ ->
 208             {:ok, target}
 209         end
 210       _ ->
 211         if user do
 212           {:ok, user}
 213         else
 214           {:error, "You need to specify screen_name or user_id"}
 215         end
 216     end
 217   end
 218
 219   defp parse_int(string, default \\ nil)
 220   defp parse_int(string, default) when is_binary(string) do
 221     with {n, _} <- Integer.parse(string) do
 222       n
 223     else
 224       _e -> default
 225     end
 226   end
 227   defp parse_int(_, default), do: default
 228
 229   def search(user, %{"q" => query} = params) do
 230     limit = parse_int(params["rpp"], 20)
 231     page = parse_int(params["page"], 1)
 232     offset = (page - 1) * limit
 233
 234     q = from a in Activity,
 235       where: fragment("?->>'type' = 'Create'", a.data),
 236       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 237       limit: ^limit,
 238       offset: ^offset,
 239       order_by: [desc: :inserted_at] # this one isn't indexed so psql won't take the wrong index.
 240
 241     activities = Repo.all(q)
 242     activities_to_statuses(activities, %{for: user})
 243   end
 244
 245   defp activities_to_statuses(activities, opts) do
 246     Enum.map(activities, fn(activity) ->
 247       activity_to_status(activity, opts)
 248     end)
 249   end
 250
 251   # For likes, fetch the liked activity, too.
 252   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 253     actor = get_in(activity.data, ["actor"])
 254     user = User.get_cached_by_ap_id(actor)
 255     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 256
 257     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 258   end
 259
 260   # For announces, fetch the announced activity and the user.
 261   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 262     actor = get_in(activity.data, ["actor"])
 263     user = User.get_cached_by_ap_id(actor)
 264     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 265     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 266
 267     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 268   end
 269
 270   defp activity_to_status(%Activity{data: %{"type" => "Delete"}} = activity, opts) do
 271     actor = get_in(activity.data, ["actor"])
 272     user = User.get_cached_by_ap_id(actor)
 273     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user}))
 274   end
 275
 276   defp activity_to_status(activity, opts) do
 277     actor = get_in(activity.data, ["actor"])
 278     user = User.get_cached_by_ap_id(actor)
 279     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 280     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 281       if ap_id do
 282         User.get_cached_by_ap_id(ap_id)
 283       else
 284         nil
 285       end
 286     end)
 287     |> Enum.filter(&(&1))
 288
 289     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 290   end
 291
 292   defp make_date do
 293     DateTime.utc_now() |> DateTime.to_iso8601
 294   end
 295
 296   def context_to_conversation_id(context) do
 297     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 298       id
 299       else _e ->
 300         changeset = Object.context_mapping(context)
 301         case Repo.insert(changeset) do
 302           {:ok, %{id: id}} -> id
 303           # This should be solved by an upsert, but it seems ecto
 304           # has problems accessing the constraint inside the jsonb.
 305           {:error, _} -> Object.get_cached_by_ap_id(context).id
 306         end
 307     end
 308   end
 309
 310   def conversation_id_to_context(id) do
 311     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 312       context
 313     else _e ->
 314       {:error, "No such conversation"}
 315     end
 316   end
 317
 318   def get_external_profile(for_user, uri) do
 319     with {:ok, %User{} = user} <- OStatus.find_or_make_user(uri) do
 320       with url <- user.info["topic"],
 321            {:ok, %{body: body}} <- @httpoison.get(url, [], follow_redirect: true, timeout: 10000, recv_timeout: 20000) do
 322         OStatus.handle_incoming(body)
 323       end
 324       {:ok, UserView.render("show.json", %{user: user, for: for_user})}
 325     else _e ->
 326         {:error, "Couldn't find user"}
 327     end
 328   end
 329 end