git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Pleroma.{User, Activity, Repo, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   5
   6   import Ecto.Query
   7
   8   def to_for_user_and_mentions(user, mentions) do
   9     default_to = [
  10       User.ap_followers(user),
  11       "https://www.w3.org/ns/activitystreams#Public"
  12     ]
  13
  14     default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  15   end
  16
  17   def format_input(text, mentions) do
  18     HtmlSanitizeEx.strip_tags(text)
  19     |> String.replace("\n", "<br>")
  20     |> add_user_links(mentions)
  21   end
  22
  23   def attachments_from_ids(ids) do
  24     Enum.map(ids || [], fn (media_id) ->
  25       Repo.get(Object, media_id).data
  26     end)
  27   end
  28
  29   def get_replied_to_activity(id) when not is_nil(id) do
  30     Repo.get(Activity, id)
  31   end
  32
  33   def get_replied_to_activity(_), do: nil
  34
  35   def add_attachments(text, attachments) do
  36     attachment_text = Enum.map(attachments, fn
  37       (%{"url" => [%{"href" => href} | _]}) ->
  38         "<a href='#{href}'>#{href}</a>"
  39       _ -> ""
  40     end)
  41     Enum.join([text | attachment_text], "<br>")
  42     end
  43
  44   def create_status(%User{} = user, %{"status" => status} = data) do
  45     attachments = attachments_from_ids(data["media_ids"])
  46     context = ActivityPub.generate_context_id
  47     mentions = parse_mentions(status)
  48     content_html = status
  49     |> format_input(mentions)
  50     |> add_attachments(attachments)
  51
  52     to = to_for_user_and_mentions(user, mentions)
  53     date = make_date()
  54
  55     inReplyTo = get_replied_to_activity(data["in_reply_to_status_id"])
  56
  57     # Wire up reply info.
  58     [to, context, object, additional] =
  59       if inReplyTo do
  60       context = inReplyTo.data["context"]
  61       to = to ++ [inReplyTo.data["actor"]]
  62
  63       object = %{
  64         "type" => "Note",
  65         "to" => to,
  66         "content" => content_html,
  67         "published" => date,
  68         "context" => context,
  69         "attachment" => attachments,
  70         "actor" => user.ap_id,
  71         "inReplyTo" => inReplyTo.data["object"]["id"],
  72         "inReplyToStatusId" => inReplyTo.id,
  73       }
  74       additional = %{}
  75
  76       [to, context, object, additional]
  77       else
  78       object = %{
  79         "type" => "Note",
  80         "to" => to,
  81         "content" => content_html,
  82         "published" => date,
  83         "context" => context,
  84         "attachment" => attachments,
  85         "actor" => user.ap_id
  86       }
  87       [to, context, object, %{}]
  88     end
  89
  90     ActivityPub.create(to, user, context, object, additional, data)
  91   end
  92
  93   def fetch_friend_statuses(user, opts \\ %{}) do
  94     ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  95     |> activities_to_statuses(%{for: user})
  96   end
  97
  98   def fetch_public_statuses(user, opts \\ %{}) do
  99     opts = Map.put(opts, "local_only", true)
 100     ActivityPub.fetch_public_activities(opts)
 101     |> activities_to_statuses(%{for: user})
 102   end
 103
 104   def fetch_public_and_external_statuses(user, opts \\ %{}) do
 105     ActivityPub.fetch_public_activities(opts)
 106     |> activities_to_statuses(%{for: user})
 107   end
 108
 109   def fetch_user_statuses(user, opts \\ %{}) do
 110     ActivityPub.fetch_activities([], opts)
 111     |> activities_to_statuses(%{for: user})
 112   end
 113
 114   def fetch_mentions(user, opts \\ %{}) do
 115     ActivityPub.fetch_activities([user.ap_id], opts)
 116     |> activities_to_statuses(%{for: user})
 117   end
 118
 119   def fetch_conversation(user, id) do
 120     with context when is_binary(context) <- conversation_id_to_context(id),
 121          activities <- ActivityPub.fetch_activities_for_context(context),
 122          statuses <- activities |> activities_to_statuses(%{for: user})
 123     do
 124       statuses
 125     else _e ->
 126       []
 127     end
 128   end
 129
 130   def fetch_status(user, id) do
 131     with %Activity{} = activity <- Repo.get(Activity, id) do
 132       activity_to_status(activity, %{for: user})
 133     end
 134   end
 135
 136   def follow(%User{} = follower, params) do
 137     with {:ok, %User{} = followed} <- get_user(params),
 138          {:ok, follower} <- User.follow(follower, followed),
 139          {:ok, activity} <- ActivityPub.insert(%{
 140            "type" => "Follow",
 141            "actor" => follower.ap_id,
 142            "object" => followed.ap_id,
 143            "published" => make_date()
 144          })
 145     do
 146       {:ok, follower, followed, activity}
 147     else
 148       err -> err
 149     end
 150   end
 151
 152   def unfollow(%User{} = follower, params) do
 153     with {:ok, %User{} = unfollowed} <- get_user(params),
 154          {:ok, follower} <- User.unfollow(follower, unfollowed)
 155     do
 156       {:ok, follower, unfollowed}
 157     else
 158       err -> err
 159     end
 160   end
 161
 162   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 163     object = Object.get_by_ap_id(object["id"])
 164
 165     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 166     new_data = activity.data
 167     |> Map.put("object", object.data)
 168
 169     status = %{activity | data: new_data}
 170     |> activity_to_status(%{for: user})
 171
 172     {:ok, status}
 173   end
 174
 175   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 176     object = Object.get_by_ap_id(object["id"])
 177
 178     {:ok, object} = ActivityPub.unlike(user, object)
 179     new_data = activity.data
 180     |> Map.put("object", object.data)
 181
 182     status = %{activity | data: new_data}
 183     |> activity_to_status(%{for: user})
 184
 185     {:ok, status}
 186   end
 187
 188   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 189     object = Object.get_by_ap_id(object["id"])
 190
 191     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 192     new_data = activity.data
 193     |> Map.put("object", object.data)
 194
 195     status = %{activity | data: new_data}
 196     |> activity_to_status(%{for: user})
 197
 198     {:ok, status}
 199   end
 200
 201   def upload(%Plug.Upload{} = file, format \\ "xml") do
 202     {:ok, object} = ActivityPub.upload(file)
 203
 204     url = List.first(object.data["url"])
 205     href = url["href"]
 206     type = url["mediaType"]
 207
 208     case format do
 209       "xml" ->
 210         # Fake this as good as possible...
 211         """
 212         <?xml version="1.0" encoding="UTF-8"?>
 213         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 214         <mediaid>#{object.id}</mediaid>
 215         <media_id>#{object.id}</media_id>
 216         <media_id_string>#{object.id}</media_id_string>
 217         <media_url>#{href}</media_url>
 218         <mediaurl>#{href}</mediaurl>
 219         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 220         </rsp>
 221         """
 222       "json" ->
 223         %{
 224           media_id: object.id,
 225           media_id_string: "#{object.id}}",
 226           media_url: href,
 227           size: 0
 228         } |> Poison.encode!
 229     end
 230   end
 231
 232   def parse_mentions(text) do
 233     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 234     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 235
 236     Regex.scan(regex, text)
 237     |> List.flatten
 238     |> Enum.uniq
 239     |> Enum.map(fn ("@" <> match = full_match) -> {full_match, User.get_cached_by_nickname(match)} end)
 240     |> Enum.filter(fn ({_match, user}) -> user end)
 241   end
 242
 243   def add_user_links(text, mentions) do
 244     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) -> String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 245   end
 246
 247   def register_user(params) do
 248     params = %{
 249       nickname: params["nickname"],
 250       name: params["fullname"],
 251       bio: params["bio"],
 252       email: params["email"],
 253       password: params["password"],
 254       password_confirmation: params["confirm"]
 255     }
 256
 257     changeset = User.register_changeset(%User{}, params)
 258
 259     with {:ok, user} <- Repo.insert(changeset) do
 260       {:ok, UserRepresenter.to_map(user)}
 261     else
 262       {:error, changeset} ->
 263         errors = Ecto.Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end)
 264       |> Poison.encode!
 265       {:error, %{error: errors}}
 266     end
 267   end
 268
 269   def get_user(user \\ nil, params) do
 270     case params do
 271       %{"user_id" => user_id} ->
 272         case target = Repo.get(User, user_id) do
 273           nil ->
 274             {:error, "No user with such user_id"}
 275           _ ->
 276             {:ok, target}
 277         end
 278       %{"screen_name" => nickname} ->
 279         case target = Repo.get_by(User, nickname: nickname) do
 280           nil ->
 281             {:error, "No user with such screen_name"}
 282           _ ->
 283             {:ok, target}
 284         end
 285       _ ->
 286         if user do
 287           {:ok, user}
 288         else
 289           {:error, "You need to specify screen_name or user_id"}
 290         end
 291     end
 292   end
 293
 294   defp activities_to_statuses(activities, opts) do
 295     Enum.map(activities, fn(activity) ->
 296       activity_to_status(activity, opts)
 297     end)
 298   end
 299
 300   # For likes, fetch the liked activity, too.
 301   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 302     actor = get_in(activity.data, ["actor"])
 303     user = User.get_cached_by_ap_id(actor)
 304     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 305
 306     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 307   end
 308
 309   # For announces, fetch the announced activity and the user.
 310   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 311     actor = get_in(activity.data, ["actor"])
 312     user = User.get_cached_by_ap_id(actor)
 313     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 314     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 315
 316     ActivityRepresenter.to_map(activity, Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 317   end
 318
 319   defp activity_to_status(activity, opts) do
 320     actor = get_in(activity.data, ["actor"])
 321     user = User.get_cached_by_ap_id(actor)
 322     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 323     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 324       User.get_cached_by_ap_id(ap_id)
 325     end)
 326     |> Enum.filter(&(&1))
 327
 328     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 329   end
 330
 331   defp make_date do
 332     DateTime.utc_now() |> DateTime.to_iso8601
 333   end
 334
 335   def context_to_conversation_id(context) do
 336     with %Object{id: id} <- Object.get_cached_by_ap_id(context) do
 337       id
 338     else _e ->
 339       changeset = Object.context_mapping(context)
 340       {:ok, %{id: id}} = Repo.insert(changeset)
 341       id
 342     end
 343   end
 344
 345   def conversation_id_to_context(id) do
 346     with %Object{data: %{"id" => context}} <- Repo.get(Object, id) do
 347       context
 348     else _e ->
 349       {:error, "No such conversation"}
 350     end
 351   end
 352 end