git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api.ex

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPI do
   2   alias Ecto.Changeset
   3   alias Pleroma.{User, Activity, Repo, Object}
   4   alias Pleroma.Web.{ActivityPub.ActivityPub, Websub, OStatus}
   5   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   6
   7   import Ecto.Query
   8
   9   def create_status(%User{} = user, %{} = data) do
  10     attachments = Enum.map(data["media_ids"] || [], fn (media_id) ->
  11       Repo.get(Object, media_id).data
  12     end)
  13
  14     context = ActivityPub.generate_context_id
  15
  16     content = data["status"] |> HtmlSanitizeEx.strip_tags |> String.replace("\n", "<br>")
  17
  18     mentions = parse_mentions(content)
  19
  20     default_to = [
  21       User.ap_followers(user),
  22       "https://www.w3.org/ns/activitystreams#Public"
  23     ]
  24
  25     to = default_to ++ Enum.map(mentions, fn ({_, %{ap_id: ap_id}}) -> ap_id end)
  26
  27     content_html = add_user_links(content, mentions)
  28
  29     date = make_date()
  30
  31     activity = %{
  32       "type" => "Create",
  33       "to" => to,
  34       "actor" => user.ap_id,
  35       "object" => %{
  36         "type" => "Note",
  37         "to" => to,
  38         "content" => content_html,
  39         "published" => date,
  40         "context" => context,
  41         "attachment" => attachments,
  42         "actor" => user.ap_id
  43      },
  44       "published" => date,
  45       "context" => context
  46    }
  47
  48     # Wire up reply info.
  49     activity = with inReplyToId when not is_nil(inReplyToId) <- data["in_reply_to_status_id"],
  50                     inReplyTo <- Repo.get(Activity, inReplyToId),
  51                     context <- inReplyTo.data["context"]
  52                do
  53
  54                to = activity["to"] ++ [inReplyTo.data["actor"]]
  55
  56                activity
  57                |> put_in(["to"], to)
  58                |> put_in(["context"], context)
  59                |> put_in(["object", "context"], context)
  60                |> put_in(["object", "inReplyTo"], inReplyTo.data["object"]["id"])
  61                |> put_in(["object", "inReplyToStatusId"], inReplyToId)
  62                |> put_in(["statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  63                |> put_in(["object", "statusnetConversationId"], inReplyTo.data["statusnetConversationId"])
  64                else _e ->
  65                  activity
  66                end
  67
  68     with {:ok, activity} <- ActivityPub.insert(activity) do
  69       {:ok, activity} = add_conversation_id(activity)
  70       Websub.publish(OStatus.feed_path(user), user, activity)
  71       {:ok, activity}
  72     end
  73   end
  74
  75   def fetch_friend_statuses(user, opts \\ %{}) do
  76     activities = ActivityPub.fetch_activities([user.ap_id | user.following], opts)
  77     activities_to_statuses(activities, %{for: user})
  78   end
  79
  80   def fetch_public_statuses(user, opts \\ %{}) do
  81     activities = ActivityPub.fetch_public_activities(opts)
  82     activities_to_statuses(activities, %{for: user})
  83   end
  84
  85   def fetch_user_statuses(user, opts \\ %{}) do
  86     activities = ActivityPub.fetch_activities([], opts)
  87     activities_to_statuses(activities, %{for: user})
  88   end
  89
  90   def fetch_mentions(user, opts \\ %{}) do
  91     activities = ActivityPub.fetch_activities([user.ap_id], opts)
  92     activities_to_statuses(activities, %{for: user})
  93   end
  94
  95   def fetch_conversation(user, id) do
  96     query = from activity in Activity,
  97       where: fragment("? @> ?", activity.data, ^%{statusnetConversationId: id}),
  98       limit: 1
  99
 100     with %Activity{} = activity <- Repo.one(query),
 101          context <- activity.data["context"],
 102          activities <- ActivityPub.fetch_activities_for_context(context),
 103          statuses <- activities |> activities_to_statuses(%{for: user})
 104     do
 105       statuses
 106     else e ->
 107       IO.inspect(e)
 108       []
 109     end
 110   end
 111
 112   def fetch_status(user, id) do
 113     with %Activity{} = activity <- Repo.get(Activity, id) do
 114       activity_to_status(activity, %{for: user})
 115     end
 116   end
 117
 118   def follow(%User{} = follower, params) do
 119     with {:ok, %User{} = followed} <- get_user(params),
 120          {:ok, follower} <- User.follow(follower, followed),
 121          {:ok, activity} <- ActivityPub.insert(%{
 122           "type" => "Follow",
 123           "actor" => follower.ap_id,
 124           "object" => followed.ap_id,
 125           "published" => make_date()
 126         })
 127     do
 128       {:ok, follower, followed, activity}
 129     else
 130       err -> err
 131     end
 132   end
 133
 134   def unfollow(%User{} = follower, params) do
 135     with {:ok, %User{} = unfollowed} <- get_user(params),
 136          {:ok, follower} <- User.unfollow(follower, unfollowed)
 137     do
 138       {:ok, follower, unfollowed}
 139     else
 140       err -> err
 141     end
 142   end
 143
 144   def favorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 145     object = Object.get_by_ap_id(object["id"])
 146
 147     {:ok, _like_activity, object} = ActivityPub.like(user, object)
 148     new_data = activity.data
 149     |> Map.put("object", object.data)
 150
 151     status = %{activity | data: new_data}
 152     |> activity_to_status(%{for: user})
 153
 154     {:ok, status}
 155   end
 156
 157   def unfavorite(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 158     object = Object.get_by_ap_id(object["id"])
 159
 160     {:ok, object} = ActivityPub.unlike(user, object)
 161     new_data = activity.data
 162     |> Map.put("object", object.data)
 163
 164     status = %{activity | data: new_data}
 165     |> activity_to_status(%{for: user})
 166
 167     {:ok, status}
 168   end
 169
 170   def retweet(%User{} = user, %Activity{data: %{"object" => object}} = activity) do
 171     object = Object.get_by_ap_id(object["id"])
 172
 173     {:ok, _announce_activity, object} = ActivityPub.announce(user, object)
 174     new_data = activity.data
 175     |> Map.put("object", object.data)
 176
 177     status = %{activity | data: new_data}
 178     |> activity_to_status(%{for: user})
 179
 180     {:ok, status}
 181   end
 182
 183   def upload(%Plug.Upload{} = file, format \\ "xml") do
 184     {:ok, object} = ActivityPub.upload(file)
 185
 186     url = List.first(object.data["url"])
 187     href = url["href"]
 188     type = url["mediaType"]
 189
 190     case format do
 191       "xml" ->
 192         # Fake this as good as possible...
 193         """
 194         <?xml version="1.0" encoding="UTF-8"?>
 195         <rsp stat="ok" xmlns:atom="http://www.w3.org/2005/Atom">
 196         <mediaid>#{object.id}</mediaid>
 197         <media_id>#{object.id}</media_id>
 198         <media_id_string>#{object.id}</media_id_string>
 199         <media_url>#{href}</media_url>
 200         <mediaurl>#{href}</mediaurl>
 201         <atom:link rel="enclosure" href="#{href}" type="#{type}"></atom:link>
 202         </rsp>
 203         """
 204       "json" ->
 205         %{
 206           media_id: object.id,
 207           media_id_string: "#{object.id}}",
 208           media_url: href,
 209           size: 0
 210        } |> Poison.encode!
 211     end
 212   end
 213
 214   def parse_mentions(text) do
 215     # Modified from https://www.w3.org/TR/html5/forms.html#valid-e-mail-address
 216     regex = ~r/@[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@?[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*/
 217
 218     regex
 219     |> Regex.scan(text)
 220     |> List.flatten
 221     |> Enum.uniq
 222     |> Enum.map(fn ("@" <> match = full_match) ->
 223       {full_match, User.get_cached_by_nickname(match)} end)
 224     |> Enum.filter(fn ({_match, user}) -> user end)
 225   end
 226
 227   def add_user_links(text, mentions) do
 228     Enum.reduce(mentions, text, fn ({match, %User{ap_id: ap_id}}, text) ->
 229       String.replace(text, match, "<a href='#{ap_id}'>#{match}</a>") end)
 230   end
 231
 232   defp add_conversation_id(activity) do
 233     if is_integer(activity.data["statusnetConversationId"]) do
 234       {:ok, activity}
 235     else
 236       data = activity.data
 237       |> put_in(["object", "statusnetConversationId"], activity.id)
 238       |> put_in(["statusnetConversationId"], activity.id)
 239
 240       object = Object.get_by_ap_id(activity.data["object"]["id"])
 241
 242       changeset = Changeset.change(object, data: data["object"])
 243       Repo.update(changeset)
 244
 245       changeset = Changeset.change(activity, data: data)
 246       Repo.update(changeset)
 247     end
 248   end
 249
 250   def register_user(params) do
 251     params = %{
 252       nickname: params["nickname"],
 253       name: params["fullname"],
 254       bio: params["bio"],
 255       email: params["email"],
 256       password: params["password"],
 257       password_confirmation: params["confirm"]
 258    }
 259
 260     changeset = User.register_changeset(%User{}, params)
 261
 262     with {:ok, user} <- Repo.insert(changeset) do
 263       {:ok, UserRepresenter.to_map(user)}
 264     else
 265       {:error, changeset} ->
 266         errors = Poison.encode!(Changeset.traverse_errors(changeset, fn {msg, _opts} -> msg end))
 267         {:error, %{error: errors}}
 268     end
 269   end
 270
 271   def get_user(user \\ nil, params) do
 272     case params do
 273       %{"user_id" => user_id} ->
 274         case target = Repo.get(User, user_id) do
 275           nil ->
 276             {:error, "No user with such user_id"}
 277           _ ->
 278             {:ok, target}
 279         end
 280       %{"screen_name" => nickname} ->
 281         case target = Repo.get_by(User, nickname: nickname) do
 282           nil ->
 283             {:error, "No user with such screen_name"}
 284           _ ->
 285             {:ok, target}
 286         end
 287       _ ->
 288         if user do
 289           {:ok, user}
 290         else
 291           {:error, "You need to specify screen_name or user_id"}
 292         end
 293     end
 294   end
 295
 296   defp activities_to_statuses(activities, opts) do
 297     Enum.map(activities, fn(activity) ->
 298       activity_to_status(activity, opts)
 299     end)
 300   end
 301
 302   # For likes, fetch the liked activity, too.
 303   defp activity_to_status(%Activity{data: %{"type" => "Like"}} = activity, opts) do
 304     actor = get_in(activity.data, ["actor"])
 305     user = User.get_cached_by_ap_id(actor)
 306     [liked_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 307
 308     ActivityRepresenter.to_map(activity,
 309       Map.merge(opts, %{user: user, liked_activity: liked_activity}))
 310   end
 311
 312   # For announces, fetch the announced activity and the user.
 313   defp activity_to_status(%Activity{data: %{"type" => "Announce"}} = activity, opts) do
 314     actor = get_in(activity.data, ["actor"])
 315     user = User.get_cached_by_ap_id(actor)
 316     [announced_activity] = Activity.all_by_object_ap_id(activity.data["object"])
 317     announced_actor = User.get_cached_by_ap_id(announced_activity.data["actor"])
 318
 319     ActivityRepresenter.to_map(activity,
 320       Map.merge(opts, %{users: [user, announced_actor], announced_activity: announced_activity}))
 321   end
 322
 323   defp activity_to_status(activity, opts) do
 324     actor = get_in(activity.data, ["actor"])
 325     user = User.get_cached_by_ap_id(actor)
 326     # mentioned_users = Repo.all(from user in User, where: user.ap_id in ^activity.data["to"])
 327     mentioned_users = Enum.map(activity.data["to"] || [], fn (ap_id) ->
 328       User.get_cached_by_ap_id(ap_id)
 329     end)
 330     mentioned_users = mentioned_users |> Enum.filter(&(&1))
 331
 332     ActivityRepresenter.to_map(activity, Map.merge(opts, %{user: user, mentioned: mentioned_users}))
 333   end
 334
 335   defp make_date do
 336     DateTime.utc_now() |> DateTime.to_iso8601
 337   end
 338 end